arg_min() (función de agregación)

Se aplica a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Busca una fila en la tabla que minimiza la expresión especificada. Devuelve todas las columnas de la tabla de entrada o columnas especificadas.

Alias en desuso: argmin()

Sintaxis

arg_min ( ExprToMinimize,* | ExprToReturn [, ...])

Obtenga más información sobre las convenciones de sintaxis.

Parámetros

Control nulo

Cuando ExprToMinimize es null para todas las filas de una tabla, se selecciona una fila de la tabla. De lo contrario, se omiten las filas donde ExprToMinimize es NULL.

Devoluciones

Devuelve una fila de la tabla que minimiza ExprToMinimizey los valores de las columnas especificadas en ExprToReturn. Use o * para devolver toda la fila.

Ejemplos

En el ejemplo siguiente se busca la latitud máxima de un evento storm en cada estado.

StormEvents 
| summarize arg_min(BeginLat, BeginLocation) by State

Salida

La tabla de resultados que se muestra incluye solo las primeras 10 filas.

Busque la primera vez que se produjo un evento con una muerte directa en cada estado, mostrando todas las columnas.

La consulta filtra primero los eventos para incluir solo aquellos en los que hubo al menos una muerte directa. A continuación, la consulta devuelve toda la fila con el valor más bajo de StartTime.

StormEvents
| where DeathsDirect > 0
| summarize arg_min(StartTime, *) by State

Salida

La tabla de resultados que se muestra incluye solo las primeras 10 filas y las primeras 3 columnas.

En el ejemplo siguiente se muestra el control nulo.

datatable(Fruit: string, Color: string, Version: int) [
    "Apple", "Red", 1,
    "Apple", "Green", int(null),
    "Banana", "Yellow", int(null),
    "Banana", "Green", int(null),
    "Pear", "Brown", 1,
    "Pear", "Green", 2,
]
| summarize arg_min(Version, *) by Fruit

Salida

Comparación con min()

La función arg_min() difiere de la función min(). La función arg_min() permite devolver columnas adicionales junto con el valor mínimo y min() solo devuelve el propio valor mínimo.

Ejemplos

En el ejemplo siguiente se usa arg_min() para buscar la última vez que se produjo un evento con una muerte directa en cada estado, mostrando todas las columnas.

StormEvents
| where DeathsDirect > 0
| summarize arg_min(StartTime, *)

La tabla de resultados devuelve todas las columnas de la fila que contiene el valor más bajo de la expresión especificada.

En el ejemplo siguiente se usa la función min() para buscar la última vez que se produjo un evento con una muerte directa en cada estado, pero solo devuelve el valor mínimo de StartTime.

StormEvents
| where DeathsDirect > 0
| summarize min(StartTime)

La tabla de resultados devuelve el valor más bajo solo en la columna específica.

Contenido relacionado

• de función mínima
• de función máxima
• de función promedio
• de función percentil
• de función mínima