Propiedad Shape.RowType (Visio)

Obtiene o establece el tipo de una fila en una sección de geometría, de puntos de conexión, de controles o de tabuladores de ShapeSheet. Lectura y escritura.

Sintaxis

expresión. RowType (Section, Row)

expresión Variable que representa un objeto Shape.

Parameters

Valor devuelto

Entero

Observaciones

Después de cambiar el tipo de una fila, el nuevo tipo de fila puede o no tener las mismas celdas. El programa debe proporcionar las fórmulas apropiadas para las celdas nuevas o para las modificadas.

Para especificar el tipo de fila que desee, establezca RowType en el mismo valor que cualquiera de las siguientes constantes declaradas en la biblioteca de tipos de Visio en el miembro VisRowTags.

Si se pasa una etiqueta de fila inapropiada o la fila no existe, no se producirá ningún cambio y se devolverá un error.

Utilice la propiedad RowName para realizar la transición desde las filas Puntos de conexión sin nombre a las filas Puntos de conexión con nombre.

Vea VisRowIndices para obtener una lista de constantes de fila válidas y VisRowTags para obtener una lista de constantes de etiqueta de fila válidas.

Consulte VisSectionIndices para obtener una lista de constantes de sección válidas.

Ejemplo

Esta macro de Microsoft Visual Basic para Aplicaciones (VBA) muestra cómo utilizar la propiedad RowType para cambiar el tipo de una fila de ShapeSheet. Dibuja un rectángulo en una página y curva las líneas de dicho rectángulo convirtiendo las líneas de la forma en arcos. Para ello, cambia los tipos de las filas de ShapeSheet para cada lado del rectángulo de LineTo a ArcTo y, a continuación, cambia los valores de las celdas X e Y en cada una de estas filas.

 
Public Sub RowType_Example() 
 
 Dim vsoPage As Visio.Page 
 Dim vsoShape As Visio.Shape 
 Dim vsoCell As Visio.Cell 
 Dim strBowCell As String 
 Dim strBowFormula As String 
 Dim intCounter As Integer 
 
 'Set the value of the strBowCell string. 
 strBowCell = "Scratch.X1" 
 
 'Set the value of the strBowFormula string. 
 strBowFormula = "=Min(Width, Height) / 5" 
 Set vsoPage = ActivePage 
 
 'If there isn't an active page, set vsoPage 
 'to the first page of the active document. 
 If vsoPage Is Nothing Then 
 
 Set vsoPage = ActiveDocument.Pages(1) 
 
 End If 
 
 'Draw a rectangle on the active page. 
 Set vsoShape = vsoPage.DrawRectangle(1, 5, 5, 1) 
 
 'Add a scratch section and add a row to the scratch section. 
 vsoShape.AddSection visSectionScratch 
 vsoShape.AddRow visSectionScratch, visRowScratch, 0 
 
 'Set vsoCell to the Scratch.X1 cell and set its formula. 
 Set vsoCell = vsoShape.Cells(strBowCell) 
 vsoCell.formula = strBowFormula 
 
 'Bow in or curve the rectangle's lines by changing 
 'each row type from LineTo to ArcTo and entering the bow value. 
 For intCounter = 1 To 4 
 
 vsoShape.RowType(visSectionFirstComponent, visRowVertex + intCounter) = visTagArcTo 
 Set vsoCell = vsoShape.CellsSRC(visSectionFirstComponent, visRowVertex + intCounter, 2) 
 vsoCell.formula = "-" & strBowCell 
 
 Next intCounter 
 
End Sub

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.