Plug-In „bag_unpack“

Gilt für: ✅Microsoft Fabric✅Azure Data Explorer

Das bag_unpack Plug-In entpackt eine einzelne Spalte vom Typ dynamic, indem jeder Eigenschaftenbehälter auf oberster Ebene als Spalte behandelt wird. Das Plug-In wird mit dem evaluate Operator aufgerufen.

Syntax

T|evaluatebag_unpack( Column [,OutputColumnPrefix ] [,columnsConflict ] [,ignoredProperties ] ) [:OutputSchema]

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Ausgabeschemasyntax

( ColumnName:ColumnType [, ...])

Verwenden Sie einen Wildcard * als ersten Parameter, um alle Spalten der Quelltabelle in die Ausgabe einzuschließen:

( * , ColumnName:ColumnType [, ...])

Leistungsüberlegungen

Die Verwendung des Plug-Ins ohne OutputSchema kann schwerwiegende Leistungsauswirkungen in großen Datasets haben und sollte vermieden werden.

Wenn Sie ein OutputSchema bereitstellen, kann das Abfragemodul die Abfrageausführung optimieren, da es das Ausgabeschema bestimmen kann, ohne die Eingabedaten analysieren und analysieren zu müssen. OutputSchema ist von Vorteil, wenn die Eingabedaten groß oder komplex sind. Sehen Sie sich die Beispiele mit Leistungsauswirkungen der Verwendung des Plug-Ins mit und ohne ein definiertes OutputSchema an.

Gibt zurück

Das bag_unpack Plug-In gibt eine Tabelle mit so vielen Datensätzen wie die tabellarische Eingabe (T) zurück. Das Schema der Tabelle entspricht dem Schema der tabellarischen Eingabe mit den folgenden Änderungen:

• Die angegebene Eingabespalte (Spalte) wird entfernt.
• Der Name jeder Spalte entspricht dem Namen jedes Steckplatzes, optional präfix von OutputColumnPrefix.
• Der Typ jeder Spalte ist entweder der Typ des Steckplatzes, wenn alle Werte desselben Steckplatzes denselben Typ aufweisen, oder dynamic, wenn sich die Werte in Typ unterscheiden.
• Das Schema wird um so viele Spalten erweitert, wie es unterschiedliche Steckplätze in den Werten des Eigenschaftenbehälters der obersten Ebene von T gibt.

Tabellarische Schemaregeln gelten für die Eingabedaten. Dies gilt insbesondere für:

• Ein Ausgabespaltenname kann nicht mit einer vorhandenen Spalte in der tabellarischen Eingabe T identisch sein, es sei denn, es handelt sich um die Spalte zum Entpacken (Spalte). Andernfalls enthält die Ausgabe zwei Spalten mit demselben Namen.
• Alle Slotnamen müssen bei präfix "OutputColumnPrefix" gültige Entitätsnamen sein und den Benennungsregeln für Bezeichner entsprechen.

Das Plug-In ignoriert NULL-Werte.

Beispiele

Die Beispiele in diesem Abschnitt zeigen, wie Sie die Syntax verwenden, um Ihnen den Einstieg zu erleichtern.

Erweitern einer Tasche:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({"Name": "Dave", "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d)

Ausgabe

Erweitern Sie eine Tasche, und verwenden Sie die OutputColumnPrefix Option, um Spaltennamen mit einem Präfix zu erstellen:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({"Name": "Dave", "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, 'Property_')

Ausgabe

Erweitern Sie einen Beutel, und verwenden Sie die columnsConflict Option, um einen Spaltenkonflikt zwischen der dynamischen Spalte und der vorhandenen Spalte zu lösen:

datatable(Name:string, d:dynamic)
[
    'James', dynamic({"Name": "John", "Age":20}),
    'David', dynamic({ "Age":40}),
    'Emily', dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, columnsConflict='replace_source') // Replace old column Name by new column

Ausgabe

datatable(Name:string, d:dynamic)
[
    'James', dynamic({"Name": "John", "Age":20}),
    'David', dynamic({"Name": "Dave", "Age":40}),
    'Emily', dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d, columnsConflict='keep_source') // Keep old column Name

Ausgabe

Erweitern Sie eine Tasche, und verwenden Sie die ignoredProperties Option, 2 der Eigenschaften im Eigenschaftenbehälter zu ignorieren:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20, "Address": "Address-1" }),
    dynamic({"Name": "Dave", "Age":40, "Address": "Address-2"}),
    dynamic({"Name": "Jasmine", "Age":30, "Address": "Address-3"}),
]
// Ignore 'Age' and 'Address' properties
| evaluate bag_unpack(d, ignoredProperties=dynamic(['Address', 'Age']))

Ausgabe

Erweitern Sie einen Beutel, und verwenden Sie die Option OutputSchema:

datatable(d:dynamic)
[
    dynamic({"Name": "John", "Age":20}),
    dynamic({ "Name": "Dave", "Height": 170, "Age":40}),
    dynamic({"Name": "Jasmine", "Age":30}),
]
| evaluate bag_unpack(d)

Ausgabe

Erweitern Sie einen Beutel mit einem OutputSchema , und verwenden Sie die Option "Wildcard * ":

Diese Abfrage gibt die ursprüngliche Platzbeschreibung und die spalten zurück, die im OutputSchema definiert sind.

datatable(d:dynamic, Description: string)
[
    dynamic({"Name": "John", "Age":20, "height":180}), "Student",
    dynamic({"Name": "Dave", "Age":40, "height":160}), "Teacher",
    dynamic({"Name": "Jasmine", "Age":30, "height":172}), "Student",
]
| evaluate bag_unpack(d) : (*, Name:string, Age:long)

Ausgabe

Beispiele mit Leistungsauswirkungen

Erweitern Sie einen Beutel mit und ohne ein definiertes OutputSchema , um Leistungsauswirkungen zu vergleichen:

In diesem Beispiel wird eine öffentlich verfügbare Tabelle im Hilfecluster verwendet. In der ContosoSales-Datenbank gibt es eine Tabelle namens "SalesDynamic". Die Tabelle enthält Umsatzdaten und enthält eine dynamische Spalte mit dem Namen Customer_Properties.

• Beispiel ohne Ausgabeschema: Die erste Abfrage definiert kein OutputSchema. Die Abfrage benötigt 5,84 Sekunden CPU und scannt 36,39 MB Daten.

  Abfrage ausführen

  SalesDynamic
  | evaluate bag_unpack(Customer_Properties) 
  | summarize Sales=sum(SalesAmount) by Country, State
  

• Beispiel mit Ausgabeschema: Die zweite Abfrage stellt ein OutputSchema bereit. Die Abfrage benötigt 0,45 Sekunden CPU und scannt 19,31 MB Daten. Die Abfrage muss die Eingabetabelle nicht analysieren, was die Verarbeitungszeit spart.

  Abfrage ausführen

  SalesDynamic
  | evaluate bag_unpack(Customer_Properties) :  (*, Country:string, State:string, City:string)
  | summarize Sales=sum(SalesAmount) by Country, State
  

Ausgabe

Die Ausgabe ist für beide Abfragen identisch. Die ersten 10 Zeilen der Ausgabe werden unten angezeigt.

Verwandte Inhalte

• parse_json Funktion
• mv-expand-Operator
• Pack-All-Funktion