Partager via

Démarrage rapide : Déployer un cluster Azure DocumentDB à l’aide de Bicep

Dans ce guide de démarrage rapide, vous déployez un nouveau cluster Azure DocumentDB à l’aide de Bicep. Ce guide de démarrage rapide fournit des instructions pas à pas pour vous aider à commencer rapidement. Ce cluster contient toutes vos ressources MongoDB : bases de données, collections et documents. Il fournit un point de terminaison unique pour les outils et les kits de développement logiciel (SDK) pour se connecter à Azure DocumentDB et effectuer des opérations.

Prerequisites

  • Un abonnement Azure

Configurer l’environnement

Configurez votre environnement Azure CLI pour gérer les ressources Azure DocumentDB dans votre abonnement.

  1. Démarrez dans un répertoire vide.

  2. Connectez-vous à Azure CLI.

    az login

  3. Vérifiez votre abonnement Azure cible.

    az account show

    Note

    Si vous n’êtes pas connecté à l’abonnement attendu, utilisez cette commande pour modifier votre abonnement :

    az account set --subscription "<subscription-name>"

    Pour plus d’informations, consultez gérer les abonnements Azure avec Azure CLI.

Préparer le modèle Bicep

Créez et configurez un fichier Bicep pour définir les ressources nécessaires au déploiement d’un cluster Azure DocumentDB.

  1. Créez un fichier main.bicep dans votre répertoire de projet.

  2. Ajoutez ce modèle au contenu du fichier.

    @description('Cluster name')
@minLength(8)
@maxLength(40)
param clusterName string = 'msdocs-${uniqueString(resourceGroup().id)}'

@description('Location for the cluster.')
param location string = resourceGroup().location

@description('Username for admin user')
param adminUsername string

@secure()
@description('Password for admin user')
@minLength(8)
@maxLength(128)
param adminPassword string

resource cluster 'Microsoft.DocumentDB/mongoClusters@2025-09-01' = {
  name: clusterName
  location: location
  properties: {
    administrator: {
      userName: adminUsername
      password: adminPassword
    }
    serverVersion: '8.0'
    sharding: {
      shardCount: 1
    }
    storage: {
      sizeGb: 32
    }
    highAvailability: {
      targetMode: 'Disabled'
    }
    compute: {
      tier: 'M10'
    }
  }
}

resource firewallRules 'Microsoft.DocumentDB/mongoClusters/firewallRules@2025-09-01' = {
  parent: cluster
  name: 'AllowAllAzureServices'
  properties: {
    startIpAddress: '0.0.0.0'
    endIpAddress: '0.0.0.0'
  }
}

    Conseil / Astuce

    Pour plus d’informations sur les options à l’aide de la Microsoft.DocumentDB/mongoclusters ressource, consultez Microsoft.DocumentDB/mongoclusters la documentation.

Déployer le modèle

Déployez le modèle créé à l’étape précédente à l’aide d’un déploiement Azure Resource Manager.

  1. Utilisez la az group create commande pour créer un groupe de ressources dans votre abonnement.

    az group create \
    --name "<resource-group-name>" \
    --location "<location>"

  2. Utilisez az deployment group create pour déployer le modèle Bicep. Vous êtes ensuite invité à entrer une valeur pour les paramètres adminUsername et adminPassword.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep'

    Conseil / Astuce

    Vous pouvez également utiliser l’option --parameters permettant de transmettre un fichier de paramètres avec des valeurs prédéfinies.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep' \
    --parameters @main.parameters.json

    Cet exemple de fichier JSON injecte les valeurs clusteradmin et P@ssw.rd pour les paramètres adminUsername et adminPassword respectivement.

    {
  "$schema": "https://schema.management.azure.com/schemas/2015-01-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "adminUsername": {
      "value": "clusteradmin"
    },
    "adminPassword": {
      "value": "P@ssw.rd"
    }
  }
}

  3. Attendez que l’opération de déploiement se termine avant de passer à l’opération.

Passer en revue les ressources déployées

Répertoriez les ressources Azure DocumentDB déployées sur votre groupe de ressources.

  1. Permet az resource list d’obtenir la liste des ressources de votre groupe de ressources.

    az resource list \
    --resource-group "<resource-group-name>" \
    --namespace "Microsoft.DocumentDB" \
    --resource-type "mongoClusters" \
    --query "[].name" \
    --output json

  2. Dans l’exemple de sortie, recherchez les ressources qui ont un type de Microsoft.DocumentDB/mongoClusters. Voici un exemple de type de sortie à attendre :

    [
  "msdocs-documentdb-example-cluster"
]

Nettoyer les ressources

Lorsque vous avez terminé avec votre cluster Azure DocumentDB, vous pouvez supprimer les ressources Azure que vous avez créées afin de ne pas entraîner de frais supplémentaires.

  1. Permet az group delete de supprimer le groupe de ressources de votre abonnement.

    az group delete \
    --name "<resource-group-name>" \
    --yes \
    --no-wait

    Important

    Vérifiez que vous n’avez plus besoin des ressources avant d’exécuter cette commande, car elle les supprime définitivement.

Contenu connexe

  • Last updated on