Démarrage rapide : Créer et déployer des ressources Azure Functions à partir de Terraform

Dans ce guide de démarrage rapide, vous utilisez Terraform pour créer une application de fonction dans un plan Flex Consumption dans Azure Functions, ainsi que d’autres ressources Azure requises. Le plan Flex Consumption fournit un hébergement serverless qui vous permet d’exécuter votre code à la demande sans provisionner ou gérer explicitement l’infrastructure. L’application de fonction s’exécute sur Linux et est configurée pour utiliser le stockage Blob Azure pour les déploiements de code.

Terraform active la définition, la préversion et le déploiement de l’infrastructure cloud. À l’aide de Terraform, vous créez des fichiers de configuration à l’aide de la syntaxe HCL. La syntaxe HCL vous permet de spécifier le fournisseur de cloud , tel qu’Azure, et les éléments qui composent votre infrastructure cloud. Après avoir créé vos fichiers de configuration, vous créez un plan d’exécution qui vous permet d’afficher un aperçu des modifications de votre infrastructure avant leur déploiement. Une fois que vous avez vérifié les modifications, vous appliquez le plan d’exécution pour déployer l’infrastructure.

Créez un groupe de ressources Azure avec un nom unique.
Générez une chaîne aléatoire de 13 lettres minuscules pour nommer les ressources.
Créez un compte de stockage dans Azure.
Créez un conteneur de stockage d’objets blob dans le compte de stockage.
Créez un plan Flex Consumption dans Azure Functions.
Créez une application de fonction avec un plan Flex Consumption dans Azure.
Affichez les noms du groupe de ressources, du compte de stockage, du plan de service, de l'application de fonction et du plan de consommation Flex d’Azure Functions.

Prerequisites

Créer un compte Azure avec un abonnement actif. Vous pouvez créer un compte gratuitement.
Installez et configurez Terraform.
Installez Azure CLI pour obtenir l’ID d’abonnement ou l’exécuter dans Azure Cloud Shell.

Implémenter le code Terraform

L’exemple de code de cet article se trouve dans le dépôt GitHub Azure Terraform . Vous pouvez afficher le fichier journal contenant les résultats des tests des versions actuelles et précédentes de Terraform. Consultez d’autres articles et exemples de code montrant comment utiliser Terraform pour gérer les ressources Azure.

Créez un répertoire dans lequel tester et exécuter l’exemple de code Terraform, et définissez-le en tant que répertoire actif.

Créez un fichier nommé main.tf et insérez le code suivant :

# This Terraform configuration creates a Flex Consumption plan app in Azure Functions 
# with the required Storage account and Blob Storage deployment container.

# Create a random pet to generate a unique resource group name
resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

# Create a resource group
resource "azurerm_resource_group" "example" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

# Random String for unique naming of resources
resource "random_string" "name" {
  length  = 8
  special = false
  upper   = false
  lower   = true
  numeric = false
}

# Create a storage account
resource "azurerm_storage_account" "example" {
  name                     = coalesce(var.sa_name, random_string.name.result)
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = var.sa_account_tier
  account_replication_type = var.sa_account_replication_type
}

# Create a storage container
resource "azurerm_storage_container" "example" {
  name                  = "example-flexcontainer"
  storage_account_id    = azurerm_storage_account.example.id
  container_access_type = "private"
}

# Create a Log Analytics workspace for Application Insights
resource "azurerm_log_analytics_workspace" "example" {
  name                = coalesce(var.ws_name, random_string.name.result)
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  sku                 = "PerGB2018"
  retention_in_days   = 30
}

# Create an Application Insights instance for monitoring
resource "azurerm_application_insights" "example" {
  name                = coalesce(var.ai_name, random_string.name.result)
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  application_type    = "web"
  workspace_id = azurerm_log_analytics_workspace.example.id
}

# Create a service plan
resource "azurerm_service_plan" "example" {
  name                = coalesce(var.asp_name, random_string.name.result)
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  sku_name            = "FC1"
  os_type             = "Linux"
}

# Create a function app
resource "azurerm_function_app_flex_consumption" "example" {
  name                = coalesce(var.fa_name, random_string.name.result)
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  service_plan_id     = azurerm_service_plan.example.id

  storage_container_type      = "blobContainer"
  storage_container_endpoint  = "${azurerm_storage_account.example.primary_blob_endpoint}${azurerm_storage_container.example.name}"
  storage_authentication_type = "StorageAccountConnectionString"
  storage_access_key          = azurerm_storage_account.example.primary_access_key
  runtime_name                = var.runtime_name
  runtime_version             = var.runtime_version
  maximum_instance_count      = 50
  instance_memory_in_mb       = 2048
  
  site_config {
  }
}

Créez un fichier nommé outputs.tf et insérez le code suivant :

output "resource_group_name" {
  value = azurerm_resource_group.example.name
}

output "sa_name" {
  value = azurerm_storage_account.example.name
}

output "asp_name" {
  value = azurerm_service_plan.example.name
}

output "fa_name" {
  value = azurerm_function_app_flex_consumption.example.name
}

output "fa_url" {
  value = "https://${azurerm_function_app_flex_consumption.example.name}.azurewebsites.net"
}

Créez un fichier nommé providers.tf et insérez le code suivant :

terraform {
  required_version = ">=1.0"

  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~>4.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

Créez un fichier nommé variables.tf et insérez le code suivant :

variable "resource_group_name" {
  type        = string
  default     = ""
  description = "The name of the Azure resource group. If blank, a random name will be generated."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "resource_group_location" {
  type        = string
  default     = "eastus"
  description = "Location of the resource group."
}

variable "sa_account_tier" {
  description = "The tier of the storage account. Possible values are Standard and Premium."
  type        = string
  default     = "Standard"
}

variable "sa_account_replication_type" {
  description = "The replication type of the storage account. Possible values are LRS, GRS, RAGRS, and ZRS."
  type        = string
  default     = "LRS"
}

variable "sa_name" {
  description = "The name of the storage account. If blank, a random name will be generated."
  type        = string
  default     = ""
}

variable "ws_name" {
  description = "The name of the Log Analytics workspace. If blank, a random name will be generated."
  type        = string
  default     = ""
}

variable "ai_name" {
  description = "The name of the Application Insights instance. If blank, a random name will be generated."
  type        = string
  default     = ""
}

variable "asp_name" {
  description = "The name of the App Service Plan. If blank, a random name will be generated."
  type        = string
  default     = ""
}

variable "fa_name" {
  description = "The name of the Function App. If blank, a random name will be generated."
  type        = string
  default     = ""
}

variable "runtime_name" {
  description = "The name of the language worker runtime."
  type        = string
  default     = "node" # Allowed: dotnet-isolated, java, node, powershell, python
}

variable "runtime_version" {
  description = "The version of the language worker runtime."
  type        = string
  default     = "20" # Supported versions: see https://aka.ms/flexfxversions
}

Utilisez cette commande Azure CLI pour définir la ARM_SUBSCRIPTION_ID variable d’environnement sur l’ID de votre abonnement actuel :
```
export ARM_SUBSCRIPTION_ID=$(az account show --query "id" --output tsv)
```
Vous devez avoir cette variable définie pour que Terraform puisse s’authentifier auprès de votre abonnement Azure.

Initialisez Terraform

Exécutez terraform init pour initialiser le déploiement Terraform. Cette commande télécharge le fournisseur Azure requis pour gérer vos ressources Azure.

terraform init -upgrade

Points clés :

Le paramètre -upgrade met à niveau les plug-ins de fournisseur nécessaires vers la version la plus récente conforme aux contraintes de version de la configuration.

Créer un plan d’exécution Terraform

Exécutez le plan terraform pour créer un plan d’exécution.

terraform plan -out main.tfplan -var="runtime_name=dotnet-isolated" -var="runtime_version=8"

terraform plan -out main.tfplan -var="runtime_name=powershell" -var="runtime_version=7.4"

terraform plan -out main.tfplan -var="runtime_name=python" -var="runtime_version=3.12"

terraform plan -out main.tfplan -var="runtime_name=java" -var="runtime_version=21"

terraform plan -out main.tfplan -var="runtime_name=node" -var="runtime_version=20"

Assurez-vous que runtime_version correspond à la version de la pile linguistique que vous avez vérifiée localement. Sélectionnez votre pile de langues préférée en haut de l’article.

Points clés :

La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, il détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution correspond à vos attentes avant d’apporter des modifications aux ressources réelles.
Le paramètre -out facultatif vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné est exactement ce qui est appliqué.

Appliquer un plan d’exécution Terraform

Exécutez terraform pour appliquer le plan d’exécution à votre infrastructure cloud.

terraform apply main.tfplan

Points clés :

L’exemple terraform apply commande suppose que vous avez précédemment exécuté terraform plan -out main.tfplan.
Si vous avez spécifié un nom de fichier différent pour le paramètre -out, utilisez ce même nom de fichier dans l’appel à terraform apply.
Si vous n’avez pas utilisé le paramètre -out, appelez terraform apply sans aucun paramètre.

Vérifier les résultats

Le outputs.tf fichier retourne ces valeurs pour votre nouvelle application de fonction :

Value	Description
`resource_group_name`	Le nom du groupe de ressources créé.
`sa_name`	Nom du compte de stockage Azure requis par l’hôte Functions.
`asp_name`	Nom du plan Flex Consumption qui héberge votre nouvelle application.
`fa_name`	Nom de votre nouvelle application de fonction.
`fa_url`	URL de votre nouveau point de terminaison d’application de fonction.

Ouvrez un navigateur et accédez à l’emplacement de l’URL dans fa_url. Vous pouvez également utiliser la commande de sortie terraform pour passer en revue ces valeurs ultérieurement.

Capture d’écran de l’application Azure Functions « Page d’accueil ».

Nettoyer les ressources

Lorsque vous n’avez plus besoin des ressources créées via Terraform, procédez comme suit :

Exécutez terraform plan et spécifiez le flag destroy.
```
terraform plan -destroy -out main.destroy.tfplan
```
Points clés :
- La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, il détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution correspond à vos attentes avant d’apporter des modifications aux ressources réelles.
- Le paramètre -out facultatif vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné est exactement ce qui est appliqué.
Exécutez terraform apply pour appliquer le plan d’exécution.
```
terraform apply main.destroy.tfplan
```

Résoudre les problèmes de Terraform sur Azure

Résoudre les problèmes courants liés à l’utilisation de Terraform sur Azure.

Étapes suivantes

Vous pouvez maintenant déployer un projet de code sur les ressources de l’application de fonction que vous avez créées dans Azure.

Vous pouvez créer, vérifier et déployer un projet de code sur votre nouvelle application de fonction à partir de ces environnements locaux :

Commentaires

Cette page a-t-elle été utile ?

Last updated on 2025-10-08

Partager via

Démarrage rapide : Créer et déployer des ressources Azure Functions à partir de Terraform

Prerequisites

Implémenter le code Terraform

Initialisez Terraform

Créer un plan d’exécution Terraform

Appliquer un plan d’exécution Terraform

Vérifier les résultats

Nettoyer les ressources

Résoudre les problèmes de Terraform sur Azure

Étapes suivantes

Commentaires

Ressources supplémentaires