sp_cursor_list (Transact-SQL)

Meldet die Attribute der Servercursor, die aktuell für die Verbindung geöffnet sind.

Transact-SQL-Syntaxkonventionen

Syntax

sp_cursor_list [ @cursor_return = ] cursor_variable_name OUTPUT 
     , [ @cursor_scope = ] cursor_scope
[;]

Argumente

• [ @cursor\_return= ] cursor_variable_nameOUTPUT
  Der Name einer deklarierten Cursorvariablen. cursor_variable_name ist vom Datentyp cursor und hat keinen Standardwert. Bei dem Cursor handelt es sich um einen scrollfähigen, dynamischen, schreibgeschützten Cursor.

• [ @cursor\_scope= ] cursor_scope
  Gibt die Ebene der Cursor an, die gemeldet werden sollen. cursor_scope ist vom Datentyp int, hat keinen Standardwert und kann einen der folgenden Werte aufweisen.

  Wert	Beschreibung
  1	Alle lokalen Cursor melden.
  2	Alle globalen Cursor melden.
  3	Lokale und globale Cursor melden.

Rückgabecodewerte

Keine

Zurückgegebene Cursor

sp_cursor_list gibt den Bericht nicht als Resultset, sondern als einen Transact-SQL-Cursorausgabeparameter zurück. Dies ermöglicht, dass Transact-SQL-Batches, gespeicherte Prozeduren und Trigger die Ausgabe zeilenweise verwenden können. Dies bedeutet außerdem, dass es nicht möglich ist, die Prozedur direkt über Datenbank-API-Funktionen aufzurufen. Der cursor-Ausgabeparameter muss an eine Programmvariable gebunden sein, aber die Datenbank-APIs unterstützen die Bindung von cursor-Parametern oder -Variablen nicht.

Dies ist das Format des von sp_cursor_list zurückgegebenen Cursors. Das Format des Cursors ist mit dem von sp_describe_cursor zurückgegebenen Format identisch.

Hinweise

sp_cursor_list erstellt eine Liste der aktuellen Servercursor, die für die Verbindung geöffnet sind, und beschreibt die globalen Cursorattribute, wie z. B. die Scrolloptionen und die Aktualisierbarkeit des Cursors. sp_cursor_list listet die folgenden Cursor auf:

• Transact-SQL-Servercursor.

• API-Servercursor, die von einer ODBC-Anwendung geöffnet wurden, die dann SQLSetCursorName genannt wird, um den Cursor zu benennen.

Mit sp_describe_cursor_columns zeigen Sie eine Beschreibung der Attribute des vom Cursor zurückgegebenen Resultsets an. Mit sp_describe_cursor_tables zeigen Sie an, auf welche Basistabellen der Cursor verweist. sp_describe_cursor zeigt die gleichen Informationen an wie sp_cursor_list, jedoch nur für den angegebenen Cursor.

Berechtigungen

Die Ausführungsberechtigungen erhält standardmäßig die public-Rolle.

Beispiele

Im folgenden Beispiel wird ein globaler Cursor geöffnet und mithilfe von sp_cursor_list ein Bericht der Cursorattribute erstellt.

USE AdventureWorks2012;
GO
-- Declare and open a keyset-driven cursor.
DECLARE abc CURSOR KEYSET FOR
SELECT LastName
FROM Person.Person
WHERE LastName LIKE 'S%';
OPEN abc;

-- Declare a cursor variable to hold the cursor output variable
-- from sp_cursor_list.
DECLARE @Report CURSOR;

-- Execute sp_cursor_list into the cursor variable.
EXEC master.dbo.sp_cursor_list @cursor_return = @Report OUTPUT,
      @cursor_scope = 2;

-- Fetch all the rows from the sp_cursor_list output cursor.
FETCH NEXT from @Report;
WHILE (@@FETCH_STATUS <> -1)
BEGIN
   FETCH NEXT from @Report;
END

-- Close and deallocate the cursor from sp_cursor_list.
CLOSE @Report;
DEALLOCATE @Report;
GO

-- Close and deallocate the original cursor.
CLOSE abc;
DEALLOCATE abc;
GO

Siehe auch

Verweis

Gespeicherte Systemprozeduren (Transact-SQL)