Tägliches Triggerbeispiel (Skripting)

In diesem Skriptbeispiel wird gezeigt, wie Sie täglich eine Aufgabe erstellen, die Editor um 8:00 Uhr ausführt. Die Aufgabe enthält einen täglichen Trigger, der eine Startgrenze zum Aktivieren des Triggers angibt und die Tageszeit der Aufgabe angibt, ein Triggerintervall, um anzugeben, dass die Aufgabe täglich ausgeführt wird, und eine Endgrenze zum Deaktivieren des Triggers. Das Beispiel zeigt auch, wie ein Wiederholungsmuster für den Trigger festgelegt wird, um die Aufgabe zu wiederholen. Die Aufgabe enthält auch eine ausführbare Aktion, die Editor ausführt.

Im folgenden Verfahren wird beschrieben, wie Sie einen Vorgang planen, um täglich um 8:00 Uhr eine ausführbare Datei zu starten. (Diese Schritte entsprechen den Codekommentaren, die im Beispielcode enthalten sind.)

So planen Sie editor, um jeden Tag um 8:00 Uhr zu beginnen

1. Erstellen Sie ein TaskService--Objekt. Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
2. Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder--Methode, um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask--Methode, um das TaskDefinition-Objekt zu erstellen, das die Aufgabe darstellt.
3. Definieren Sie Informationen zur Aufgabe mithilfe des TaskDefinition--Objekts. Verwenden Sie die TaskDefinition.Settings Eigenschaft, um die Einstellungen zu definieren, die bestimmen, wie der Task Scheduler-Dienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo Eigenschaft, um die Informationen zu definieren, die die Aufgabe beschreiben.
4. Erstellen Sie einen täglichen Trigger mithilfe der TaskDefinition.Triggers-Eigenschaft. Diese Eigenschaft bietet Zugriff auf das TriggerCollection--Objekt, das zum Erstellen des Triggers verwendet wird. Verwenden Sie die TriggerCollection.Create -Methode (angeben des Typs des Triggers, den Sie erstellen möchten), um einen täglichen Trigger zu erstellen. Legen Sie beim Erstellen des Triggers die Startgrenze fest, um den Trigger zu aktivieren, und geben Sie die Tageszeit an, die die Aufgabe ausführt, das Intervall zwischen den Tagen und die Endgrenze zum Deaktivieren des Triggers. Das folgende Beispiel zeigt, wie Sie ein Wiederholungsmuster für den Trigger festlegen, um die Aufgabe zu wiederholen.
5. Erstellen Sie eine Aktion für die Aufgabe, die mithilfe der TaskDefinition.Actions-Eigenschaft ausgeführt werden soll. Diese Eigenschaft bietet Zugriff auf das ActionCollection- Objekt, das zum Erstellen der Aktion verwendet wird. Verwenden Sie die ActionCollection.Create-Methode, um den Typ der zu erstellenden Aktion anzugeben. In diesem Beispiel wird ein ExecAction -Objekt verwendet, das eine Aktion darstellt, die einen Befehlszeilenvorgang ausführt.
6. Registrieren Sie die Aufgabe mithilfe der TaskFolder.RegisterTaskDefinition--Methode. In diesem Beispiel beginnt die Aufgabe jeden Tag um 8:00 Uhr mit dem Editor.

Im folgenden VBScript-Beispiel wird gezeigt, wie Sie einen Vorgang für die Ausführung von Editor täglich um 8:00 Uhr planen.

'------------------------------------------------------------------
' This sample schedules a task to start on a daily basis.
'------------------------------------------------------------------

' A constant that specifies a daily trigger.
const TriggerTypeDaily = 2
' A constant that specifies an executable action.
const ActionTypeExec = 0

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at 8:00AM daily"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a daily trigger. Note that the start boundary 
' specifies the time of day that the task starts and the 
' interval specifies what days the task is run.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeDaily)

' Trigger variables that define when the trigger is active 
' and the time of day that the task is run. The format of 
' this time is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime

Dim time
startTime = "2006-05-02T08:00:00"  'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysInterval = 1    'Task runs every day.
trigger.Id = "DailyTriggerId"
trigger.Enabled = True

' Set the task repetition pattern for the task.
' This will repeat the task 5 times.
Dim repetitionPattern
Set repetitionPattern = trigger.Repetition
repetitionPattern.Duration = "PT4M"
repetitionPattern.Interval = "PT1M"

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Daily Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Verwandte Themen

Verwenden des Taskplaner-