TextWriterTraceListener-Konstruktor (Stream, String)

Initialisiert eine neue Instanz der TextWriterTraceListener-Klasse mit dem angegebenen Namen und unter Verwendung des Streams als Empfänger der Debug- oder Ablaufverfolgungsausgabe.

Namespace: System.Diagnostics
Assembly: System (in system.dll)

Syntax

'Declaration
Public Sub New ( _
    stream As Stream, _
    name As String _
)
'Usage
Dim stream As Stream
Dim name As String

Dim instance As New TextWriterTraceListener(stream, name)

public TextWriterTraceListener (
    Stream stream,
    string name
)

public:
TextWriterTraceListener (
    Stream^ stream, 
    String^ name
)

public TextWriterTraceListener (
    Stream stream, 
    String name
)

public function TextWriterTraceListener (
    stream : Stream, 
    name : String
)

Parameter

• stream
  Ein Stream, der den Stream darstellt, in den der TextWriterTraceListener schreibt.

• name
  Der Name der neuen Instanz.

Ausnahmen

Hinweise

Dieser Konstruktor initialisiert die Name-Eigenschaft mit dem name-Parameter oder einer leeren Zeichenfolge (""), wenn der name-Parameter NULL (Nothing in Visual Basic) ist.

Beispiel

Im folgenden Codebeispiel wird ein TextWriterTraceListener mit dem TextWriterTraceListener(Stream,String)-Konstruktor erstellt und zu TraceListenerCollection hinzugefügt. Anschließend werden in diesen TextWriterTraceListener zwei Meldungen und in alle TraceListener-Objekte in TraceListenerCollection eine Meldung geschrieben. Schließlich wird TextWriterTraceListener geleert und geschlossen.

Imports System
Imports System.Diagnostics
Imports System.IO
Imports Microsoft.VisualBasic

Module TWTLConStreamNameMod

    Const LISTENER_NAME As String = "myStreamListener"

    ' args(0) is the specification of the trace log file.
    Sub Main(ByVal args() As String)

        ' Verify that a parameter was entered.
        If args.Length = 0 Then
            Console.WriteLine("Enter a trace file specification.")

        Else
            ' Create a stream object.
            Dim traceStream As FileStream
            Try
                traceStream = New FileStream( _
                    args(0), FileMode.Append, FileAccess.Write)
            Catch ex As Exception
                Console.WriteLine( _
                    "Error creating FileStream for trace file ""{0}"":" & _
                    vbCrLf & "{1}", args(0), ex.Message)
                Return
            End Try

            ' Create a TextWriterTraceListener object that takes a stream.
            Dim textListener As TextWriterTraceListener
            textListener = _
                New TextWriterTraceListener(traceStream, LISTENER_NAME)
            Trace.Listeners.Add(textListener)

            ' Write these messages only to the TextWriterTraceListener.
            textListener.WriteLine( _
                "This is trace listener named """ & textListener.Name & """")
            textListener.WriteLine( _
                "Trace written through a stream to: " & _
                vbCrLf & "    """ & args(0) & """")

            ' Write a message to all trace listeners.
            Trace.WriteLine(String.Format( _
                "This trace message written {0} to all listeners.", Now))

            ' Flush and close the output.
            Trace.Flush()
            textListener.Flush()
            textListener.Close()
        End If
    End Sub
End Module

Plattformen

Windows 98, Windows 2000 SP4, Windows Millennium Edition, Windows Server 2003, Windows XP Media Center Edition, Windows XP Professional x64 Edition, Windows XP SP2, Windows XP Starter Edition

.NET Framework unterstützt nicht alle Versionen sämtlicher Plattformen. Eine Liste der unterstützten Versionen finden Sie unter Systemanforderungen.

Versionsinformationen

.NET Framework

Unterstützt in: 2.0, 1.1, 1.0

Siehe auch

Referenz

TextWriterTraceListener-Klasse
TextWriterTraceListener-Member
System.Diagnostics-Namespace
TraceListener
DefaultTraceListener-Klasse
ConsoleTraceListener-Klasse
EventLogTraceListener-Klasse
TextWriterTraceListener-Klasse
Stream
TextWriter
Debug-Klasse
Trace