Erstellen Ihres ersten Connectors: Hello World

Dieses Beispiel bietet eine einfache Datenquellenerweiterung, die in Visual Studio Code ausgeführt und in Power BI Desktop geladen werden kann.

Hello World-Beispiel

Als Übersicht zeigt dieses Beispiel:

• Exportfunktion (HelloWorld.Contents), die einen Optionstextparameter verwendet.
• Definieren einer Datenquellenart, die:
  • Deklariert, dass die implizite (anonyme) Authentifizierung verwendet wird.
  • Verwendet Zeichenfolgenressourcen, die die Lokalisierung ermöglichen.
  • Deklarieren von UI-Metadaten, damit die Erweiterung im Power BI Desktop Get Data-Dialogfeld angezeigt werden kann.

Erstellen Sie nach den Anweisungen zum Installieren des PowerQuery SDK einen neuen Connector namens "HelloWorld", kopieren Sie den folgenden M-Code, fügen Sie ihn in die Datei "HelloWorld.pq" Ihres Connectorarbeitsbereichs ein, und folgen Sie dann den restlichen Anweisungen, um ihn in Power BI öffnen zu können.

In der folgenden Connectordefinition finden Sie:

• Eine section Anweisung.
• Eine Datenquellenfunktion mit Metadaten, die sie als Datenquellen-Definition mit dem Typ HelloWorld und veröffentlichen HelloWorld.Publish festlegt.
• Ein Authentication Datensatz, der deklariert, dass implizit (anonym) der einzige Authentifizierungstyp für diese Quelle ist.
• Ein Veröffentlichungsdatensatz, der angibt, dass sich diese Verbindung in der Beta-Phase befindet, welchen Text aus der RESX-Datei geladen werden soll, sowie das Quellbild und den Quellbildtyp.
• Eine Zuordnung, die Symbolgrößen bestimmten PNG-Dateien im Build-Ordner zuweist.

section HelloWorld;
 
[DataSource.Kind="HelloWorld", Publish="HelloWorld.Publish"]
shared HelloWorld.Contents = (optional message as text) =>
    let
        message = if (message <> null) then message else "Hello world"
    in
        message;
 
HelloWorld = [
    Authentication = [
        Implicit = []
    ],
    Label = Extension.LoadString("DataSourceLabel")
];
 
HelloWorld.Publish = [
    Beta = true,
    ButtonText = { Extension.LoadString("FormulaTitle"), Extension.LoadString("FormulaHelp") },
    SourceImage = HelloWorld.Icons,
    SourceTypeImage = HelloWorld.Icons
];
 
HelloWorld.Icons = [
    Icon16 = { Extension.Contents("HelloWorld16.png"), Extension.Contents("HelloWorld20.png"), Extension.Contents("HelloWorld24.png"), Extension.Contents("HelloWorld32.png") },
    Icon32 = { Extension.Contents("HelloWorld32.png"), Extension.Contents("HelloWorld40.png"), Extension.Contents("HelloWorld48.png"), Extension.Contents("HelloWorld64.png") }
];

Nachdem Sie die Datei erstellt und in das richtige Verzeichnis kopiert haben, öffnen Sie Power BI, indem Sie die Anweisungen im Lernprogramm zum Installieren des PowerQuery SDK befolgen. Sie können im Dialogfeld " Daten abrufen " nach "Hello" suchen, um Ihren Connector zu finden.

In diesem Schritt wird ein Authentifizierungsdialogfeld angezeigt. Da keine Authentifizierungsoptionen vorhanden sind und die Funktion keine Parameter verwendet, gibt es keine weiteren Schritte in diesen Dialogfeldern.

Drücken Sie "Verbinden" und das Dialogfeld teilt Ihnen mit, dass es sich um einen Vorschau-Connector handelt, da Beta er in der Abfrage auf "true" festgelegt ist. Da keine Authentifizierung vorhanden ist, zeigt der Authentifizierungsbildschirm eine Registerkarte für die anonyme Authentifizierung ohne Felder an. Drücken Sie erneut verbinden , um den Vorgang abzuschließen.

Schließlich wird im Abfrage-Editor angezeigt, was Sie erwarten – eine Funktion, die den Text "Hello world" zurückgibt.

Das vollständig implementierte Beispiel finden Sie im Hello World-Beispiel im Datenconnectors-Beispiel-Repository.