PerformanceCounterCategory.GetInstanceNames-Methode

Ruft die Liste der Leistungsobjektinstanzen ab, die dieser Kategorie zugeordnet sind.

Namespace: System.Diagnostics
Assembly: System (in system.dll)

Syntax

'Declaration
Public Function GetInstanceNames As String()
'Usage
Dim instance As PerformanceCounterCategory
Dim returnValue As String()

returnValue = instance.GetInstanceNames

public string[] GetInstanceNames ()

public:
array<String^>^ GetInstanceNames ()

public String[] GetInstanceNames ()

public function GetInstanceNames () : String[]

Rückgabewert

Ein Array von Zeichenfolgen, das die Namen der Leistungsobjektinstanzen darstellt, die dieser Kategorie zugeordnet sind, oder, wenn die Kategorie nur eine Leistungsobjektinstanz enthält, ein Array mit einzelnem Eintrag, das eine leere Zeichenfolge ("") enthält.

Ausnahmen

Beispiel

Im folgenden Codebeispiel wird eine Liste der PerformanceCounter-Objekte in einer PerformanceCounterCategory abgerufen. Zuerst wird abhängig davon, ob ein Computername angegeben wurde, eine PerformanceCounterCategory mit dem entsprechenden Konstruktor erstellt. Dann wird GetInstanceNames verwendet, um die Instanznamen als Array von String zurückzugeben, das sortiert und angezeigt wird.

Sub Main(ByVal args() As String)
    Dim categoryName As String = ""
    Dim machineName As String = ""
    Dim pcc As PerformanceCounterCategory
    Dim instances() As String

    ' Copy the supplied arguments into the local variables.
    Try
        categoryName = args(0)
        machineName = IIf(args(1) = ".", "", args(1))
    Catch ex As Exception
        ' Ignore the exception from non-supplied arguments.
    End Try

    Try
        ' Create the appropriate PerformanceCounterCategory object.
        If machineName.Length > 0 Then
            pcc = New PerformanceCounterCategory(categoryName, machineName)
        Else
            pcc = New PerformanceCounterCategory(categoryName)
        End If

        ' Get the instances associated with this category.
        instances = pcc.GetInstanceNames()

    Catch ex As Exception
        Console.WriteLine("Unable to get instance information for " & _
             "category ""{0}"" on " & IIf(machineName.Length > 0, _
             "computer ""{1}"":", "this computer:"), _
             categoryName, machineName)
        Console.WriteLine(ex.Message)
        Return
    End Try

    'If an empty array is returned, the category has a single instance.
    If instances.Length = 0 Then
        Console.WriteLine( _
            "Category ""{0}"" on " & IIf(machineName.Length > 0, _
            "computer ""{1}""", "this computer") & _
            " is single-instance.", pcc.CategoryName, pcc.MachineName)
    Else
        ' Otherwise, display the instances.
        Console.WriteLine( _
            "These instances exist in category ""{0}"" on " & _
            IIf(machineName.Length > 0, _
                "computer ""{1}"".", "this computer:"), _
            pcc.CategoryName, pcc.MachineName)

        Array.Sort(instances)
        Dim objX As Integer
        For objX = 0 To instances.Length - 1
            Console.WriteLine("{0,4} - {1}", objX + 1, instances(objX))
        Next objX
    End If
End Sub

Plattformen

Windows 98, Windows 2000 SP4, Windows Server 2003, Windows XP Media Center Edition, Windows XP Professional x64 Edition, Windows XP SP2, Windows XP Starter Edition

.NET Framework unterstützt nicht alle Versionen sämtlicher Plattformen. Eine Liste der unterstützten Versionen finden Sie unter Systemanforderungen.

Versionsinformationen

.NET Framework

Unterstützt in: 2.0, 1.1, 1.0

Siehe auch

Referenz

PerformanceCounterCategory-Klasse
PerformanceCounterCategory-Member
System.Diagnostics-Namespace
CategoryName
PerformanceCounter.InstanceName-Eigenschaft
PerformanceCounter-Klasse