Démarrage rapide : Créer une tâche de stockage avec Bicep

Ce guide de démarrage rapide explique comment créer une tâche de stockage à l’aide de Bicep.

Bicep est un langage spécifique à un domaine (DSL) qui utilise la syntaxe déclarative pour déployer des ressources Azure. Il fournit une syntaxe concise, une cohérence des types fiable et une prise en charge de la réutilisation du code. Bicep offre la meilleure expérience de création pour vos solutions d’infrastructure en tant que code dans Azure.

Conditions préalables

Si vous n’avez pas d’abonnement Azure, créez un compte gratuit avant de commencer.

Examiner le fichier Bicep

Le fichier Bicep utilisé dans ce guide de démarrage rapide est tiré des modèles de démarrage rapide Azure.

@sys.description('The name of storage task.')
@minLength(3)
@maxLength(18)
param storageTaskName string

@sys.description('A description of the storage task.')
param description string

@sys.description('The region in which to create the storage task.')
param location string = resourceGroup().location

@sys.description('Locks the file for one day.')
param lockedUntilDate string = dateTimeAdd(utcNow(), 'P1D')

resource storageTask 'Microsoft.StorageActions/storageTasks@2023-01-01' = {
  name: storageTaskName
  location: location
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    action: {
      if: {
        condition: '[[endsWith(Name, \'.docx\')]]'
        operations: [
         {
            name: 'SetBlobImmutabilityPolicy'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
              untilDate: lockedUntilDate
              mode: 'locked'
            }
         }
         {
            name: 'SetBlobTags'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
                tagsetImmutabilityUpdatedBy: 'StorageTaskQuickstart'
            }     
         }
        ]
      }

    }
    description: description
    enabled: true
  }
}

La ressource Microsoft.StorageActions/storageTasks Azure est définie dans le fichier Bicep.

Déployer le fichier Bicep

1. Enregistrez le fichier Bicep en tant que main.bicep sur votre ordinateur local.

2. Déployez le fichier Bicep à l’aide d’Azure CLI ou d’Azure PowerShell.

az group create --name exampleRG --location <region>

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageTaskName="<storage-task-name>" description="<description>" 

New-AzResourceGroup -Name exampleRG -Location <region>

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageTaskName "<storage-task-name>" -description "<description>"

Passer en revue les ressources déployées

1. Dans le Portail Microsoft Azure, recherchez Tâches de stockage. Ensuite, sous Services, sélectionnez Tâches de stockage - Actions de stockage Azure.

2. Dans la liste des tâches de stockage, recherchez le nom de la tâche de stockage que vous avez déployée.

   

Nettoyer les ressources

Lorsqu’il n’est plus nécessaire, supprimez le groupe de ressources. Le groupe de ressources et toutes les ressources du groupe de ressources sont supprimés. Utilisez la commande suivante pour supprimer le groupe de ressources et toutes ses ressources contenues.

az group delete --name <resource-group-name>

Remove-AzResourceGroup -Name <resource-group-name>

Remplacez <resource-group-name> par le nom de votre groupe de ressources.

Étapes suivantes

Affectez une tâche de stockage à un compte de stockage.