Compartir a través de

Inicio rápido: Uso de Terraform para crear un servicio de aprovisionamiento de dispositivos Azure IoT

En esta guía rápida, aprenderá a implementar un recurso del servicio de aprovisionamiento de dispositivos de Azure IoT Hub (DPS) con un algoritmo de asignación basado en hash mediante Terraform.

Este inicio rápido se probó con las siguientes versiones de Terraform y del proveedor de Terraform:

Terraform habilita la definición, la versión preliminar y la implementación de la infraestructura en la nube. Con Terraform, se crean archivos de configuración mediante la sintaxis de HCL. La sintaxis de HCL permite especificar el proveedor de nube , como Azure, y los elementos que componen la infraestructura en la nube. Después de crear los archivos de configuración, se crea un plan de ejecución que permite obtener una vista previa de los cambios de infraestructura antes de implementarlos. Una vez que compruebe los cambios, aplique el plan de ejecución para implementar la infraestructura.

En este artículo aprenderá a:

  • Crear una cuenta de almacenamiento y un contenedor de almacenamiento
  • Crear un centro de eventos, un espacio de nombres y una regla de autorización
  • Crear un IoT Hub
  • Vincular IoT Hub al punto de conexión de la cuenta de almacenamiento y al punto de conexión de Event Hubs
  • Creación de una directiva de acceso compartido de IoT Hub
  • Creación de un recurso de DPS
  • Vinculación de DPS e IoT Hub

Prerrequisitos

  • Suscripción de Azure: si no tiene una suscripción de Azure, cree una cuenta gratuita antes de comenzar.

Implementación del código de Terraform

Nota:

El código de ejemplo de este artículo se encuentra en el repositorio de GitHub de de Azure Terraform. Para más información, incluidos artículos y código de ejemplo que muestra cómo usar Terraform para administrar recursos de Azure, consulte la documentación de Terraform en Azure.

  1. Cree un directorio en el que probar y ejecutar el código de ejemplo de Terraform y conviértalo en el directorio actual.

  2. Cree un archivo denominado providers.tf e inserte el siguiente código:

    terraform {
  required_version = ">=1.0"

  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">=3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

  3. Cree un archivo denominado main.tf e inserte el siguiente código:

    resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "azurerm_resource_group" "rg" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

# Create storage account & container
resource "random_string" "sa_name" {
  length  = 12
  special = false
  upper   = false
}

resource "azurerm_storage_account" "sa" {
  name                     = random_string.sa_name.id
  resource_group_name      = azurerm_resource_group.rg.name
  location                 = azurerm_resource_group.rg.location
  account_tier             = "Standard"
  account_replication_type = "LRS"
}

resource "azurerm_storage_container" "my_terraform_container" {
  name                  = "mycontainer"
  storage_account_name  = azurerm_storage_account.sa.name
  container_access_type = "private"
}


# Create an Event Hub & Authorization Rule
resource "random_pet" "eventhub_namespace_name" {
  prefix = var.eventhub_namespace_name_prefix
}

resource "azurerm_eventhub_namespace" "namespace" {
  name                = random_pet.eventhub_namespace_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location
  sku                 = "Basic"
}

resource "azurerm_eventhub" "my_terraform_eventhub" {
  name                = "myEventHub"
  resource_group_name = azurerm_resource_group.rg.name
  namespace_name      = azurerm_eventhub_namespace.namespace.name
  partition_count     = 2
  message_retention   = 1
}

resource "azurerm_eventhub_authorization_rule" "my_terraform_authorization_rule" {
  resource_group_name = azurerm_resource_group.rg.name
  namespace_name      = azurerm_eventhub_namespace.namespace.name
  eventhub_name       = azurerm_eventhub.my_terraform_eventhub.name
  name                = "acctest"
  send                = true
}


# Create an IoT Hub
resource "random_pet" "iothub_name" {
  prefix = var.iothub_name_prefix
  length = 1
}

resource "azurerm_iothub" "iothub" {
  name                = random_pet.iothub_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location

  sku {
    name     = "S1"
    capacity = 1
  }

  endpoint {
    type                       = "AzureIotHub.StorageContainer"
    connection_string          = azurerm_storage_account.sa.primary_blob_connection_string
    name                       = "export"
    batch_frequency_in_seconds = 60
    max_chunk_size_in_bytes    = 10485760
    container_name             = azurerm_storage_container.my_terraform_container.name
    encoding                   = "Avro"
    file_name_format           = "{iothub}/{partition}_{YYYY}_{MM}_{DD}_{HH}_{mm}"
  }

  endpoint {
    type              = "AzureIotHub.EventHub"
    connection_string = azurerm_eventhub_authorization_rule.my_terraform_authorization_rule.primary_connection_string
    name              = "export2"
  }

  route {
    name           = "export"
    source         = "DeviceMessages"
    condition      = "true"
    endpoint_names = ["export"]
    enabled        = true
  }

  route {
    name           = "export2"
    source         = "DeviceMessages"
    condition      = "true"
    endpoint_names = ["export2"]
    enabled        = true
  }

  enrichment {
    key            = "tenant"
    value          = "$twin.tags.Tenant"
    endpoint_names = ["export", "export2"]
  }

  cloud_to_device {
    max_delivery_count = 30
    default_ttl        = "PT1H"
    feedback {
      time_to_live       = "PT1H10M"
      max_delivery_count = 15
      lock_duration      = "PT30S"
    }
  }

  tags = {
    purpose = "testing"
  }
}

#Create IoT Hub Access Policy
resource "azurerm_iothub_shared_access_policy" "hub_access_policy" {
  name                = "terraform-policy"
  resource_group_name = azurerm_resource_group.rg.name
  iothub_name         = azurerm_iothub.iothub.name

  registry_read   = true
  registry_write  = true
  service_connect = true
}

# Create IoT Hub DPS
resource "random_pet" "dps_name" {
  prefix = var.dps_name_prefix
  length = 1
}

resource "azurerm_iothub_dps" "dps" {
  name                = random_pet.dps_name.id
  resource_group_name = azurerm_resource_group.rg.name
  location            = azurerm_resource_group.rg.location
  allocation_policy   = "Hashed"

  sku {
    name     = "S1"
    capacity = 1
  }

  linked_hub {
    connection_string       = azurerm_iothub_shared_access_policy.hub_access_policy.primary_connection_string
    location                = azurerm_resource_group.rg.location
    allocation_weight       = 150
    apply_allocation_policy = true
  }
}

  4. Cree un archivo denominado variables.tf e inserte el siguiente código:

    variable "resource_group_location" {
  default     = "eastus"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "eventhub_namespace_name_prefix" {
  default     = "namespace"
  description = "Prefix of the event hub namespace name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "iothub_name_prefix" {
  default     = "iothub"
  description = "Prefix of the iot hub name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "dps_name_prefix" {
  default     = "dps"
  description = "Prefix of the dps name that's combined with a random ID so name is unique in your Azure subscription."
}

  5. Cree un archivo denominado outputs.tf e inserte el siguiente código:

    output "azurerm_iothub_name" {
  value = azurerm_iothub.iothub.name
}

output "azurerm_iothub_dps_name" {
  value = azurerm_iothub_dps.dps.name
}

output "resource_group_name" {
  value = azurerm_resource_group.rg.name
}

Inicialización de Terraform

Ejecute terraform init para inicializar la implementación de Terraform. Este comando descarga el proveedor de Azure necesario para administrar los recursos de Azure.

terraform init -upgrade

Puntos clave:

  • El parámetro -upgrade actualiza los complementos de proveedor necesarios a la versión más reciente que cumpla con las restricciones de versión de la configuración.

Creación de un plan de ejecución de Terraform

Ejecute terraform plan para crear un plan de ejecución.

terraform plan -out main.tfplan

Puntos clave:

  • El comando terraform plan crea un plan de ejecución, pero no lo ejecuta. En su lugar, determina qué acciones son necesarias para crear la configuración especificada en los archivos de configuración. Este patrón le permite comprobar si el plan de ejecución coincide con sus expectativas antes de realizar cambios en los recursos reales.
  • El parámetro opcional -out permite especificar un archivo de salida para el plan. El uso del parámetro -out garantiza que el plan que ha revisado es exactamente lo que se aplica.

Aplicación de un plan de ejecución de Terraform

Ejecute terraform apply para aplicar el plan de ejecución a la infraestructura en la nube.

terraform apply main.tfplan

Puntos clave:

  • El comando terraform apply de ejemplo asume que ejecutó terraform plan -out main.tfplan previamente.
  • Si especificó un nombre de archivo diferente para el parámetro -out, use ese mismo nombre de archivo en la llamada a terraform apply.
  • Si no ha utilizado el parámetro -out, llame a terraform apply sin ningún parámetro.

Comprobación de los resultados

Ejecute az iot dps show para mostrar el recurso de Azure DPS.

az iot dps show \
   --name <azurerm_iothub_dps_name> \
   --resource-group <resource_group_name>

Puntos clave:

  • Los nombres del grupo de recursos y la instancia de DPS se muestran en la terraform apply salida. También puede ejecutar terraform output para visualizar estos valores de salida.

Limpieza de recursos

Cuando ya no necesite los recursos creados a través de Terraform, siga estos pasos:

  1. Ejecute terraform plan y especifique el indicador destroy.

    terraform plan -destroy -out main.destroy.tfplan

    Puntos clave:

    • El comando terraform plan crea un plan de ejecución, pero no lo ejecuta. En su lugar, determina qué acciones son necesarias para crear la configuración especificada en los archivos de configuración. Este patrón le permite comprobar si el plan de ejecución coincide con sus expectativas antes de realizar cambios en los recursos reales.
    • El parámetro opcional -out permite especificar un archivo de salida para el plan. El uso del parámetro -out garantiza que el plan que ha revisado es exactamente lo que se aplica.

  2. Ejecute terraform apply para aplicar el plan de ejecución.

    terraform apply main.destroy.tfplan

Solución de problemas de Terraform en Azure

Solución de problemas comunes al usar Terraform en Azure

Pasos siguientes

En este inicio rápido, ha implementado un centro de IoT y una instancia de Device Provisioning Service, y ha vinculado los dos recursos. Para saber cómo usar esta configuración para aprovisionar un dispositivo, vaya al inicio rápido en el que se explica cómo crear un dispositivo.

Inicio rápido: Aprovisionamiento de un dispositivo simulado con clave simétrica

  • Last updated on