Field2.Expression-Eigenschaft (DAO)

Gilt für: Access 2013, Office 2013

Ruft einen Ausdruck ab, der die Formel für ein berechnetes Feld darstellt, oder legt diesen fest. Zeichenfolge mit Lese-/Schreibzugriff.

Informationen zur Version

Hinzugefügte Version: Access 2010

Syntax

Ausdruck . Ausdruck

Ausdruck Eine Variable, die ein Field2-Objekt darstellt.

Hinweise

In Access 2013 können Sie Tabellenfelder erstellen, die Werte berechnen. Die Berechnungen können Werte aus Feldern in derselben Tabelle sowie integrierte Access-Funktionen enthalten.

Die Berechnung darf keine Felder aus anderen Tabellen oder Abfragen enthalten.

Die Ergebnisse der Berechnung sind schreibgeschützt.

Beispiel

Im folgenden Beispiel wird veranschaulicht, wie Sie ein berechnetes Feld erstellen. Die CreateField-Methode erstellt ein Feld namens FullName. Die Expression-Eigenschaft wird dann auf den Ausdruck festgelegt, der den Wert des Felds berechnet.

Der Beispielcode stammt von:Microsoft Access 2010 Programmer's Reference.

    Sub CreateCalculatedField()
        Dim dbs As DAO.Database
        Dim tdf As DAO.TableDef
        Dim fld As DAO.Field2
        
        ' get the database
        Set dbs = CurrentDb()
        
        ' create the table
        Set tdf = dbs.CreateTableDef("tblContactsCalcField")
        
        ' create the fields: first name, last name
        tdf.Fields.Append tdf.CreateField("FirstName", dbText, 20)
        tdf.Fields.Append tdf.CreateField("LastName", dbText, 20)
        
        ' create the calculated field: full name
        Set fld = tdf.CreateField("FullName", dbText, 50)
        fld.Expression = "[FirstName] & "" "" & [LastName]"
        tdf.Fields.Append fld
        
        ' append the table and cleanup
        dbs.TableDefs.Append tdf
        
    Cleanup:
        Set fld = Nothing
        Set tdf = Nothing
        Set dbs = Nothing
    End Sub