Dashboardspezifische Visuals

Alle Visualisierungen, die im Kontext des Renderoperators erstellt werden, sind in Dashboard-Visualisierungen verfügbar. Die folgenden Visualisierungen sind jedoch nur in Azure Data Explorer-Dashboards, Echtzeit-Dashboards oder Azure Data Explorer-Webbenutzeroberfläche und nicht mit dem Renderoperator verfügbar.

Informationen zum Anpassen von Dashboards visuellen Elementen finden Sie unter Anpassen von Azure Data Explorer Dashboard visuelle Elemente

Allgemeine Informationen zu Dashboards im Azure-Daten-Explorer finden Sie unter Visualisieren von Daten mit Azure Data Explorer-Dashboards.

Verkaufstrichterdiagramm

Ein Trichterdiagramm zeigt einen linearen Prozess mit aufeinanderfolgenden und miteinander verbundenen Phasen visuell dar. Jede Phase des Diagramms stellt einen prozentualen Anteil am Gesamtwert dar. Daher hat ein Trichterdiagramm in den meisten Fällen die Form eines Trichters, wobei die erste Phase am größten und jede nachfolgende Phase etwas kleiner ist.

Im folgenden Beispiel wird der Fortschritt von Serveranforderungen visualisiert, wobei die Gesamtanzahl der Sitzungen, Anforderungen und deren Abschlussstatus angezeigt wird. Er hebt die Abnahme von Sitzungen zu Anfragen und den Anteil der vollständigen im Vergleich zu unvollständigen Anfragen hervor.

Beispielabfrage

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Wärmebild

Eine Kachel zeigt Werte für eine Standard Variable von Interesse über zwei Achsenvariablen als Raster farbiger Quadrate an.

Um eine Tabelle zu rendern, muss die Abfrage eine Tabelle mit drei Spalten generieren. Die für das Wertfeld verwendeten Daten müssen numerisch sein. Die Spalten, die für x- und y-Werte verwendet werden, verwenden die folgenden Regeln:

• Wenn sich die Werte in Spalte x im string Format befinden, müssen sich die Werte in der Spalte y ebenfalls im string Format befinden.
• Wenn sich die Werte in Spalte x im datetime Format befinden, müssen die Werte in der Spalte y numerisch sein.

Das folgende Beispiel zeigt die Verteilung der fünf am häufigsten verwendeten SQL-Metriken über verschiedene Metriktypen hinweg. Es hebt hervor, welche Metriktypen für jede SQL-Metrik am häufigsten verwendet werden, wodurch die Identifizierung von Aktivitätsmustern in den wichtigsten Metriken erleichtert wird.

Beispielabfrage

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count