Visuels spécifiques au tableau de bord

Toutes les visualisations créées dans le contexte de l’opérateur de rendu sont disponibles dans les visualisations de tableau de bord. Toutefois, les visualisations suivantes sont uniquement disponibles dans les tableaux de bord Azure Data Explorer, les tableaux de bord en temps réel ou l’interface utilisateur web d’Azure Data Explorer, et non avec l’opérateur de rendu.

Pour savoir comment personnaliser tous les objets visuels de tableau de bord, consultez Personnaliser les objets visuels de tableau de bord d’explorateur de données Azure

Pour obtenir des informations générales sur les tableaux de bord dans Azure Data Explorer, consultez Visualiser des données avec des tableaux de bord Azure Data Explorer.

Graphique de synthèse

Un graphique en entonnoir visualise un processus linéaire qui comporte des étapes séquentielles et connectées. Chaque étape de l’entonnoir représente un pourcentage du total. C’est pourquoi un graphique en entonnoir a généralement la forme d’un entonnoir, où la première étape est la plus large et chaque étape suivante est plus étroite que l’étape précédente.

L’exemple suivant visualise la progression des demandes de serveur, affichant le nombre total de sessions, de demandes et leur état d’achèvement. Il met en évidence la diminution entre les sessions et les demandes ainsi que la proportion de demandes terminées par rapport aux demandes incomplètes.

Exemple de requête

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Carte thermique

Un carte thermique affiche les valeurs d’une variable principale d’intérêt sur deux variables d’axe sous la forme d’une grille de carrés colorés.

Pour afficher une carte thermique, la requête doit générer une table avec trois colonnes. Les données utilisées pour le champ valeur doivent être numériques. Les colonnes qui seront utilisées pour les valeurs x et y utilisent les règles suivantes :

• Si les valeurs de la colonne x sont au string format, les valeurs de la colonne y doivent également être au string format.
• Si les valeurs de la colonne x sont au datetime format, les valeurs de la colonne y doivent être numériques.

L’exemple suivant montre la distribution des cinq métriques SQL les plus fréquentes entre différents types de métriques. Il met en évidence les types de métriques les plus courants pour chaque métrique SQL, ce qui facilite l’identification des modèles d’activité dans les métriques principales.

Exemple de requête

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count