Compartir a través de

Date.FromText

Sintaxis

Date.FromText(text as nullable text, optional options as any) as nullable date

Acerca de

Crea un valor de fecha a partir de una representación textual.

  • text: valor de texto que se va a cubrir en una fecha.

  • options: opcional record que se puede proporcionar para especificar propiedades adicionales. record puede contener los campos siguientes:

    • Format: un valor text que indica el formato que se usará. Para obtener más información, vaya a Cadenas de formato de fecha y hora estándar y Cadenas de formato de fecha y hora personalizados. Omitir este campo o proporcionar null resultados al analizar la fecha con un mejor esfuerzo.
    • Culture: cuando Format no es null, Culture controla algunos especificadores de formato. Por ejemplo, en "en-US""MMM" es "Jan", "Feb", "Mar", ..., mientras que en "ru-RU""MMM" es "янв", "фев", "мар", .... Cuando Format es null, Culture controla el formato predeterminado que se va a usar. Cuando Culture es null o se omite, se usa Culture.Current.

Para admitir flujos de trabajo heredados, options también puede ser un valor de texto. Esto tiene el mismo comportamiento que options = [Format = null, Culture = options].

Ejemplo 1

Convertir "2010-12-31" en un valor date.

Uso

Date.FromText("2010-12-31")

Salida

#date(2010, 12, 31)

Ejemplo 2

Convertir con un formato personalizado y la referencia cultural alemana.

Uso

Date.FromText("30 Dez 2010", [Format="dd MMM yyyy", Culture="de-DE"])

Salida

#date(2010, 12, 30)

Ejemplo 3

Busque la fecha en el calendario gregoriano que corresponde al principio de 1400 en el calendario Hijri.

Uso

Date.FromText("1400", [Format="yyyy", Culture="ar-SA"])

Salida

#date(1979, 11, 20)

Ejemplo 4

Convierta las fechas de texto italiano con meses abreviados en la columna Fecha publicada a valores de fecha.

Uso

let
    Source = #table(type table [Account Code = text, Posted Date = text, Sales = number],
    {
        {"US-2004", "20 gen. 2023", 580},
        {"CA-8843", "18 lug. 2024", 280},
        {"PA-1274", "12 gen. 2023", 90},
        {"PA-4323", "14 apr. 2023", 187},
        {"US-1200", "14 dic. 2023", 350},
        {"PTY-507", "4 giu. 2024", 110}
    }),
    #"Converted Date" = Table.TransformColumns(
        Source, 
        {"Posted Date", each Date.FromText(_, [Culture = "it-IT"]), type date}
    )
in
    #"Converted Date"

Salida

#table(type table [Account Code = text, Posted Date = date, Sales = number],
{
    {"US-2004", #date(2023, 1, 20), 580},
    {"CA-8843", #date(2024, 7, 18), 280},
    {"PA-1274", #date(2023, 1, 12), 90},
    {"PA-4323", #date(2023, 4, 14), 187},
    {"US-1200", #date(2023, 12, 14), 350},
    {"PTY-507", #date(2024, 6, 4), 110}
})

Contenido relacionado

  • Last updated on