Compartir a través de

Procedimientos recomendados de FinOps para Storage

En este artículo se describe una colección de prácticas probadas de FinOps para los servicios de almacenamiento. Proporciona estrategias para optimizar los costos, mejorar la eficacia y usar consultas de Azure Resource Graph (ARG) para obtener información sobre los recursos de almacenamiento. Al seguir estos procedimientos, puede asegurarse de que los servicios de almacenamiento son rentables y se alinean con los objetivos financieros de su organización.


Copia de seguridad

En las secciones siguientes se proporcionan consultas ARG para los servicios de copia de seguridad. Estas consultas le ayudan a obtener información sobre los recursos de copia de seguridad y a asegurarse de que están configuradas con las opciones adecuadas. Mediante el análisis de elementos de copia de seguridad y la identificación de copias de seguridad inactivas, puede optimizar los servicios de copia de seguridad para la rentabilidad.

Consulta: copias de seguridad inactivas

Esta consulta de ARG analiza los elementos de copia de seguridad dentro de los almacenes de Azure Recovery Services e identifica los que no se han realizado copias de seguridad durante más de 90 días.

Categoría

Optimización

Consulta

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Consulta: enumeración de almacenes de Recovery Services

Esta consulta de Azure Resource Graph (ARG) obtiene información detallada sobre los almacenes de Azure Recovery Services. La consulta también incluye información sobre el nivel de SKU, la configuración de redundancia y otros metadatos pertinentes.

Categoría

Optimización

Consulta

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Discos

En las secciones siguientes se proporcionan consultas ARG para servicios de disco. Estas consultas le ayudan a obtener información sobre los recursos de disco y a asegurarse de que están configuradas con las opciones adecuadas. Mediante el análisis de instantáneas de disco e identificación de discos inactivos, puede optimizar los servicios de disco para la rentabilidad.

Consulta: discos inactivos

Esta consulta de ARG identifica discos administrados inactivos o no conectados en el entorno de Azure.

Categoría

Optimización

Consulta

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc 
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Consulta: instantánea de disco de hace más de 30 días

Esta consulta de ARG identifica las instantáneas de disco que tienen más de 30 días.

Categoría

Optimización

Consulta

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Consulta: instantánea mediante almacenamiento premium

Esta consulta de ARG identifica las instantáneas de disco que utilizan Premium Storage.

Categoría

Optimización

Consulta

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Cuentas de almacenamiento

En la sección siguiente se proporciona una consulta ARG para las cuentas de almacenamiento. Le ayuda a obtener información sobre los recursos de almacenamiento y a asegurarse de que están configurados con las opciones adecuadas. Mediante el análisis de las cuentas de almacenamiento y la identificación de los tipos de cuenta de almacenamiento heredados, puede optimizar sus servicios de almacenamiento para lograr una mayor eficiencia de costos.

Consulta: cuenta de almacenamiento v1

Esta consulta de ARG identifica las cuentas de almacenamiento que siguen usando el tipo heredado v1, que podría no proporcionar las mismas características y eficiencias que los tipos de cuenta de almacenamiento más recientes.

Categoría

Optimización

Consulta

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| where resourceGroup in ({ResourceGroup})
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Proporcionar comentarios

Déjanos saber cómo lo estamos haciendo con una breve revisión. Usamos estas revisiones para mejorar y expandir herramientas y recursos de FinOps.

Enviar comentarios

Si busca algo específico, vote por una idea existente o cree una idea nueva. Comparta ideas con otros usuarios para obtener más votos. Nos centramos en las ideas con la mayoría de los votos.

Votar o sugerir ideas


Contenido relacionado

Recursos relacionados

Soluciones relacionadas:


  • Last updated on