Objetos visuales específicos del panel

Todas las visualizaciones que se crean en el contexto del operador de renderizado están disponibles en las visualizaciones del panel. Sin embargo, las visualizaciones siguientes solo están disponibles en paneles de Azure Data Explorer, paneles en tiempo real o interfaz de usuario web de Azure Data Explorer, y no con el operador render.

Para obtener información sobre cómo personalizar cualquier objeto visual de panel, consulte Personalización de objetos visuales de panel de Azure Data Explorer.

Para obtener información general sobre los paneles de Azure Data Explorer, consulte Visualización de datos con paneles de Azure Data Explorer.

Gráfico de embudo

Los gráficos de embudo visualizan un proceso lineal con fases secuenciales conectadas. Cada fase del embudo representa un porcentaje del total. Por lo tanto, en la mayoría de los casos, un gráfico de embudo tiene la forma de embudo: la primera fase es la más grande y cada fase posterior es menor que su predecesora.

En el ejemplo siguiente se visualiza la progresión de las solicitudes del servidor, que muestra el número total de sesiones, solicitudes y su estado de finalización. Resalta la caída desde las sesiones hasta las solicitudes y la proporción de solicitudes completadas frente a incompletas.

Ejemplo de consulta

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Mapa térmico

Un mapa térmico muestra los valores de una variable principal de interés en dos variables de eje como una cuadrícula de cuadrados coloreados.

Para representar un mapa térmico, la consulta debe generar una tabla con tres columnas. Los datos usados para el campo de valor deben ser numéricos. Las columnas que se usarán para los valores x e y usan las reglas siguientes:

• Si los valores de la columna x tienen el string formato , los valores de la columna y también deben tener el string formato .
• Si los valores de la columna x tienen el datetime formato , los valores de la columna y deben ser numéricos.

En el ejemplo siguiente se muestra la distribución de las cinco métricas sql más frecuentes en distintos tipos de métricas. Resalta qué tipos de métricas son más comunes para cada métrica de SQL, lo que facilita la identificación de patrones de actividad en las métricas principales.

Ejemplo de consulta

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count