TextWriterTraceListener-Konstruktor (TextWriter, String)

Initialisiert eine neue Instanz der TextWriterTraceListener-Klasse mit dem angegebenen Namen und unter Verwendung des angegebenen Writers als Empfänger der Ablaufverfolgungs- oder Debugausgabe.

Namespace: System.Diagnostics
Assembly: System (in system.dll)

Syntax

'Declaration
Public Sub New ( _
    writer As TextWriter, _
    name As String _
)
'Usage
Dim writer As TextWriter
Dim name As String

Dim instance As New TextWriterTraceListener(writer, name)

public TextWriterTraceListener (
    TextWriter writer,
    string name
)

public:
TextWriterTraceListener (
    TextWriter^ writer, 
    String^ name
)

public TextWriterTraceListener (
    TextWriter writer, 
    String name
)

public function TextWriterTraceListener (
    writer : TextWriter, 
    name : String
)

Parameter

• writer
  Ein TextWriter, der die Ausgabe vom TextWriterTraceListener empfängt.

• name
  Der Name der neuen Instanz.

Ausnahmen

Beispiel

Im folgenden Codebeispiel wird ein TextWriterTraceListener mit dem TextWriterTraceListener(TextWriter,String)-Konstruktor erstellt. Im Beispiel wird ein StreamWriter erstellt. Anschließend wird auf StreamWriter verwiesen, wenn der TextWriterTraceListener erstellt wird. Dieser wird dann zur TraceListenerCollection hinzugefügt. In diesen TextWriterTraceListener werden zwei Meldungen und in alle TraceListener-Objekte in TraceListenerCollection eine Meldung geschrieben. Schließlich wird TextWriterTraceListener geleert und geschlossen.

Imports System
Imports System.Diagnostics
Imports System.IO
Imports Microsoft.VisualBasic

Module TWTLConWriterNameMod

    Const LISTENER_NAME As String = "myWriterListener"

    ' args(0) is the specification of the trace log file.
    Sub Main(ByVal args() As String)

        ' Verify that a parameter was entered.
        If args.Length = 0 Then
            Console.WriteLine("Enter a trace file specification.")

        Else
            ' Create a StreamWriter object that supports appending.
            Dim traceWriter As StreamWriter
            Try
                traceWriter = New StreamWriter(args(0), True)
            Catch ex As Exception
                Console.WriteLine( _
                    "Error creating StreamWriter for trace file ""{0}"":" & _
                    vbCrLf & "{1}", args(0), ex.Message)
                Return
            End Try

            ' Create a TextWriterTraceListener that takes a StreamWriter.
            Dim textListener As TextWriterTraceListener
            textListener = _
                New TextWriterTraceListener(traceWriter, LISTENER_NAME)
            Trace.Listeners.Add(textListener)

            ' Write these messages only to this TextWriterTraceListener.
            textListener.WriteLine( _
                "This is trace listener named """ & textListener.Name & """")
            textListener.WriteLine( _
                "Trace written through a stream to: " & _
                vbCrLf & "    """ & args(0) & """")

            ' Write a message to all trace listeners.
            Trace.WriteLine(String.Format( _
                "This trace message written {0} to all listeners.", Now))

            ' Flush and close the output.
            Trace.Flush()
            textListener.Flush()
            textListener.Close()
        End If
    End Sub
End Module

Plattformen

Windows 98, Windows 2000 SP4, Windows Millennium Edition, Windows Server 2003, Windows XP Media Center Edition, Windows XP Professional x64 Edition, Windows XP SP2, Windows XP Starter Edition

.NET Framework unterstützt nicht alle Versionen sämtlicher Plattformen. Eine Liste der unterstützten Versionen finden Sie unter Systemanforderungen.

Versionsinformationen

.NET Framework

Unterstützt in: 2.0, 1.1, 1.0

Siehe auch

Referenz

TextWriterTraceListener-Klasse
TextWriterTraceListener-Member
System.Diagnostics-Namespace
TraceListener
DefaultTraceListener-Klasse
ConsoleTraceListener-Klasse
EventLogTraceListener-Klasse
TextWriterTraceListener-Klasse
Stream
TextWriter
Debug-Klasse
Trace