mv-expand operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Expande matrices dinámicas de varios valores o contenedores de propiedades en varios registros.

mv-expand can be described as the opposite of the aggregation operators that pack multiple values into a single dynamic-typed array or property bag, such as summarize ... make-list() and make-series. Cada elemento de la matriz (escalar) o del contenedor de propiedades genera un nuevo registro en la salida del operador. Todas las columnas de la entrada que no se expanden se duplican en todos los registros de la salida.

Syntax

T|mv-expand [kind=(bag | array)] [with_itemindex=IndexColumnName] ColumnName [to typeof(Typename)] [,ColumnName ...] [limitRowlimit]

T|mv-expand [kind=(bag | array)] [Name=] ArrayExpression [to typeof(Typename)] [, [Name=] ArrayExpression [to typeof(Typename)] ...] [limitRowlimit]

Learn more about syntax conventions.

Parameters

Returns

Para cada registro de la entrada, el operador devuelve cero, uno o muchos registros en la salida, lo que se determina de la siguiente manera:

1. Las columnas de entrada que no se expanden aparecen en la salida con su valor original. Si un único registro de entrada se expande en varios registros de salida, el valor se duplica en todos los registros.

2. For each ColumnName or ArrayExpression that is expanded, the number of output records is determined for each value as explained in modes of expansion. Para cada registro de entrada, se calcula el número máximo de registros de salida. Todas las matrices o contenedores de propiedades se expanden "en paralelo" para que los valores que falten (si los hubiera) se reemplacen por valores NULL. Los elementos se expanden en filas en el orden en que aparecen en la matriz o el contenedor originales.

3. Si el valor dinámico es NULL, se genera un único registro para él (NULL). Si el valor dinámico es una matriz o un contenedor de propiedades vacíos, no se genera ningún registro para ese valor. En caso contrario, se generan tantos registros como elementos hay en el valor dinámico.

Las columnas expandidas son del tipo dynamic, salvo que se escriban explícitamente mediante la cláusula to typeof().

Modos de expansión

Se admiten dos modos de expansiones de contenedores de propiedades:

• kind=bag o bagexpansion=bag: Las bolsas de propiedades se expanden en bolsas de propiedades de entrada única. Este modo es el predeterminado.
• kind=array or bagexpansion=array: Property bags are expanded into two-element [key,value] array structures, allowing uniform access to keys and values. Este modo también permite, por ejemplo, ejecutar una agregación de recuento distintiva sobre los nombres de propiedad.

Examples

Los ejemplos de esta sección muestran cómo usar la sintaxis para ayudarle a empezar.

Columna única: expansión de matriz

datatable (a: int, b: dynamic)
[
    1, dynamic([10, 20]),
    2, dynamic(['a', 'b'])
]
| mv-expand b

Output

Columna única: expansión de bolsa

Una simple expansión de una única columna:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand b

Output

Columna única: expansión de contenedor a pares clave-valor

Una expansión de bolsa simple a pares clave-valor:

datatable (a: int, b: dynamic)
[
    1, dynamic({"prop1": "a1", "prop2": "b1"}),
    2, dynamic({"prop1": "a2", "prop2": "b2"})
]
| mv-expand kind=array b 
| extend key = b[0], val=b[1]

Output

Dos columnas comprimidas:

Expandir dos columnas primero "zip" las columnas aplicables y, a continuación, expandirlas:

datatable (a: int, b: dynamic, c: dynamic)[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 4, 3])
]
| mv-expand b, c

Output

Producto cartesiano de dos columnas

Si quiere obtener un producto cartesiano de la expansión de dos columnas, expanda una después de la otra:

datatable (a: int, b: dynamic, c: dynamic)
[
    1, dynamic({"prop1": "a", "prop2": "b"}), dynamic([5, 6])
]
| mv-expand b
| mv-expand c

Output

Convert output

Para forzar la salida de una operación mv-expand a un tipo determinado (el valor predeterminado es dinámico), use to typeof:

datatable (a: string, b: dynamic, c: dynamic)[
    "Constant", dynamic([1, 2, 3, 4]), dynamic([6, 7, 8, 9])
]
| mv-expand b, c to typeof(int)
| getschema 

Output

Observe que la columna b se devuelve como dynamic, mientras que c se devuelve como int.

Using with_itemindex

Expansión de una matriz con with_itemindex:

range x from 1 to 4 step 1
| summarize x = make_list(x)
| mv-expand with_itemindex=Index x

Output