Compartir a través de

Método Shapes.AddWebControl (Publisher)

Agrega un nuevo objeto Shape que representa un control de formulario web a la colección Shapes especificada.

Sintaxis

expresión. AddWebControl (Type, Left, Top, Width, Height, LaunchPropertiesWindow)

expresión Variable que representa un objeto Shapes.

Parameters

Nombre Obligatorio/opcional Tipo de datos Descripción
Type Obligatorio PbWebControlType Especifica el tipo de control de formulario web que se va a agregar. Puede ser una de las constantes PbWebControlType declaradas en la biblioteca de tipos de Microsoft Publisher. Se produce un error si se usa pbWebControlWebComponent .
Left Obligatorio Variant Posición del borde izquierdo de la forma que representa el control de formulario web.
Top Obligatorio Variant Posición del borde superior de la forma que representa el control de formulario web.
Width Obligatorio Variant Ancho de la forma que representa el control de formulario web. Este parámetro se pasa por alto para botones de comando.
Height Obligatorio Variant Alto de la forma que representa el control de formulario web. Este parámetro se pasa por alto para botones de comando.
LaunchPropertiesWindow Opcional Boolean No se admite. El valor predeterminado es False; Si este argumento se establece en True, se produce un error.

Valor devuelto

Forma

Comentarios

Para los parámetros Left, Top, Width y Height , los valores numéricos se evalúan en puntos; Las cadenas pueden estar en cualquier unidad compatible con Microsoft Publisher (por ejemplo, "2,5 in").

Al agregar un punto de acceso frecuente a un control web mediante la constante pbWebControlHotSpot , la dirección URL se especifica mediante la propiedad Hyperlinks .

Tenga en cuenta que la propiedad Shape.Fill, que devuelve un objeto FillFormat y la propiedad Shape.Line, que devuelve un objeto LineFormat, no se pueden tener acceso a partir de una forma de zona activa. Si se intenta obtener acceso a estas propiedades desde una forma de zona activa, se devuelve un error en tiempo de ejecución.

Ejemplo

En el ejemplo siguiente se agrega un control de casilla de verificación de formulario web a la primera página de la publicación activa.

Dim shpCheckBox As Shape 
 
Set shpCheckBox = ActiveDocument.Pages(1).Shapes.AddWebControl _ 
 (Type:=pbWebControlCheckBox, _ 
 Left:=216, Top:=216, _ 
 Width:=18, Height:=18)

En el ejemplo siguiente se agregan puntos calientes a una forma de la página cuatro de la publicación web activa. En primer lugar, se agrega una autoforma de estrella de cuatro puntas a la página. A continuación, se agrega una zona activa a cada brazo de la estrella mediante el método AddWebControl con un tipo de pbWebControlHotSpot. Por último, se agrega un hipervínculo a cada punto activo mediante la propiedad Hyperlinks de cada forma de punto de acceso frecuente.

Dim theDoc As Document 
Dim theStar As Shape 
Dim theWC1 As Shape 
Dim theWC2 As Shape 
Dim theWC3 As Shape 
Dim theWC4 As Shape 
 
Set theDoc = ActiveDocument 
Set theStar = theDoc.Pages(4).Shapes.AddShape _ 
 (Type:=msoShape4pointStar, Left:=200, Top:=25, _ 
 Width:=200, Height:=200) 
 
With theDoc.Pages(4).Shapes 
 
 Set theWC1 = .AddWebControl(Type:=pbWebControlHotSpot, _ 
 Left:=280, Top:=25, Width:=40, Height:=80) 
 With theWC1 
 .Hyperlink.Address = "https://www.contoso.com/page1.htm" 
 End With 
 
 Set theWC2 = .AddWebControl(Type:=pbWebControlHotSpot, _ 
 Left:=320, Top:=105, Width:=80, Height:=40) 
 With theWC2 
 .Hyperlink.Address = "https://www.contoso.com/page2.htm" 
 End With 
 
 Set theWC3 = .AddWebControl(Type:=pbWebControlHotSpot, _ 
 Left:=280, Top:=145, Width:=40, Height:=80) 
 With theWC3 
 .Hyperlink.Address = "https://www.contoso.com/page3.htm" 
 End With 
 
 Set theWC4 = .AddWebControl(Type:=pbWebControlHotSpot, _ 
 Left:=200, Top:=105, Width:=80, Height:=40) 
 With theWC4 
 .Hyperlink.Address = "https://www.contoso.com/page4.htm" 
 End With 
End With

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.

  • Last updated on