Funciones en tiempo de ejecución de X++ para conversión

En este artículo se describen las funciones en tiempo de ejecución de conversión.

any2Date

Convierte un valor anytype en un valor de fecha .

date any2Date(anytype object)

Parámetros

Valor devuelto

Valor de fecha .

Observaciones

El parámetro object puede ser de la mayoría de los tipos de datos, pero se obtiene una salida útil cuando es del tipo str o int . El contenido inapropiado genera un error en tiempo de ejecución.

Example

static void any2DateExample(Args _args)
{
    date myDate;
    str s;
    int i;
    s = "2010 6 17"; // A string object, of yyyy mm dd.
    myDate = any2Date(s);
    Global::info(strFmt("%1  is output, from input of "2010 6 17"", myDate));
    i = 40361; // An int object, which represents the number of days from 1900/01/01.
    myDate = any2Date(i);
    Global::info(strFmt("%1  is output, from input of 40361", myDate));
}
/**** Infolog display.
Message (04:44:15 pm)
6/17/2010 is output, from input of "2010 6 17"
7/4/2010 is output, from input of 40361
****/

any2Enum

Convierte un valor anytype en el valor de la propiedad Name de un elemento de la enumeración de destino.

enum any2Enum(anytype object)

Parámetros

Valor devuelto

El valor de la propiedad Name para cualquier elemento de la enumeración de destino tiene una propiedad Value que coincide con el parámetro de entrada.

Observaciones

El parámetro object puede ser de la mayoría de los tipos de datos, pero solo se obtienen datos útiles cuando se usa un parámetro del tipo str o int . Este parámetro de objeto de entrada hace referencia a la propiedad Value de un elemento individual de la enumeración de destino.

Example

static void any2EnumExample(Args _args)
{
    NoYes myNoYes;  // NoYes is an enum.
    int i;
    str s;
    i = 0;  // An int that will be converted.
    myNoYes = any2Enum(i);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as int.", myNoYes, i));
    s = "1";  // A str that will be converted.
    myNoYes = any2Enum(s);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as str.", myNoYes, s));
    /**** Infolog display.
    Message (01:05:32 pm)
    'No' - is the output, from input of the 0 as int.
    'Yes' - is the output, from input of the 1 as str.
    ****/
}

any2Guid

Convierte el objeto anytype especificado en un objeto GUID.

guid any2Guid(anytype object)

Parámetros

Valor devuelto

Objeto GUID.

any2Int

Convierte un valor anytype en un valor int .

int any2Int(anytype object)

Parámetros

Valor devuelto

Valor int .

Observaciones

El parámetro object puede ser de la mayoría de los tipos de datos, pero solo se obtienen datos útiles cuando se usan parámetros del tipo enum, real o str .

Example

static void any2IntExample(Args _args)
{
    int myInt;
    str s;
    NoYes a;
    real r;
    s = "31";
    myInt = any2Int(s);
    Global::info(strfmt("%1 is the output, from input of 31 as a str value.", myInt));
    a = NoYes::No;
    myInt = any2Int(a);
    Global::info(strfmt("%1 is the output, from input of NoYes::No as an enum value.", myInt));
    r = 5.34e2;
    myInt = any2Int(r);
    Global::info(strfmt("%1 is the output, from the input of 5.34e2 as a real value.", myInt));
}
/**** Infolog display.
Message (02:23:59 pm)
31 is the output, from input of 31 as a str value.
0 is the output, from input of NoYes::No as an enum value.
534 is the output, from the input of 5.34e2 as a real value.
****/

any2Int64

Convierte un objeto anytype en un objeto int64 .

int64 any2Int64(anytype object)

Parámetros

Valor devuelto

Objeto int64 .

any2Real

Convierte un valor anytype en un valor real .

real any2Real(anytype object)

Parámetros

Valor devuelto

Valor real .

Observaciones

El parámetro object puede ser de la mayoría de los tipos de datos, pero se obtiene una salida útil para los elementos de entrada de los tipos date, int, enum y str .

Example

static void any2RealExample(Args _args)
{
    real myReal;
    str s;
    int i;
    NoYes a;
    s = "5.12";
    myReal = any2Real(s);
    Global::info(strfmt("%1 is the output from the input of 5.12 as a str object", myReal));
    i = 64;
    myReal = any2Real(i);
    Global::info(strfmt("%1 is the output from the input of 64 as an int object", myReal));
    a = NoYes::Yes;
    myReal = any2Real(a);
    Global::info(strfmt("%1 is the output from the input of NoYes::Yes as an enum object", myReal));
}
/****Infolog display.
Message (02:43:57 pm)
5.12 is the output from the input of 5.12 as a str object
64.00 is the output from the input of 64 as an int object
1.00 is the output from the input of NoYes::Yes as an enum object
****/

any2Str

Convierte un valor anytype en un valor str .

str any2Str(anytype object)

Parámetros

Valor devuelto

Valor str .

Observaciones

El parámetro object puede ser de la mayoría de los tipos de datos, pero la salida útil se obtiene de los elementos de entrada de los tipos date, int y enum .

Example

static void any2StrExample(Args _args)
{
    str myStr;
    anytype a;
    a = "Any to string";
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of Any to string as a str value", myStr));
    a = NoYes::Yes;
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of NoYes::Yes as an enumeration", myStr));
}
/****Infolog Display
Message (09:08:46 am)
Any to string is output, from input of Any to string as a str value
1 is output, from input of NoYes::Yes as an enumeration
****/

anytodate

Consulte any2Date.

anytoenum

Consulte any2Enum.

anytoguid

Vea any2Guid.

anytoint

Vea any2Int.

anytoint64

Vea any2Int64.

anytoreal

Vea any2Real.

anytostr

Consulte any2Str.

char2Num

Convierte un carácter de una cadena en el valor ASCII del carácter.

int char2Num(str text, int position)

Parámetros

Valor devuelto

Valor ASCII del carácter como un objeto int .

Observaciones

char2Num("ABCDEFG",3); //Returns the numeric value of C, which is 67.
char2Num("ABCDEFG",1); //Returns the numeric value of A, which is 65.

date2Num

Convierte una fecha en un entero que corresponde al número de días desde el 1 de enero de 1900.

int date2Num(date _date)

Parámetros

Valor devuelto

Número de días comprendidos entre el 1 de enero de 1900 y la fecha especificada.

Example

//Returns the value377.
date2Num(1311901);
static void date2NumExample(Args _arg)
{
    date d = today();
    int i;
    i = date2Num(d);
    print i;
}

date2Str

Convierte la fecha especificada en una cadena.

str date2Str(date date, int sequence, int day, int separator1, int month, int separator2, int year [, int flags = DateFlags::None])

Parámetros

Valor devuelto

Cadena que representa la fecha especificada.

Observaciones

MorphX asigna valores válidos a los parámetros de formato si los valores especificados no son válidos. Para usar el formato de fecha que el usuario especificó en Configuración regional, use la función strFmt o date2Str y especifique -1 en todos los parámetros de formato. Cuando la configuración regional controla el formato de fecha, la configuración puede cambiar de usuario a usuario. Si se usa -1 para cualquiera de los parámetros separadores , ambos separadores se usan de forma predeterminada en Configuración regional. Los valores del parámetro de secuencia deben ser cualquier número de tres dígitos que contenga exactamente una aparición de cada uno de los dígitos 1, 2 y 3. Los dígitos 1, 2 y 3 representan día, mes y año, respectivamente. Por ejemplo, 321 genera el año de secuencia, el mes y el día. O bien, el valor puede ser -1 para usar la configuración regional. No se debe usar ningún tipo de enumeración para este parámetro, ya que los números como 321 superan el intervalo de valores válidos para los valores de enumeración, que es de 0 a 250, ambos incluidos. El valor predeterminado del parámetro flags es el valor de enumeración DateFlags::None , lo que significa que no se realiza ningún procesamiento de secuencia de izquierda a derecha o de derecha a izquierda.

Example

En el ejemplo siguiente se muestra la fecha actual en la secuencia de año, mes y día.

static void Job2(Args _args)
{
    date currentDate = today();
    str s;
    int iEnum;
    s = date2Str
    (currentDate, 
        321,
        DateDay::Digits2,
        DateSeparator::Hyphen, // separator1
        DateMonth::Digits2,
        DateSeparator::Hyphen, // separator2
        DateYear::Digits4
    );
    info("Today is:  " + s);
}
/** Example Infolog output
Message (12:36:21 pm)
Today is:  2009-01-13
**/

datetime2Str

Convierte un valor utcdatetime en una cadena.

str datetime2Str(utcdatetime datetime [, int flags = DateFlags::None])

Parámetros

Valor devuelto

Cadena que representa el valor utcdatetime que se especificó como parámetro datetime .

Observaciones

Entrada de fecha y hora nula

Si se especifica el valor mínimo utcdatetime para el parámetro datetime , la función datetime2Str la trata como un valor de entrada null. Esto hace que la función devuelva una cadena vacía. El método DateTimeUtil::minValue devuelve la fecha y hora 1900-01T00:00:00. Este valor mínimo se trata como null.

Configuración local de derecha a izquierda

El comportamiento predeterminado de esta función es generar la cadena en secuencia de izquierda a derecha, donde la parte del año está más a la izquierda. Sin embargo, el valor del parámetro flags del valor de enumeración DateFlags::FormatAll dirige la función para generar la cadena en secuencia de derecha a izquierda si la configuración local está configurada para derecha a izquierda. El formato del método toStr de la clase DateTimeUtil no se ve afectado por la configuración regional.

Example

static void jobTestDatetime2str( Args _args )
{
    utcdatetime utc2 = 1959-06-17T15:44:33;
    str s3;
    s3 = datetime2Str( utc2 );
    info( s3 );
}

enum2Str

Convierte el texto enumerado especificado en una representación de caracteres.

str enum2Str(enum enum)

Parámetros

Valor devuelto

Valor de la enumeración como una cadena.

Example

En el ejemplo siguiente se devuelve la cadena "No incluido". Esta es la etiqueta del valor IncludeNot del tipo de enumeración ListCode .

static void enum2StrExample(Args _arg)
{
    ListCode l;
    l =  ListCode::IncludeNot;
    print enum2Str(l);
}

guid2Str

Convierte el objeto GUID especificado en la cadena equivalente.

str guid2String(guid _uuid)

Parámetros

Valor devuelto

Cadena equivalente al objeto GUID especificado.

Example

static void guid2StrExample()
{
    guid _guid;
    str stringGuid;
    _guid = Global::guidFromString("{12345678-1234-1234-1234-123456789abc}");
    print strfmt("GUID is %1", _guid);
    stringGuid = guid2str(_guid);
    info("String GUID is " + stringGuid);
}
/**** Output to Infolog
String GUID is {12345678-1234-1234-1234-123456789ABC}
****/

int2Str

Convierte un entero en la cadena equivalente.

str int2Str(int integer)

Parámetros

Valor devuelto

Representación de cadena del entero.

Example

static void int2StrExample(Args _arg)
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

int642Str

Convierte el parámetro entero especificado en la cadena de texto equivalente.

str int642Str(int64 integer)

Parámetros

Valor devuelto

Cadena de texto equivalente del parámetro entero .

Example

static void example()
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

num2Char

Convierte un entero en el carácter ASCII correspondiente.

str num2Char(int figure)

Parámetros

Valor devuelto

Carácter representado por el entero especificado.

Example

static void num2CharExample(Args _arg)
{
    str s;
    s = num2Char(42);
    // Prints an asterisk * -the character represented by 42.
    print s;
}

num2Date

Recupera la fecha que corresponde al número especificado de días después del 1 de enero de 1900.

date num2Date(int _days)

Parámetros

Valor devuelto

Fecha que es el número de días especificados por el parámetro _days después del 1 de enero de 1900.

Observaciones

num2Date(366); //Returns the date 01/01/1901 (1 January 1901).

num2Str

Convierte un número real en una cadena.

str num2Str(real number, int character, int decimals, int separator1, int separator2)

Parámetros

Valor devuelto

Cadena que representa el número.

Observaciones

Para el parámetro decimals , el valor máximo es 16. Si se usa un número mayor, este método obtiene un valor para el parámetro decimals del equipo local en su lugar. En ambos casos, se produce el redondeo. Estos son los posibles valores de enumeración para el parámetro separator1 :

• 99 – Automático (la configuración de formato del usuario determina qué separador decimal se usa), valor de enumeración DecimalSeparator::Auto
• 1 – Punto (.), valor de enumeración DecimalSeparator::D ot
• 2 – Coma (,), valor de enumeración DecimalSeparator::Comma

Estos son los valores posibles para el parámetro separator2 :

• 99 : Automático (la configuración de formato del usuario determina qué separador de miles se usa)
• 0 : Ninguno (sin mil separadores), valor de enumeración ThousandSeparator::None
• 1 – Punto (.), valor de enumeración ThousandSeparator::D ot
• 2 – Coma (,), valor de enumeración ThousandSeparator::Comma
• 3 – Apóstrofo ('), valor de enumeración ThousandSeparator::Aptrophe
• 4 – Espacio ( ), valor de enumeración ThousandSeparator::Space

Example

En el ejemplo de código siguiente, la primera llamada al método num2str proporciona 16 para el parámetro decimals y la segunda llamada proporciona 17.

static void Job_Num2Str(Args _args)
{
    real realNum = 0.1294567890123456777; // 19 decimals places.
    info(Num2Str(realNum, 0, 16, DecimalSeparator::Dot, ThousandSeparator::Space)); // 16 decimal places
    info(Num2Str(realNum, 0, 17, DecimalSeparator::Dot, ThousandSeparator::Space)); // 17 decimal places
}

Salida

Los mensajes se encuentran en la siguiente salida de Infolog. El primer número de la salida contiene 16 dígitos de posición decimal, mientras que el segundo número contiene solo dos dígitos de posición decimal.

Message (10:18:12)
0.1294567890123457
0.13

str2Date

Convierte la cadena especificada en un valor de fecha .

date str2Date(str _text, str _sequence)

Parámetros

Valor devuelto

Valor de fecha .

Observaciones

Use los valores siguientes para especificar las posiciones del día, mes y año en el parámetro _sequence :

• Día: 1
• Mes: 2
• Año: 3

Por ejemplo, si la secuencia de la cadena es mes, año y día, el parámetro _sequence debe ser 231. Se devuelve una fecha 0 (cero) si los parámetros de entrada especifican una fecha no válida. En los dos ejemplos siguientes se especifica una fecha no válida.

str2Date("31/12/44", 123) // Year must be four digits to reach the minimum of January 1 1901.
str2Date("31/12/2044", 213) // 213 means the month occurs first in the string, but 31 cannot be a month.

Example

static void str2DateExample(Args _arg)
{
    date d;
    d = str2Date("22/11/2007", 123);
    print d;
}

str2Datetime

Genera un valor utcdatetime a partir de la cadena especificada de información de fecha y hora.

utcdatetime str2datetime( str text, int sequence )

Parámetros

Valor devuelto

Valor utcdatetime que representa la fecha y hora especificadas.

Observaciones

Los requisitos de sintaxis para la parte de fecha del parámetro de texto son flexibles. La variedad de formatos válidos es la misma que en la función date2str . Cada una de las siguientes llamadas a str2datetime es válida y todas generan la misma salida.

utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
utc3 = str2datetime( "Feb-1985-25 11:04:59 pm" ,231 );
utc3 = str2datetime( "2 25 1985 11:04:59 pm" ,123 );

Cada componente de la fecha y hora se representa mediante un dígito en el parámetro de secuencia :

• 1 – Día
• 2 – Mes
• 3 – Año

Por ejemplo, año, mes, orden de día es 321. Todos los valores válidos contienen cada uno de estos tres dígitos exactamente una vez. Si el valor del parámetro de secuencia no es válido, la configuración regional se usa para interpretar el parámetro de texto de entrada. Si los parámetros de entrada describen una fecha y hora no válidas, se devuelve una cadena vacía.

Example

static void JobTestStr2datetime( Args _args )
{
    utcdatetime utc3;
    str sTemp;
    utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
    sTemp = datetime2str( utc3 );
    print( "sTemp == " + sTemp );
}

str2Enum

Recupera el elemento de enumeración para el que el valor de la propiedad Label localizado coincide con la cadena de entrada.

enum str2Enum(enum _type, str _text)

Parámetros

Valor devuelto

Elemento de la enumeración de destino, que también representa un valor int.

Observaciones

La función relacionada enum2str devuelve el valor de una propiedad Label de un elemento de la enumeración. El valor devuelto por la función enum2str puede ser la entrada del parámetro _type de la función str2enum . Un valor adecuado para el parámetro _text es enum2Str(BankAccountType::SavingsAccount). Cada elemento de una enumeración tiene una propiedad Name y una propiedad Label . En una instalación nueva, los valores name son casi siempre palabras en inglés. En la edición en inglés, el valor de la propiedad Label es casi siempre el mismo que el valor Name . Sin embargo, en las ediciones que no son en inglés, los valores label se localizan y, por tanto, no coinciden con los valores name .

Example

Para evitar errores de coincidencia de cadenas causados por la localización a otros lenguajes hablados, se recomienda usar la función enum2str para generar la entrada en la función str2enum . En el ejemplo siguiente se muestra la manera adecuada de usar la función str2enum junto con la función enum2str .

static void str2Enum_AcrossLangs(Args _arg)
{
    BankAccountType bat;
    str sEnumValueLabelLocalized;
    int nInt;
    // enum2str.
    sEnumValueLabelLocalized = enum2str(BankAccountType::SavingsAccount);
    info("Localized friendly string: "
        + sEnumValueLabelLocalized);
    // str2enum.
    bat = str2Enum(bat, sEnumValueLabelLocalized);
    nInt = bat;
    info("nInt = " + int2str(nInt));
    /********** Actual output:
    Message (04:32:12 pm)
    Localized friendly string: Savings account
    nInt = 1
    **********/
}

str2Guid

Convierte una cadena en un objeto GUID.

Guid str2Guid(str text)

Parámetros

Valor devuelto

GUID representado por la cadena de entrada.

Observaciones

Por ejemplo, un valor válido para el parámetro guid es {12345678-1234-abCD-3456-123456789012}, ya sea con o sin llaves.

str2Int

Convierte una cadena en el entero equivalente.

int str2Int(str _text)

Parámetros

Valor devuelto

Equivalente entero de la cadena especificada.

Example

static void str2IntExample(Args _arg)
{
    int i;
    i = str2Int("1234567890");
    print "i = " + int2Str(i);
}

str2Int64

Convierte una cadena en un valor Int64 .

int str2Int64(str text)

Parámetros

Valor devuelto

Valor Int64 de la cadena especificada.

Example

static void str2Int64Example(Args _args)
{
    str myStr;
    str tooBig;
    Int64 myInt64;
    myStr = "1234567890";
    tooBig = int642str(int64Max()+1);
    myInt64 = str2Int64(mystr);
    print strfmt ("int64: %1",myInt64);
    myInt64 = str2Int64(tooBig);
    print strfmt ("Too big int64: %1",myInt64);
}

str2Num

Convierte una cadena en un número real.

real str2Num(str _text)

Parámetros

Valor devuelto

Número real si la cadena especificada contiene un número válido; de lo contrario, 0 (cero).

Observaciones

En los ejemplos siguientes se muestra cómo se usa esta función.

str2Num("123.45") returns the value 123.45.
str2Num("a123") returns the value 0.0.
str2Num("123a") returns the value 123.00.

El examen se produce de izquierda a derecha y finaliza cuando un carácter no se puede convertir en parte de un número real.

Example

static void str2NumToReal(Args _arg)
{
    real r;
    str s;
    r = str2Num("3.15");
    s = strFmt("r = %1", r);
    info(s);
}
/*** Infolog output.
Message_@SYS14327 (02:36:12 pm)
r = 3.15
***/

static void str2NumExponentialSyntax(Args _args)
{
    Qty qty1, qty2, qty3;
    qty1 = str2num('1e-3'); // Bad syntax by the user.
    qty2 = str2num('1.e-3');
    qty3 = str2num('1.0e-3');
    info(strfmt('Result: %1; Expected: %2', num2str(qty1, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty2, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty3, 0,3,2,0), '0.001'));
}
/*** Infolog output. The first result differs from expectations.
Message_@SYS14327 (02:20:55 pm)
Result: 1,000; Expected: 0.001
Result: 0,001; Expected: 0.001
Result: 0,001; Expected: 0.001
***/

str2Time

Convierte una cadena en un valor timeOfDay .

int str2Time(str _text)

Parámetros

Valor devuelto

Número de segundos entre medianoche y el parámetro _text ; de lo contrario, -1.

Observaciones

str2Time("05:01:37") //Returns the value 18097.
str2Time("7 o'clock") //Returns the value -1.

Example

static void str2TimeExample(Args _arg)
{
    int i;
    i = str2Time("11:30");
    print i;
}

time2Str

Convierte un valor timeOfDay en una cadena que incluye horas, minutos y segundos.

str time2Str(int _time, int _separator, int _timeFormat)

Parámetros

Valor devuelto

Cadena que representa la hora especificada.

Observaciones

El valor del parámetro _time es el número de segundos desde la medianoche.

Example

static void TimeJob4(Args _args)
{
    timeOfDay theTime = timeNow();
    info( time2Str(theTime, TimeSeparator::Colon, TimeFormat::AMPM) );
}
/**
Message (04:33:56 pm)
04:33:56 pm
**/

uint2Str

Convierte un entero en una cadena. La suposición es que el entero no tiene signo.

str uint2Str(int integer)

Parámetros

Valor devuelto

Cadena equivalente al entero sin signo especificado.

Observaciones

Use esta función en lugar de la función int2str para enteros muy grandes, como identificadores de registro.

info(int2str(3123456789)); //returns -1171510507 as a string.
info(uint2str(3123456789)); //returns 3123456789 as a string.