Summary of C statements

statement:
 labeled-statement
 compound-statement
 expression-statement
 selection-statement
 iteration-statement
 jump-statement
 try-except-statement /* Microsoft-specific */
 try-finally-statement /* Microsoft-specific */

jump-statement:
 goto identifier ;
 continue ;
 break ;
 return expression_opt ;
 __leave ; /* Microsoft-specific¹ */

compound-statement:
 { declaration-list_opt statement-list_opt }

declaration-list:
 declaration
 declaration-list declaration

statement-list:
 statement
 statement-list statement

expression-statement:
 expression_opt ;

iteration-statement:
 while ( expression ) statement
 do statement while ( expression ) ;
 for ( expression_opt ; expression_opt ; expression_opt ) statement

selection-statement:
 if ( expression ) statement
 if ( expression ) statement else statement
 switch ( expression ) statement

labeled-statement:
 identifier : statement
 case constant-expression : statement
 default : statement

try-except-statement: /* Microsoft-specific */
 __try compound-statement __except ( expression ) compound-statement

try-finally-statement: /* Microsoft-specific */
 __try compound-statement __finally compound-statement

1 The __leave keyword is only valid within the __try block of a try-except-statement or a try-finally-statement.

See also

Phrase structure grammar