Freigeben über

Schnellstart: Bereitstellen eines Azure DocumentDB-Clusters mit Bicep

In dieser Schnellstartanleitung stellen Sie einen neuen Azure DocumentDB-Cluster mit Bicep bereit. Diese Schnellstartanleitung enthält schrittweise Anleitungen, mit denen Sie schnell beginnen können. Dieser Cluster enthält alle Ihre MongoDB-Ressourcen: Datenbanken, Sammlungen und Dokumente. Es stellt einen eindeutigen Endpunkt für Tools und Software Development Kits (SDKs) bereit, um eine Verbindung mit Azure DocumentDB herzustellen und Vorgänge auszuführen.

Voraussetzungen

  • Ein Azure-Abonnement

    • Wenn Sie nicht über ein Azure-Abonnement verfügen, erstellen Sie ein kostenloses Konto

Konfigurieren der Umgebung

Richten Sie Ihre Azure CLI-Umgebung ein, um Azure DocumentDB-Ressourcen in Ihrem Abonnement zu verwalten.

  1. Beginnen Sie in einem leeren Verzeichnis.

  2. Melden Sie sich bei Azure CLI an.

    az login

  3. Überprüfen Sie Ihr Azure-Zielabonnement.

    az account show

    Hinweis

    Wenn Sie nicht mit dem erwarteten Abonnement verbunden sind, verwenden Sie diesen Befehl, um Ihr Abonnement zu ändern:

    az account set --subscription "<subscription-name>"

    Weitere Informationen finden Sie unter Verwalten von Azure-Abonnements mit der Azure CLI.

Vorbereiten der Vorlage "Bicep"

Erstellen und konfigurieren Sie eine Bicep-Datei, um die ressourcen zu definieren, die für die Bereitstellung eines Azure DocumentDB-Clusters erforderlich sind.

  1. Erstellen Sie eine neue datei "main.bicep " in Ihrem Projektverzeichnis.

  2. Fügen Sie diese Vorlage dem Inhalt der Datei hinzu.

    @description('Cluster name')
@minLength(8)
@maxLength(40)
param clusterName string = 'msdocs-${uniqueString(resourceGroup().id)}'

@description('Location for the cluster.')
param location string = resourceGroup().location

@description('Username for admin user')
param adminUsername string

@secure()
@description('Password for admin user')
@minLength(8)
@maxLength(128)
param adminPassword string

resource cluster 'Microsoft.DocumentDB/mongoClusters@2025-09-01' = {
  name: clusterName
  location: location
  properties: {
    administrator: {
      userName: adminUsername
      password: adminPassword
    }
    serverVersion: '8.0'
    sharding: {
      shardCount: 1
    }
    storage: {
      sizeGb: 32
    }
    highAvailability: {
      targetMode: 'Disabled'
    }
    compute: {
      tier: 'M10'
    }
  }
}

resource firewallRules 'Microsoft.DocumentDB/mongoClusters/firewallRules@2025-09-01' = {
  parent: cluster
  name: 'AllowAllAzureServices'
  properties: {
    startIpAddress: '0.0.0.0'
    endIpAddress: '0.0.0.0'
  }
}

    Tipp

    Weitere Informationen zu Optionen, die die Ressource Microsoft.DocumentDB/mongoclusters verwenden, finden Sie in der Microsoft.DocumentDB/mongoclustersDokumentation.

Implementieren der Vorlage

Stellen Sie die im vorherigen Schritt erstellte Vorlage mithilfe einer Azure Resource Manager-Bereitstellung bereit.

  1. Verwenden Sie den az group create Befehl, um eine neue Ressourcengruppe in Ihrem Abonnement zu erstellen.

    az group create \
    --name "<resource-group-name>" \
    --location "<location>"

  2. Verwenden Sie az deployment group create, um die Bicep-Vorlage bereitzustellen. Sie werden dann aufgefordert, einen Wert für die Parameter adminUsername und adminPassword einzugeben.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep'

    Tipp

    Alternativ können Sie die --parameters Option verwenden, um eine Parameterdatei mit vordefinierten Werten zu übergeben.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep' \
    --parameters @main.parameters.json

    Dieses JSON-Beispieldatei injiziert clusteradmin- und P@ssw.rd-Werte für die adminUsername- und adminPassword-Parameter.

    {
  "$schema": "https://schema.management.azure.com/schemas/2015-01-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "adminUsername": {
      "value": "clusteradmin"
    },
    "adminPassword": {
      "value": "P@ssw.rd"
    }
  }
}

  3. Warten Sie, bis der Bereitstellungsvorgang abgeschlossen ist, bevor Sie fortfahren.

Überprüfen der bereitgestellten Ressourcen

Listen Sie die in Ihrer Ressourcengruppe bereitgestellten Azure DocumentDB-Ressourcen auf.

  1. Verwenden Sie az resource list, um eine Liste von Ressourcen in Ihrer Ressourcengruppe abzurufen.

    az resource list \
    --resource-group "<resource-group-name>" \
    --namespace "Microsoft.DocumentDB" \
    --resource-type "mongoClusters" \
    --query "[].name" \
    --output json

  2. Suchen Sie in der Beispielausgabe nach Ressourcen mit einem Typ von Microsoft.DocumentDB/mongoClusters. Hier ist ein Beispiel für den erwarteten Ausgabetyp:

    [
  "msdocs-documentdb-example-cluster"
]

Bereinigen von Ressourcen

Wenn Sie mit Ihrem Azure DocumentDB-Cluster fertig sind, können Sie die azure-Ressourcen löschen, die Sie erstellt haben, damit keine weiteren Gebühren anfallen.

  1. Verwenden Sie az group delete, um die Ressourcengruppe aus Ihrem Abonnement zu entfernen.

    az group delete \
    --name "<resource-group-name>" \
    --yes \
    --no-wait

    Von Bedeutung

    Stellen Sie sicher, dass Sie die Ressourcen nicht mehr benötigen, bevor Sie diesen Befehl ausführen, da sie endgültig gelöscht werden.

Verwandte Inhalte

  • Last updated on