Anmeldetrigger (Beispiel) (Skripting)

In diesem Skriptbeispiel wird gezeigt, wie Sie eine Aufgabe erstellen, die für die Ausführung von Editor geplant ist, wenn sich ein Benutzer anmeldet. Die Aufgabe enthält einen Anmeldetrigger, der eine Startgrenze für die aufgabe angibt, die gestartet werden soll, und einen Benutzerbezeichner, der den Benutzer angibt. Die Aufgabe wird mithilfe der Gruppe "Administratoren" als Sicherheitskontext registriert, um die Aufgabe auszuführen.

Im folgenden Verfahren wird beschrieben, wie Sie eine ausführbare Datei wie Editor planen, die gestartet wird, wenn sich ein angegebener Benutzer anmeldet.

So planen Sie den Start des Editors, wenn sich ein Benutzer

1. Erstellen Sie ein TaskService--Objekt. Mit diesem Objekt können Sie die Aufgabe in einem angegebenen Ordner erstellen.
2. Rufen Sie einen Aufgabenordner ab, und erstellen Sie eine Aufgabe. Verwenden Sie die TaskService.GetFolder--Methode, um den Ordner abzurufen, in dem die Aufgabe gespeichert ist, und die TaskService.NewTask--Methode, um das TaskDefinition-Objekt zu erstellen, das die Aufgabe darstellt.
3. Definieren Sie Informationen zur Aufgabe mithilfe des TaskDefinition--Objekts. Verwenden Sie die TaskDefinition.Settings Eigenschaft, um die Einstellungen zu definieren, die bestimmen, wie der Task Scheduler-Dienst die Aufgabe ausführt, und die TaskDefinition.RegistrationInfo Eigenschaft, um die Informationen zu definieren, die die Aufgabe beschreiben.
4. Erstellen Sie einen Anmeldetrigger mithilfe der TaskDefinition.Triggers-Eigenschaft. Diese Eigenschaft bietet Zugriff auf das TriggerCollection--Objekt. Verwenden Sie die TriggerCollection.Create -Methode (angeben des Typs des Triggers, den Sie erstellen möchten), um einen Anmeldetrigger zu erstellen. Legen Sie beim Erstellen des Triggers die Startgrenze und die Endgrenze des Triggers fest, um den Trigger zu aktivieren und zu deaktivieren. Sie müssen die UserId-Eigenschaft für den Trigger festlegen, damit die Aktionen der Aufgabe ausgeführt werden sollen, wenn sich der angegebene Benutzer nach der Startgrenze anmeldet.
5. Erstellen Sie eine Aktion für die Aufgabe, die mithilfe der TaskDefinition.Actions-Eigenschaft ausgeführt werden soll. Diese Eigenschaft bietet Zugriff auf das ActionCollection--Objekt. Verwenden Sie die ActionCollection.Create-Methode, um den Typ der Aktion anzugeben, die Sie erstellen möchten. In diesem Beispiel wird ein ExecAction -Objekt verwendet, das eine Aktion darstellt, die eine ausführbare Datei startet.
6. Registrieren Sie die Aufgabe mithilfe der TaskFolder.RegisterTaskDefinition--Methode. In diesem Beispiel wird die Aufgabe registriert, sodass sie die Gruppe "Administratoren" als Sicherheitskontext zum Ausführen der Aufgabe verwendet.

Das folgende VBScript-Beispiel zeigt, wie Sie eine Aufgabe zum Ausführen von Editor planen, wenn sich ein Benutzer anmeldet.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when a user logs on.
'---------------------------------------------------------

' A constant that specifies a logon trigger.
const TriggerTypeLogon = 9
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when a " & _
    "specified user logs on."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a logon trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeLogon)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2006-05-02T10:49:02"
endTime = "2006-05-02T10:52:02"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "LogonTriggerId"
trigger.UserId = "DOMAIN\UserName"   ' Must be a valid user account   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
    "Test Logon Trigger", taskDefinition, createOrUpdateTask, _
    "Builtin\Administrators", , 4)

WScript.Echo "Task submitted."

Verwandte Themen

Verwenden des Taskplaner-