Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

Las instrucciones let son útiles para:

• Dividir una expresión compleja en varias partes, cada una representada por una variable.
• Definir constantes fuera del cuerpo de la consulta para mejorar la legibilidad.
• Definir una variable una vez y usarla varias veces dentro de una consulta.

Si la variable anteriormente representaba otro valor, por ejemplo, en instrucciones anidadas, se aplicará la instrucción let más interna.

Para optimizar varios usos de la instrucción let en una sola consulta, vea Optimización de consultas que usan expresiones con nombre.

Sintaxis: expresiones escalares o tabulares

let Name=Expression

Learn more about syntax conventions.

Parameters

Sintaxis: vista o función

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

Los ejemplos de consulta muestran la sintaxis y el uso de ejemplo del operador, la instrucción o la función.

Definición de valores escalares

En el ejemplo siguiente se usa una instrucción de expresión escalar.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Definición de expresiones tabulares

En el ejemplo siguiente se enlaza el nombre some number mediante la notación ['name'] y, a continuación, se usa en una instrucción de expresión tabular.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Creación de una función definida por el usuario mediante cálculo escalar

En este ejemplo se usa la instrucción Let con argumentos para el cálculo escalar. La consulta define la función MultiplyByN para multiplicar dos números.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Creación de una función definida por el usuario que recorta la entrada

En el siguiente ejemplo se quitan los valores iniciales y finales de la entrada.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Uso de varias instrucciones Let

En este ejemplo se definen dos instrucciones Let de manera que una instrucción (foo2) usa a la otra (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Creación de una vista o una tabla virtual

En este ejemplo se muestra cómo usar una instrucción let para crear una view o tabla virtual.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Uso de la función materialize

La función materialize() permite almacenar en caché los resultados de la subconsulta durante la ejecución de la consulta. Cuando se usa la función materialize(), los datos se almacenan en caché y cualquier invocación posterior del resultado usa datos almacenados en caché.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Uso de instrucciones let anidadas

Se permite el uso de instrucciones let anidadas, incluida una expresión de función definida por el usuario. Las instrucciones y argumentos Let se aplican en el ámbito actual e interno del cuerpo de la función.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Argumento tabular con esquema

En el ejemplo siguiente se especifica que el parámetro T de tabla debe tener una columna State de tipo string. La tabla T también puede incluir otras columnas, pero no se puede hacer referencia a ellas en la función StateState porque no se declaran.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Argumento tabular con carácter comodín

El parámetro T de tabla puede tener cualquier esquema y la función CountRecordsInTable funcionará.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output