Déployer un espace de travail à l’aide de Terraform

L’exemple de configuration suivant utilise le azurerm fournisseur Terraform pour déployer un espace de travail Azure Databricks. Il part du principe que vous êtes connecté à Azure (az login) sur votre ordinateur local avec un utilisateur Azure disposant Contributor des droits de votre abonnement.

Pour plus d’informations sur le azurerm plug-in Terraform pour Databricks, consultez azurerm_databricks_workspace.

Simplicité de la configuration

terraform {
  required_providers {
    azurerm =  "~> 2.33"
    random = "~> 2.2"
  }
}

provider "azurerm" {
  features {}
}

variable "region" {
  type = string
  default = "westeurope"
}

resource "random_string" "naming" {
  special = false
  upper   = false
  length  = 6
}

data "azurerm_client_config" "current" {
}

data "external" "me" {
  program = ["az", "account", "show", "--query", "user"]
}

locals {
  prefix = "databricksdemo${random_string.naming.result}"
  tags = {
    Environment = "Demo"
    Owner       = lookup(data.external.me.result, "name")
  }
}

resource "azurerm_resource_group" "this" {
  name     = "${local.prefix}-rg"
  location = var.region
  tags     = local.tags
}

resource "azurerm_databricks_workspace" "this" {
  name                        = "${local.prefix}-workspace"
  resource_group_name         = azurerm_resource_group.this.name
  location                    = azurerm_resource_group.this.location
  sku                         = "premium"
  managed_resource_group_name = "${local.prefix}-workspace-rg"
  tags                        = local.tags
}

output "databricks_host" {
  value = "https://${azurerm_databricks_workspace.this.workspace_url}/"
}

Configuration du fournisseur

Dans Gérer les espaces de travail Databricks à l’aide de Terraform, utilisez les configurations spéciales pour Azure :

provider "databricks" {
  host = azurerm_databricks_workspace.this.workspace_url
}