Partager via

Réduire vos émissions de carbone dans Azure

L’optimisation du carbone dans Azure fonctionne avec Azure Advisor pour fournir des recommandations d’optimisation. Azure Advisor identifie les ressources inactives et sous-utilisées et affiche les économies de carbone et de coûts associées de l’implémentation des recommandations. Les recommandations peuvent inclure l’arrêt des machines virtuelles inactives et la gestion des droits des machines virtuelles. Pour plus de recommandations et d’informations sur Azure Advisor, consultez Réduire les coûts de service à l’aide d’Azure Advisor.

Pour afficher les recommandations d’optimisation du carbone, accédez à la page Réduction des émissions, puis sélectionnez l’abonnement et les groupes de ressources souhaités.

Cette page présente le nombre total de recommandations disponibles et les opportunités d’économies potentielles en termes de coût et de carbone. Elle indique également les équivalents d'économies de carbone calculés par le calculateur d'équivalents de gaz à effet de serre de l'agence américaine pour la protection de l'environnement (EPA).

Afficher les recommandations

La liste des recommandations du tableau montre des ressources utilisées inefficacement qui peuvent contribuer à réduire les émissions de carbone. Chaque recommandation montre les économies de carbone associées et les économies potentielles de coûts qui peuvent provenir d’agir sur une recommandation.

Agir sur la recommandation

Pour agir sur la recommandation, sélectionnez le nom de la ressource ou le texte de la colonne Recommandation. La sélection du texte de recommandation vous permet d’accéder à la page d’action de la ressource. Par exemple, la page de redimensionnement, la page de modification du nombre d’instances ou la page vue d’ensemble des ressources pour les recommandations de suppression.

Capture d’écran montrant la page de réduction des émissions.

Convertir les économies d’émissions en équivalents

Le calculateur d'équivalences de gaz à effet de serre vous permet de convertir les données relatives aux émissions en quantité équivalente de dioxyde de carbone (CO2) émise par l'utilisation de cette quantité. La calculatrice vous aide à traduire des mesures abstraites en termes concrets, comme les émissions annuelles provenant d’arbres, de ménages ou de sacs poubelles. Cette calculatrice peut être utile pour communiquer votre stratégie de réduction des gaz à effet de serre, vos objectifs de réduction ou d’autres initiatives visant à réduire les émissions de gaz à effet de serre.

Pour en savoir plus sur les types de recommandations, consultez Réduire les coûts de service à l’aide d’Azure Advisor.

Recommandations relatives à la réduction des émissions d’exportation

Vous pouvez exporter des recommandations de réduction des émissions à l’aide d’Azure Resource Graph. Exécutez la requête suivante dans l’Explorateur Azure Resource Graph. Ensuite, vous pouvez télécharger les résultats au format CSV.

L’exportation inclut :

  • ID de recommandation
  • ID d’abonnement/Nom de l’abonnement
  • Nom du groupe de ressources
  • Économies mensuelles sur les coûts
  • Économies mensuelles de carbone en kilogrammes
  • Nom de la ressource
  • Message de recommandation
  • Type de recommandation
  • Détails sur la recommandation, y compris les métadonnées de ressource, telles que l’ID de ressource et le nom du rôle
// Export emissions reduction recommendations using Azure Resource Graph

advisorresources
  | where tolower(type) == "microsoft.advisor/recommendations"
  | extend RecommendationTypeId = tostring(properties.recommendationTypeId)
  | where RecommendationTypeId in ("94aea435-ef39-493f-a547-8408092c22a7", "e10b1381-5f0a-47ff-8c7b-37bd13d7c974")
  | project stableId=name, subscriptionId, resourceGroup, properties, recommendationId=id
  | join kind=leftouter(
      advisorresources
      | where tolower(type) == 'microsoft.advisor/suppressions'
      | extend tokens = split(id, '/')
      | extend stableId = iff(array_length(tokens) > 3, tokens[(array_length(tokens)-3)], '')
      | extend expirationTimeStamp = todatetime(iff(strcmp(tostring(properties.ttl), '-1') == 0, '9999-12-31', properties.expirationTimeStamp))
      | where expirationTimeStamp > now()
      | project suppressionId = tostring(properties.suppressionId), stableId, expirationTimeStamp
  ) on stableId
  | join kind = leftouter (
      advisorresources
      | where tolower(type) == 'microsoft.advisor/configurations'
      | where isempty(resourceGroup) == true
      | project subscriptionId, excludeRecomm = properties.exclude, lowCpuThreshold = properties.lowCpuThreshold
  ) on subscriptionId
  | extend isActive = iff(isempty(excludeRecomm), true, tobool(excludeRecomm) == false)
  | extend isNotExcludedViaCpuThreshold = iff((isnotempty(lowCpuThreshold) and isnotnull(properties.extendedProperties) and isnotempty(properties.extendedProperties.MaxCpuP95)),
      todouble(properties.extendedProperties.MaxCpuP95) < todouble(lowCpuThreshold),
      iff((isnull(properties.extendedProperties) or isempty(properties.extendedProperties.MaxCpuP95) or todouble(properties.extendedProperties.MaxCpuP95) < 100),
          true,
          false))
  | where isActive == true and isNotExcludedViaCpuThreshold == true
  | join kind = leftouter (
      advisorresources
      | where type =~ 'microsoft.advisor/configurations'
      | where isnotempty(resourceGroup) == true
      | project subscriptionId, resourceGroup, excludeProperty = properties.exclude
  ) on subscriptionId, resourceGroup
  | extend shouldBeIncluded = iff(isempty(excludeProperty), true, tobool(excludeProperty) == false)
  | where shouldBeIncluded == true
  | summarize expirationTimeStamp = max(expirationTimeStamp), suppressionIds = make_list(suppressionId) by recommendationId, stableId, subscriptionId, resourceGroup, tostring(properties)
  | extend isRecommendationActive = (isnull(expirationTimeStamp) or isempty(expirationTimeStamp))
  | extend properties = parse_json(properties)
  | extend monthlyCostSavings = toreal(properties.extendedProperties.savingsAmount)
  | extend monthlyCarbonSavingsKg = toreal(properties.extendedProperties.PotentialMonthlyCarbonSavings)
  | where monthlyCarbonSavingsKg > 0
  | extend resourceId = properties.resourceMetadata.resourceId, resourceName = tostring(properties.extendedProperties.roleName), recommendationMessage = properties.extendedProperties.recommendationMessage, recommendationType=tostring(properties.extendedProperties.recommendationType)
  | project recommendationId, subscriptionId, resourceGroup, suppressionIds, isRecommendationActive, monthlyCostSavings, monthlyCarbonSavingsKg, resourceId, resourceName, recommendationMessage, recommendationType| where isRecommendationActive == true| order by monthlyCarbonSavingsKg desc

Étapes suivantes

  • Last updated on