Démarrage rapide : Diriger le trafic web avec Azure Application Gateway - Terraform

Dans ce guide de démarrage rapide, vous allez utiliser Terraform pour créer une passerelle Azure Application Gateway. Ensuite, vous la testerez pour être sûr qu’elle fonctionne correctement. La référence SKU Standard v2 est utilisée dans cet exemple.

Terraform active la définition, la préversion et le déploiement de l’infrastructure cloud. À l’aide de Terraform, vous créez des fichiers de configuration à l’aide de la syntaxe HCL. La syntaxe HCL vous permet de spécifier le fournisseur de cloud , tel qu’Azure, et les éléments qui composent votre infrastructure cloud. Après avoir créé vos fichiers de configuration, vous créez un plan d’exécution qui vous permet d’afficher un aperçu des modifications de votre infrastructure avant leur déploiement. Une fois que vous avez vérifié les modifications, vous appliquez le plan d’exécution pour déployer l’infrastructure.

Conditions préalables

• Installer et configurer Terraform

Implémenter le code Terraform

1. Créez un répertoire dans lequel tester l’exemple de code Terraform et définissez-le comme répertoire actuel.

2. Créez un fichier nommé providers.tf et insérez le code suivant :

   terraform {
     required_version = ">=1.2"
     
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~> 3.0"
       }
       random = {
         source = "hashicorp/random"
         version = "~> 3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Créez un fichier nommé main.tf et insérez le code suivant :

   resource "random_string" "rg" {
     length  = 8
     upper   = false
     special = false
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = "101-application-gateway-${random_string.rg.result}"
     location = "eastus"
   }
   
   resource "azurerm_virtual_network" "vnet" {
     name                = "myVNet"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     address_space       = ["10.21.0.0/16"]
   }
   
   resource "azurerm_subnet" "frontend" {
     name                 = "myAGSubnet"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.vnet.name
     address_prefixes     = ["10.21.0.0/24"]
   }
   
   resource "azurerm_subnet" "backend" {
     name                 = "myBackendSubnet"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.vnet.name
     address_prefixes     = ["10.21.1.0/24"]
   }
   
   resource "azurerm_public_ip" "pip" {
     name                = "myAGPublicIPAddress"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     allocation_method   = "Static"
     sku                 = "Standard"
   }
   
   
   resource "azurerm_application_gateway" "main" {
     name                = "myAppGateway"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
   
     sku {
       name     = "Standard_v2"
       tier     = "Standard_v2"
       capacity = 2
     }
   
     gateway_ip_configuration {
       name      = "my-gateway-ip-configuration"
       subnet_id = azurerm_subnet.frontend.id
     }
   
     frontend_port {
       name = var.frontend_port_name
       port = 80
     }
   
     frontend_ip_configuration {
       name                 = var.frontend_ip_configuration_name
       public_ip_address_id = azurerm_public_ip.pip.id
     }
   
     backend_address_pool {
       name = var.backend_address_pool_name
     }
   
     backend_http_settings {
       name                  = var.http_setting_name
       cookie_based_affinity = "Disabled"
       port                  = 80
       protocol              = "Http"
       request_timeout       = 60
     }
   
     http_listener {
       name                           = var.listener_name
       frontend_ip_configuration_name = var.frontend_ip_configuration_name
       frontend_port_name             = var.frontend_port_name
       protocol                       = "Http"
     }
   
     request_routing_rule {
       name                       = var.request_routing_rule_name
       rule_type                  = "Basic"
       http_listener_name         = var.listener_name
       backend_address_pool_name  = var.backend_address_pool_name
       backend_http_settings_name = var.http_setting_name
       priority                   = 1
     }
   }
   
   resource "azurerm_network_interface" "nic" {
     count               = 2
     name                = "nic-${count.index+1}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
   
     ip_configuration {
       name                          = "nic-ipconfig-${count.index+1}"
       subnet_id                     = azurerm_subnet.backend.id
       private_ip_address_allocation = "Dynamic"
     }
   }
   
   resource "azurerm_network_interface_application_gateway_backend_address_pool_association" "nic-assoc" {
     count                   = 2
     network_interface_id    = azurerm_network_interface.nic[count.index].id
     ip_configuration_name   = "nic-ipconfig-${count.index+1}"
     backend_address_pool_id = one(azurerm_application_gateway.main.backend_address_pool).id
   }
   
   resource "random_password" "password" {
     length  = 16
     special = true
     lower   = true
     upper   = true
     numeric = true
   }
   
   resource "azurerm_windows_virtual_machine" "vm" {
     count               = 2
     name                = "myVM${count.index+1}"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     size                = "Standard_DS1_v2"
     admin_username      = "azureadmin"
     admin_password      = random_password.password.result
   
     network_interface_ids = [
       azurerm_network_interface.nic[count.index].id,
     ]
   
     os_disk {
       caching              = "ReadWrite"
       storage_account_type = "Standard_LRS"
     }
   
   
     source_image_reference {
       publisher = "MicrosoftWindowsServer"
       offer     = "WindowsServer"
       sku       = "2019-Datacenter"
       version   = "latest"
     }
   }
   
   resource "azurerm_virtual_machine_extension" "vm-extensions" {
     count                = 2
     name                 = "vm${count.index+1}-ext"
     virtual_machine_id   = azurerm_windows_virtual_machine.vm[count.index].id
     publisher            = "Microsoft.Compute"
     type                 = "CustomScriptExtension"
     type_handler_version = "1.10"
   
     settings = <<SETTINGS
       {
           "commandToExecute": "powershell Add-WindowsFeature Web-Server; powershell Add-Content -Path \"C:\\inetpub\\wwwroot\\Default.htm\" -Value $($env:computername)"
       }
   SETTINGS
   
   }
   

4. Créez un fichier nommé variables.tf et insérez le code suivant :

   variable "backend_address_pool_name" {
       default = "myBackendPool"
   }
   
   variable "frontend_port_name" {
       default = "myFrontendPort"
   }
   
   variable "frontend_ip_configuration_name" {
       default = "myAGIPConfig"
   }
   
   variable "http_setting_name" {
       default = "myHTTPsetting"
   }
   
   variable "listener_name" {
       default = "myListener"
   }
   
   variable "request_routing_rule_name" {
       default = "myRoutingRule"
   }
   

5. Créez un fichier nommé outputs.tf et insérez le code suivant :

   output "gateway_frontend_ip" {
     value = "http://${azurerm_public_ip.pip.ip_address}"
   }
   

Initialisez Terraform

Exécutez terraform init pour initialiser le déploiement Terraform. Cette commande télécharge le fournisseur Azure requis pour gérer vos ressources Azure.

terraform init -upgrade

Points clés :

• Le paramètre -upgrade met à niveau les plug-ins de fournisseur nécessaires vers la version la plus récente conforme aux contraintes de version de la configuration.

Créer un plan d’exécution Terraform

Exécutez le plan terraform pour créer un plan d’exécution.

terraform plan -out main.tfplan

Points clés :

• La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, il détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution correspond à vos attentes avant d’apporter des modifications aux ressources réelles.
• Le paramètre -out facultatif vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné est exactement ce qui est appliqué.

Appliquer un plan d’exécution Terraform

Exécutez terraform pour appliquer le plan d’exécution à votre infrastructure cloud.

terraform apply main.tfplan

Points clés :

• L’exemple terraform apply commande suppose que vous avez précédemment exécuté terraform plan -out main.tfplan.
• Si vous avez spécifié un nom de fichier différent pour le paramètre -out, utilisez ce même nom de fichier dans l’appel à terraform apply.
• Si vous n’avez pas utilisé le paramètre -out, appelez terraform apply sans aucun paramètre.

Vérifier les résultats

1. Lorsque vous appliquez le plan d’exécution, Terraform génère l’adresse IP publique. Si vous avez effacé l’écran, vous pouvez récupérer cette valeur avec la commande Terraform suivante :

   echo $(terraform output -raw gateway_frontend_ip)
   

2. Copiez et collez l’adresse IP publique dans la barre d’adresse de votre navigateur. Actualisez le navigateur pour voir le nom de la machine virtuelle. Une réponse valide vérifie que la passerelle d’application a été créée et qu’elle peut se connecter au serveur principal.

Nettoyer les ressources

Lorsque vous n’avez plus besoin des ressources créées via Terraform, procédez comme suit :

1. Exécutez terraform plan et spécifiez le flag destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Points clés :

   • La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, il détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution correspond à vos attentes avant d’apporter des modifications aux ressources réelles.
   • Le paramètre -out facultatif vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné est exactement ce qui est appliqué.

2. Exécutez terraform apply pour appliquer le plan d’exécution.

   terraform apply main.destroy.tfplan
   

Résoudre les problèmes de Terraform sur Azure

Résoudre les problèmes courants lors de l’utilisation de Terraform sur Azure

Étapes suivantes