Recordset2.Restartable-Eigenschaft (DAO)

Gilt für: Access 2013, Office 2013

Gibt einen Wert zurück, der angibt, ob ein Recordset -Objekt die Requery -Methode unterstützt, die die Abfrage, auf der das Recordset-Objekt basiert, erneut ausführt.

Syntax

Ausdruck . Neustartbar

Ausdruck Eine Variable, die ein Recordset2-Objekt darstellt.

Hinweise

Table-type Recordset objects always return False.

Überprüfen Sie die Restartable-Eigenschaft vor der Verwendung der Requery-Methode für ein Recordset-Objekt. Wenn die Restartable-Eigenschaft des Objekts den Wert False hat, verwenden Sie die OpenRecordset -Methode für das zugrunde liegende QueryDef -Objekt, um die Abfrage erneut auszuführen.

Beispiel

Dieses Beispiel veranschaulicht die Restartable-Eigenschaft für verschiedene Recordset-Objekte.

    Sub RestartableX()
    
       Dim dbsNorthwind As Database
       Dim rstTemp As Recordset2
    
       Set dbsNorthwind = OpenDatabase("Northwind.mdb")
    
       With dbsNorthwind
          ' Open a table-type Recordset and print its 
          ' Restartable property.
          Set rstTemp = .OpenRecordset("Employees", dbOpenTable)
          Debug.Print _
             "Table-type recordset from Employees table"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          ' Open a Recordset from an SQL statement and print its 
          ' Restartable property.
          Set rstTemp = _
             .OpenRecordset("SELECT * FROM Employees")
          Debug.Print "Recordset based on SQL statement"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          ' Open a Recordset from a saved QueryDef object and 
          ' print its Restartable property.
          Set rstTemp = .OpenRecordset("Current Product List")
          Debug.Print _
             "Recordset based on permanent QueryDef (" & _
             rstTemp.Name & ")"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          .Close
       End With
    
    End Sub