Hinweis
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, sich anzumelden oder das Verzeichnis zu wechseln.
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, das Verzeichnis zu wechseln.
Stellt einen Satz Dienstprogramme für das Freigeben von Kalenderinformationen dar.
Hinweise
Verwenden Sie die GetCalendarExporter-Methode eines Folder-Objekts , das einen Kalenderordner darstellt, um ein CalendarSharing-Objekt zu erstellen. GetCalendarExporter -Methode kann nur für Kalenderordner verwendet werden. Ein Fehler tritt auf, wenn Sie die Methode für Folder -Objekten verwenden, die andere Ordnertypen darstellen.
Verwenden Sie die SaveAsICal-Methode , um Kalenderinformationen in einer iCalendar-Datei (.ics) zum Freigeben eines Kalenders als URL zu speichern, oder verwenden Sie die ForwardAsICal-Methode , um ein MailItem-Objekt zum Freigeben eines Kalenders als Nutzlast zu erstellen.
Hinweis
Das CalendarSharing-Objekt unterstützt nur das Exportieren des iCalendar-Dateiformats.
Beispiel
Im folgenden beispiel für Visual Basic for Applications (VBA) wird ein CalendarSharing-Objekt für den Kalenderordner erstellt und anschließend der Inhalt des gesamten Ordners (einschließlich Anlagen und privaten Elementen) in eine iCalendar-Kalenderdatei (.ics) exportiert.
Public Sub ExportEntireCalendar()
Dim oNamespace As NameSpace
Dim oFolder As Folder
Dim oCalendarSharing As CalendarSharing
On Error GoTo ErrRoutine
' Get a reference to the Calendar default folder
Set oNamespace = Application.GetNamespace("MAPI")
Set oFolder = oNamespace.GetDefaultFolder(olFolderCalendar)
' Get a CalendarSharing object for the Calendar default folder.
Set oCalendarSharing = oFolder.GetCalendarExporter
' Set the CalendarSharing object to export the contents of
' the entire Calendar folder, including attachments and
' private items, in full detail.
With oCalendarSharing
.CalendarDetail = olFullDetails
.IncludeAttachments = True
.IncludePrivateDetails = True
.IncludeWholeCalendar = True
End With
' Export calendar to an iCalendar calendar (.ics) file.
oCalendarSharing.SaveAsICal "C:\SampleCalendar.ics"
EndRoutine:
On Error GoTo 0
Set oCalendarSharing = Nothing
Set oFolder = Nothing
Set oNamespace = Nothing
Exit Sub
ErrRoutine:
Select Case Err.Number
Case 287 ' &H0000011F
' The user denied access to the Address Book.
' This error occurs if the code is run by an
' untrusted application, and the user chose not to
' allow access.
MsgBox "Access to Outlook was denied by the user.", _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case -2147467259 ' &H80004005
' Export failed.
' This error typically occurs if the CalendarSharing
' method cannot export the calendar information because
' of conflicting property settings.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case -2147221233 ' &H8004010F
' Operation failed.
' This error typically occurs if the GetCalendarExporter method
' is called on a folder that doesn't contain calendar items.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case Else
' Any other error that may occur.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
End Select
GoTo EndRoutine
End Sub
Methoden
| Name |
|---|
| ForwardAsICal |
| SaveAsICal |
Eigenschaften
| Name |
|---|
| Application |
| CalendarDetail |
| Class |
| EndDate |
| Ordner |
| IncludeAttachments |
| IncludePrivateDetails |
| IncludeWholeCalendar |
| Parent |
| RestrictToWorkingHours |
| Session |
| StartDate |
Siehe auch
Support und Feedback
Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.