Método Chart.SeriesCollection (Project)

Devuelve un objeto que representa una serie (un objeto Series ) o una colección de la serie (un objeto SeriesCollection ) en el gráfico o grupo de gráficos.

Sintaxis

expresión. SeriesCollection (Index)

expresión Una variable que representa un objeto Chart.

Parameters

Valor devuelto

Objeto

Ejemplo

Para obtener una sola serie, especifique el parámetro Index . En el ejemplo siguiente se imprime el primer valor de la serie "Trabajo real". La primera llamada al método SeriesCollection obtiene la colección de todas las series del gráfico. La segunda llamada al método SeriesCollection obtiene una serie específica.

Sub GetSeriesValue()
    Dim reportName As String
    Dim theReportIndex As Integer
    Dim theChart As Chart
    Dim seriesInChart As SeriesCollection
    Dim chartSeries As Series
    
    reportName = "Simple scalar chart"
        
    If (ActiveProject.Reports.IsPresent(reportName)) Then
        ' Make the report active.
        theReportIndex = ActiveProject.Reports(reportName).Index
        ActiveProject.Reports(theReportIndex).Apply
        
        Set theChart = ActiveProject.Reports(theReportIndex).Shapes(1).Chart
        Set seriesInChart = theChart.SeriesCollection
        
        If (seriesInChart.Count > 1) Then
            Set chartSeries = theChart.SeriesCollection("Actual Work")
            Debug.Print "Value of the Actual Work series, for task " & chartSeries.XValues(1) _
                & ": " & chartSeries.Values(1)
        End If
        
    End If
End Sub

Por ejemplo, la ejecución de la macro GetSeriesValue en un gráfico que incluye un gráfico de trabajo real para tareas, podría tener la siguiente salida: Value of the Actual Work series, for task T1: 16

Vea también

Objeto Chart

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.