Freigeben über

TableDef.CreateField-Methode (DAO)

Gilt für: Access 2013 | Office 2013

Erstellt ein neues Field-Objekt (nur Microsoft Access-Arbeitsbereiche).

Syntax

Ausdruck .CreateField(Name, Type, Size)

Ausdruck Eine Variable, die ein TableDef-Objekt darstellt.

Parameter

Name

Erforderlich/optional

Datentyp

Beschreibung

Name

Optional

Variant

Eine Zeichenfolge, die das neue Field -Objekt eindeutig benennt. Unter der Name -Eigenschaft finden Sie Einzelheiten zu gültigen Field -Namen.

Type

Optional

Variant

Eine Konstante, die den Datentyp des neuen Field -Objekts bestimmt. Unter der Type -Eigenschaft finden Sie gültige Datentypen.

Size

Optional

Variant

Eine ganze Zahl, die die maximale Größe eines Field-Objekts, das Text enthält, in Bytes angibt. Unter der Size-Eigenschaft finden Sie gültige Werte für size. Dieses Argument wird für numerische Felder und Felder mit fester Breite ignoriert.

Rückgabewert

Feld

Hinweise

Mit der CreateField-Methode können Sie ein neues Feld erstellen und den Namen, den Datentyp sowie die Größe des Felds angeben. Wenn Sie einen oder mehrere der optionalen Teile für CreateField weglassen, können Sie die entsprechende Eigenschaft mithilfe einer entsprechenden Zuweisungsanweisung festlegen oder zurücksetzen, bevor Sie das neue Objekt an eine Auflistung anfügen. Nachdem Sie das neue Objekt angefügt haben, können Sie dessen Eigenschafteneinstellungen zum Teil ändern. Weitere Informationen finden Sie in den Themen zu den einzelnen Eigenschaften.

Die Argumente Typ und Größe gelten nur für Field-Objekte in einem TableDef-Objekt. Diese Argumente werden ignoriert, wenn ein Field-Objekt einem Index- oder Relation-Objekt zugeordnet ist.

Bezieht sich Name auf ein Objekt, das bereits ein Element der Auflistung ist, tritt ein Laufzeitfehler auf, wenn Sie die Append-Methode verwenden.

Um ein Field -Objekt aus einer Fields -Auflistung zu entfernen, führen Sie die Delete -Methode für die Auflistung aus. Sie können ein Field-Objekt nicht mehr aus der Fields-Auflistung eines TableDef-Objekts löschen, nachdem Sie einen Index erstellt haben, der auf das Feld verweist.

Link zur Verfügung gestellt von: UtterAccess-Community. UtterAccess ist das führende Microsoft Access-Wiki und -Hilfeforum.

Beispiel

Im folgenden Beispiel wird veranschaulicht, wie Sie ein berechnetes Feld erstellen. Die CreateField-Methode erstellt ein Feld namens FullName. Die Expression-Eigenschaft wird dann auf den Ausdruck festgelegt, der den Wert des Felds berechnet.

Der Beispielcode stammt von:Microsoft Access 2010 Programmer's Reference.

    Sub CreateCalculatedField()
        Dim dbs As DAO.Database
        Dim tdf As DAO.TableDef
        Dim fld As DAO.Field2
        
        ' get the database
        Set dbs = CurrentDb()
        
        ' create the table
        Set tdf = dbs.CreateTableDef("tblContactsCalcField")
        
        ' create the fields: first name, last name
        tdf.Fields.Append tdf.CreateField("FirstName", dbText, 20)
        tdf.Fields.Append tdf.CreateField("LastName", dbText, 20)
        
        ' create the calculated field: full name
        Set fld = tdf.CreateField("FullName", dbText, 50)
        fld.Expression = "[FirstName] & "" "" & [LastName]"
        tdf.Fields.Append fld
        
        ' append the table and cleanup
        dbs.TableDefs.Append tdf
        
    Cleanup:
        Set fld = Nothing
        Set tdf = Nothing
        Set dbs = Nothing
    End Sub
  • Last updated on