Web.Contents

Syntax

 
Web.Contents(url as text, optional options as nullable record) as binary

Acerca de

Devuelve el contenido descargado de url como binario. Se puede proporcionar un parámetro de registro opcional, options, para especificar propiedades adicionales. El registro puede contener los siguientes campos:

• Query: agregue mediante programación parámetros de consulta a la dirección URL sin tener que preocuparse por el escape.
• ApiKeyName: si el sitio de destino tiene una noción de una clave de API, este parámetro se puede usar para especificar el nombre (no el valor) del parámetro de clave que se debe usar en la dirección URL. El valor de clave real se proporciona en la credencial.
• Headers: si se especifica este valor como registro, se proporcionarán encabezados adicionales a una solicitud HTTP.
• Timeout: si se especifica este valor como una duración, se cambiará el tiempo de espera de una solicitud HTTP. El valor predeterminado es 100 segundos.
• ExcludedFromCacheKey: al especificar este valor como una lista se excluirán estas claves de encabezado HTTP de formar parte del cálculo de los datos de almacenamiento en caché.
• IsRetry: si se especifica este valor lógico como true, se omitirá cualquier respuesta existente en la memoria caché al capturar datos.
• ManualStatusHandling: si se especifica este valor como una lista, se impedirá cualquier control integrado de solicitudes HTTP cuya respuesta tenga uno de estos códigos de estado.
• RelativePath: al especificar este valor como texto se anexa a la dirección URL base antes de realizar la solicitud.
• Content: al especificar este valor se cambia la solicitud web de get a POST, utilizando el valor de la opción como el contenido de POST.

La solicitud HTTP se realiza como GET (cuando no se especifica ningún contenido) o post (cuando hay contenido). Las solicitudes POST solo se pueden realizar de forma anónima.

Los encabezados de la respuesta HTTP están disponibles como metadatos en el resultado binario. Fuera de un contexto de conector de datos personalizado, solo hay disponible un subconjunto de encabezados de respuesta (por motivos de seguridad).

Ejemplo 1

Recupere el contenido del uso de "https://bing.com/search?q=Power+Query" las RelativePath opciones y Query . Estas opciones se pueden usar para consultar dinámicamente una dirección URL base estática.

Uso

let
    searchText = "Power Query"
in
    Web.Contents(
        "https://www.bing.com",
        [
            RelativePath = "search",
            Query = [q = searchText]
        ]
    )

Salida

binary

Ejemplo 2

Realice una operación POST en una dirección URL, pasando una carga JSON binaria y analizando la respuesta como JSON.

Uso

let
    url = ...,
    headers = [#"Content-Type" = "application/json"],
    postData = Json.FromValue([x = 235.7, y = 41.53]),
    response = Web.Contents(
        url,
        [
            Headers = headers,
            Content = postData
        ]
    ),
    jsonResponse = Json.Document(response)
in
    jsonResponse

Salida

table

Ejemplo 3

Conéctese a una dirección URL segura que acepte una clave de autenticación como parte de su cadena de consulta. En lugar de codificar de forma rígida la clave secreta en M (lo que podría suponer un riesgo de seguridad), la clave se puede proporcionar de forma segura especificando su nombre (no su valor) en M, eligiendo autenticación de API web y escribiendo el valor de clave como parte de la credencial de api web. Cuando se usa de esta manera, el ejemplo siguiente generará una solicitud a "https://contoso.com/api/customers/get?api_key=******".

Uso

Web.Contents("https://contoso.com/api/customers/get", [ApiKeyName="api_key"])

Salida

binary

Información adicional

Control de código de estado con Web.Contents en conectores personalizados