Freigeben über

Schnellstart: Bicep-Dateien mit Visual Studio erstellen

Diese Schnellstartanleitung führt Sie durch die Schritte zum Erstellen einer Bicep-Datei mit Visual Studio. Sie erstellen ein Speicherkonto und ein virtuelles Netzwerk. Außerdem erfahren Sie, wie die Bicep-Erweiterung die Entwicklung vereinfacht, indem Sie Typsicherheit, Syntaxüberprüfung und AutoVervollständigen bereitstellen.

Ähnliche Erstellungsfunktionen werden auch in Visual Studio Code unterstützt. Siehe Schnellstart: Erstellen von Bicep-Dateien mit Visual Studio Code.

Voraussetzungen

Ressourcenausschnitt hinzufügen

Starten Sie Visual Studio, und erstellen Sie eine neue Datei mit dem Namen "main.bicep".

Visual Studio mit der Bicep-Erweiterung vereinfacht die Entwicklung, indem vordefinierte Codeausschnitte bereitgestellt werden. In diesem Schnellstart fügen Sie einen Codeschnipsel hinzu, mit dem ein virtuelles Netzwerk erstellt wird.

Geben Sie in main.bicepvnet ein. Wählen Sie in der Liste res-vnet aus , und drücken Sie dann [TAB] oder [EINGABETASTE].

Screenshot des Hinzufügens eines Codeausschnitts für virtuelles Netzwerk.

Tipp

Wenn diese IntelliSense-Optionen in Visual Studio nicht angezeigt werden, stellen Sie sicher, dass Sie die Bicep-Erweiterung wie in den Voraussetzungen angegeben installiert haben. Wenn Sie die Erweiterung installiert haben, geben Sie dem Bicep-Sprachdienst einige Zeit, um nach dem Öffnen der Bicep-Datei zu beginnen. Der Start erfolgt in der Regel schnell, die IntelliSense-Optionen werden aber erst nach dem Start angezeigt.

Ihre Bicep-Datei enthält jetzt den folgenden Code:

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2025-01-01' = {
  name: 'name'
  location: location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

Dieser Codeausschnitt enthält alle Werte, die Sie zum Definieren eines virtuellen Netzwerks benötigen. Sie können diesen Code jedoch so ändern, dass sie Ihren Anforderungen entspricht. Zum Beispiel ist name kein großartiger Name für das virtuelle Netzwerk. Ändern Sie die name Eigenschaft in exampleVnet.

name: 'exampleVnet'

Beachten Sie, dass der Ort eine rote geschweifte Unterstreichung hat. Dies weist auf ein Problem hin. Zeigen Sie mit dem Mauszeiger auf Ort. Die Fehlermeldung lautet : Der Name "Location" ist im aktuellen Kontext nicht vorhanden. Im nächsten Abschnitt erstellen wir einen Standortparameter.

Parameter hinzufügen

Nun fügen wir zwei Parameter für den Namen des Speicherkontos und den Speicherort hinzu. Fügen Sie oben in der Datei Folgendes hinzu:

param storageName

Beachten Sie beim Hinzufügen eines Leerzeichens nach "storageName", dass IntelliSense die Datentypen bietet, die für den Parameter verfügbar sind. Wählen Sie die Zeichenfolge aus.

Screenshot des Hinzufügens von Zeichenfolgentyp zum Parameter.

Sie haben den folgenden Parameter:

param storageName string

Dieser Parameter funktioniert einwandfrei, Speicherkonten weisen jedoch Beschränkungen für die Länge des Namens auf. Der Name muss mindestens drei Zeichen und nicht mehr als 24 Zeichen enthalten. Sie können diese Anforderungen angeben, indem Sie dem Parameter Dekoratoren hinzufügen.

Fügen Sie eine Zeile oberhalb des Parameters hinzu, und geben Sie folgendes ein @. Die verfügbaren Dekorateure werden angezeigt. Beachten Sie, dass es Dekoratoren für minLength und maxLength gibt.

Screenshot des Hinzufügens von Dekoratoren zum Parameter.

Fügen Sie beide Dekoratoren hinzu, und geben Sie die Zeichenbegrenzungen an, wie unten dargestellt.

@minLength(3)
@maxLength(24)
param storageName string

Sie können auch eine Beschreibung für den Parameter hinzufügen. Fügen Sie Informationen hinzu, die den Personen, die die Bicep-Datei bereitstellen, helfen, den bereitzustellenden Wert zu verstehen.

@minLength(3)
@maxLength(24)
@description('Provide a name for the storage account. Use only lower case letters and numbers. The name must be unique across Azure.')
param storageName string

Der Parameter "Name des Speicherkontos" kann verwendet werden.

Fügen Sie einen weiteren Standortparameter hinzu:

param location string = resourceGroup().location

Ressource hinzufügen

Anstatt einen Codeausschnitt zum Definieren des Speicherkontos zu verwenden, verwenden wir IntelliSense, um die Werte festzulegen. IntelliSense macht diesen Schritt einfacher, statt die Werte manuell eingeben zu müssen.

Verwenden Sie das resource Schlüsselwort, um eine Ressource zu definieren. Geben Sie unterhalb Ihres virtuellen Netzwerks den Begriff resource exampleStorage ein:

resource exampleStorage

exampleStorage ist ein symbolischer Name für die Ressource, die Sie bereitstellen. Sie können diesen Namen verwenden, um auf die Ressource in anderen Teilen Ihrer Bicep-Datei zu verweisen.

Wenn Sie nach dem symbolischen Namen ein Leerzeichen hinzufügen, wird eine Liste der Ressourcentypen angezeigt. Setzen Sie die Eingabe des Speichers fort, bis Sie ihn aus den verfügbaren Optionen auswählen können.

Screenshot der Auswahl von Speicherkonten für den Ressourcentyp.

Nachdem Sie "Microsoft.Storage/storageAccounts" ausgewählt haben, werden ihnen die verfügbaren API-Versionen angezeigt. Wählen Sie 2021-09-01 oder die neueste API-Version aus. Wir empfehlen die Verwendung der neuesten API-Version.

Screenshot der Auswahl der API-Version für den Ressourcentyp.

Fügen Sie nach dem einfachen Anführungszeichen für den Ressourcentyp ein Leerzeichen hinzu = . Es werden Optionen zum Hinzufügen von Eigenschaften zur Ressource angezeigt. Wählen Sie die erforderlichen Eigenschaften aus.

Screenshot des Hinzufügens erforderlicher Eigenschaften.

Mit dieser Option werden alle Eigenschaften für den Ressourcentyp hinzugefügt, der für die Bereitstellung erforderlich ist. Nachdem Sie diese Option ausgewählt haben, weist Ihr Speicherkonto die folgenden Eigenschaften auf:

resource exampleStorage 'Microsoft.Storage/storageAccounts@2025-06-01' = {
	name: 1
	location: 2
	sku: {
		name: 3
	}
	kind: 4
}

Der Code enthält vier Platzhalter. Verwenden Sie [TAB], um sie zu durchlaufen und die Werte einzugeben. Auch hier hilft Ihnen IntelliSense. Setzen Sie name auf storageName, den Parameter, der einen Namen für das Speicherkonto definiert. Setzen Sie location auf location. Beim Hinzufügen von SKU-Namen und -Art stellt IntelliSense die gültigen Optionen dar.

Wenn Sie fertig sind, haben Sie Folgendes:

@minLength(3)
@maxLength(24)
@description('Provide a name for the storage account. Use only lower case letters and numbers. The name must be unique across Azure.')
param storageName string
param location string = resourceGroup().location

resource virtualNetwork 'Microsoft.Network/virtualNetworks@2025-01-01' = {
  name: storageName
  location: location
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
    subnets: [
      {
        name: 'Subnet-1'
        properties: {
          addressPrefix: '10.0.0.0/24'
        }
      }
      {
        name: 'Subnet-2'
        properties: {
          addressPrefix: '10.0.1.0/24'
        }
      }
    ]
  }
}

resource exampleStorage 'Microsoft.Storage/storageAccounts@2025-06-01' = {
  name: storageName
  location: location
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
}

Weitere Informationen zur Bicep-Syntax finden Sie unter Bicep-Struktur.

Bereitstellen der Bicep-Datei

Die Bicep-Dateibereitstellung kann noch nicht aus Visual Studio erfolgen. Sie können die Bicep-Datei mithilfe von Azure CLI oder Azure PowerShell bereitstellen:

az group create --name exampleRG --location eastus

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageName=uniquename

Nach Abschluss der Bereitstellung sollte eine Meldung mit dem Hinweis angezeigt werden, dass die Bereitstellung erfolgreich war.

Bereinigen von Ressourcen

Wenn die Azure-Ressourcen nicht mehr benötigt werden, verwenden Sie das Azure CLI- oder Azure PowerShell-Modul, um die Schnellstartressourcengruppe zu löschen.

az group delete --name exampleRG

Nächste Schritte

Erstellen von Bicep-Dateien mithilfe von Visual Studio Code

  • Last updated on