Compartir a través de

Inicio rápido: Implementación de un clúster de Azure DocumentDB mediante Bicep

En este inicio rápido, implementará un nuevo clúster de Azure DocumentDB mediante Bicep. En este inicio rápido se proporcionan instrucciones paso a paso para ayudarle a empezar a trabajar rápidamente. Este clúster contiene todos los recursos de MongoDB: bases de datos, colecciones y documentos. Proporciona un punto de conexión único para herramientas y kits de desarrollo de software (SDK) para conectarse a Azure DocumentDB y realizar operaciones.

Prerrequisitos

  • Una suscripción de Azure

Configuración del entorno

Configure el entorno de la CLI de Azure para administrar los recursos de Azure DocumentDB en la suscripción.

  1. Inicie en un directorio vacío.

  2. Inicie sesión en la CLI de Azure.

    az login

  3. Compruebe la suscripción de Azure de destino.

    az account show

    Nota:

    Si no está conectado a la suscripción que esperaba, use este comando para cambiar la suscripción:

    az account set --subscription "<subscription-name>"

    Para más información, consulte Administración de suscripciones de Azure con la CLI de Azure.

Preparación de la plantilla de Bicep

Cree y configure un archivo de Bicep para definir los recursos necesarios para implementar un clúster de Azure DocumentDB.

  1. Cree un nuevo archivo main.bicep en el directorio del proyecto.

  2. Agregue esta plantilla al contenido del archivo.

    @description('Cluster name')
@minLength(8)
@maxLength(40)
param clusterName string = 'msdocs-${uniqueString(resourceGroup().id)}'

@description('Location for the cluster.')
param location string = resourceGroup().location

@description('Username for admin user')
param adminUsername string

@secure()
@description('Password for admin user')
@minLength(8)
@maxLength(128)
param adminPassword string

resource cluster 'Microsoft.DocumentDB/mongoClusters@2025-09-01' = {
  name: clusterName
  location: location
  properties: {
    administrator: {
      userName: adminUsername
      password: adminPassword
    }
    serverVersion: '8.0'
    sharding: {
      shardCount: 1
    }
    storage: {
      sizeGb: 32
    }
    highAvailability: {
      targetMode: 'Disabled'
    }
    compute: {
      tier: 'M10'
    }
  }
}

resource firewallRules 'Microsoft.DocumentDB/mongoClusters/firewallRules@2025-09-01' = {
  parent: cluster
  name: 'AllowAllAzureServices'
  properties: {
    startIpAddress: '0.0.0.0'
    endIpAddress: '0.0.0.0'
  }
}

    Sugerencia

    Para obtener más información sobre las opciones que utilizan el recurso Microsoft.DocumentDB/mongoclusters, consulte la documentación de Microsoft.DocumentDB/mongoclusters.

Implementación de la plantilla

Implemente la plantilla creada en el paso anterior mediante una implementación de Azure Resource Manager.

  1. Use el az group create comando para crear un nuevo grupo de recursos en la suscripción.

    az group create \
    --name "<resource-group-name>" \
    --location "<location>"

  2. Use az deployment group create para implementar la plantilla de bicep. A continuación, se le pedirá que escriba un valor para los adminUsername parámetros y adminPassword .

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep'

    Sugerencia

    Como alternativa, use la --parameters opción para pasar un archivo de parámetros con valores predefinidos.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep' \
    --parameters @main.parameters.json

    Este archivo JSON de ejemplo inserta valores clusteradmin y P@ssw.rd para los parámetros adminUsername y adminPassword respectivamente.

    {
  "$schema": "https://schema.management.azure.com/schemas/2015-01-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "adminUsername": {
      "value": "clusteradmin"
    },
    "adminPassword": {
      "value": "P@ssw.rd"
    }
  }
}

  3. Espere a que se complete la operación de implementación antes de continuar.

Revisión de los recursos implementados

Enumere los recursos de Azure DocumentDB implementados en el grupo de recursos.

  1. Use az resource list para obtener una lista de recursos en el grupo de recursos.

    az resource list \
    --resource-group "<resource-group-name>" \
    --namespace "Microsoft.DocumentDB" \
    --resource-type "mongoClusters" \
    --query "[].name" \
    --output json

  2. En la salida de ejemplo, busquen los recursos cuya clase es Microsoft.DocumentDB/mongoClusters. Este es un ejemplo del tipo de salida que se espera:

    [
  "msdocs-documentdb-example-cluster"
]

Limpieza de recursos

Cuando haya terminado con el clúster de Azure DocumentDB, puede eliminar los recursos de Azure que creó para que no incurra en más cargos.

  1. Use az group delete para quitar el grupo de recursos de la suscripción.

    az group delete \
    --name "<resource-group-name>" \
    --yes \
    --no-wait

    Importante

    Asegúrese de que ya no necesita los recursos antes de ejecutar este comando, ya que los elimina permanentemente.

Contenido relacionado

  • Last updated on