Fonctions d’exécution de conversion X++

Cet article décrit les fonctions d’exécution de conversion.

any2Date

Convertit une valeur anytype en valeur de date .

date any2Date(anytype object)

Paramètres

Valeur retournée

Valeur de date .

Remarques

Le paramètre d’objet peut être de la plupart des types de données, mais une sortie utile est obtenue lorsqu’il s’agit du type str ou int . Le contenu inapproprié génère une erreur d’exécution.

Example

static void any2DateExample(Args _args)
{
    date myDate;
    str s;
    int i;
    s = "2010 6 17"; // A string object, of yyyy mm dd.
    myDate = any2Date(s);
    Global::info(strFmt("%1  is output, from input of "2010 6 17"", myDate));
    i = 40361; // An int object, which represents the number of days from 1900/01/01.
    myDate = any2Date(i);
    Global::info(strFmt("%1  is output, from input of 40361", myDate));
}
/**** Infolog display.
Message (04:44:15 pm)
6/17/2010 is output, from input of "2010 6 17"
7/4/2010 is output, from input of 40361
****/

any2Enum

Convertit une valeur anytype en valeur de propriété Name d’un élément dans l’énumération cible.

enum any2Enum(anytype object)

Paramètres

Valeur retournée

La valeur de la propriété Name pour l’élément de l’énumération cible a une propriété Value qui correspond au paramètre d’entrée.

Remarques

Le paramètre objet peut être de la plupart des types de données, mais des données utiles sont obtenues uniquement lorsque vous utilisez un paramètre du type str ou int . Ce paramètre d’objet d’entrée fait référence à la propriété Value d’un élément individuel dans l’énumération cible.

Example

static void any2EnumExample(Args _args)
{
    NoYes myNoYes;  // NoYes is an enum.
    int i;
    str s;
    i = 0;  // An int that will be converted.
    myNoYes = any2Enum(i);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as int.", myNoYes, i));
    s = "1";  // A str that will be converted.
    myNoYes = any2Enum(s);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as str.", myNoYes, s));
    /**** Infolog display.
    Message (01:05:32 pm)
    'No' - is the output, from input of the 0 as int.
    'Yes' - is the output, from input of the 1 as str.
    ****/
}

any2Guid

Convertit l’objet anytype spécifié en objet GUID.

guid any2Guid(anytype object)

Paramètres

Valeur retournée

Objet GUID.

any2Int

Convertit une valeur anytypeen valeur int .

int any2Int(anytype object)

Paramètres

Valeur retournée

Valeur int .

Remarques

Le paramètre d’objet peut être de la plupart des types de données, mais des données utiles sont obtenues uniquement lorsque vous utilisez des paramètres de l’énumération, du type réel ou str .

Example

static void any2IntExample(Args _args)
{
    int myInt;
    str s;
    NoYes a;
    real r;
    s = "31";
    myInt = any2Int(s);
    Global::info(strfmt("%1 is the output, from input of 31 as a str value.", myInt));
    a = NoYes::No;
    myInt = any2Int(a);
    Global::info(strfmt("%1 is the output, from input of NoYes::No as an enum value.", myInt));
    r = 5.34e2;
    myInt = any2Int(r);
    Global::info(strfmt("%1 is the output, from the input of 5.34e2 as a real value.", myInt));
}
/**** Infolog display.
Message (02:23:59 pm)
31 is the output, from input of 31 as a str value.
0 is the output, from input of NoYes::No as an enum value.
534 is the output, from the input of 5.34e2 as a real value.
****/

any2Int64

Convertit un objet anytypeen objet int64 .

int64 any2Int64(anytype object)

Paramètres

Valeur retournée

Objet int64 .

any2Real

Convertit une valeur anytype en valeur réelle .

real any2Real(anytype object)

Paramètres

Valeur retournée

Valeur réelle .

Remarques

Le paramètre objet peut être de la plupart des types de données, mais une sortie utile est obtenue pour les éléments d’entrée de la date, int, enum et str types.

Example

static void any2RealExample(Args _args)
{
    real myReal;
    str s;
    int i;
    NoYes a;
    s = "5.12";
    myReal = any2Real(s);
    Global::info(strfmt("%1 is the output from the input of 5.12 as a str object", myReal));
    i = 64;
    myReal = any2Real(i);
    Global::info(strfmt("%1 is the output from the input of 64 as an int object", myReal));
    a = NoYes::Yes;
    myReal = any2Real(a);
    Global::info(strfmt("%1 is the output from the input of NoYes::Yes as an enum object", myReal));
}
/****Infolog display.
Message (02:43:57 pm)
5.12 is the output from the input of 5.12 as a str object
64.00 is the output from the input of 64 as an int object
1.00 is the output from the input of NoYes::Yes as an enum object
****/

any2Str

Convertit une valeur anytype en valeur str .

str any2Str(anytype object)

Paramètres

Valeur retournée

Valeur str .

Remarques

Le paramètre objet peut être de la plupart des types de données, mais une sortie utile est obtenue à partir d’éléments d’entrée des types date, int et énumération .

Example

static void any2StrExample(Args _args)
{
    str myStr;
    anytype a;
    a = "Any to string";
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of Any to string as a str value", myStr));
    a = NoYes::Yes;
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of NoYes::Yes as an enumeration", myStr));
}
/****Infolog Display
Message (09:08:46 am)
Any to string is output, from input of Any to string as a str value
1 is output, from input of NoYes::Yes as an enumeration
****/

anytodate

Voir any2Date.

anytoenum

Voir any2Enum.

anytoguid

Voir any2Guid.

anytoint

Voir any2Int.

anytoint64

Voir any2Int64.

anytoreal

Voir any2Real.

anytostr

Voir any2Str.

char2Num

Convertit un caractère dans une chaîne en valeur ASCII du caractère.

int char2Num(str text, int position)

Paramètres

Valeur retournée

Valeur ASCII du caractère en tant qu’objet int .

Remarques

char2Num("ABCDEFG",3); //Returns the numeric value of C, which is 67.
char2Num("ABCDEFG",1); //Returns the numeric value of A, which is 65.

date2Num

Convertit une date en entier qui correspond au nombre de jours depuis le 1er janvier 1900.

int date2Num(date _date)

Paramètres

Valeur retournée

Nombre de jours entre le 1er janvier 1900 et la date spécifiée.

Example

//Returns the value377.
date2Num(1311901);
static void date2NumExample(Args _arg)
{
    date d = today();
    int i;
    i = date2Num(d);
    print i;
}

date2Str

Convertit la date spécifiée en chaîne.

str date2Str(date date, int sequence, int day, int separator1, int month, int separator2, int year [, int flags = DateFlags::None])

Paramètres

Valeur retournée

Chaîne qui représente la date spécifiée.

Remarques

MorphX alloue des valeurs valides aux paramètres de mise en forme si les valeurs spécifiées ne sont pas valides. Pour utiliser le format de date que l’utilisateur a spécifié dans les paramètres régionaux, utilisez la fonction strFmt ou date2Str et spécifiez -1 dans tous les paramètres de mise en forme. Lorsque les paramètres régionaux contrôlent le format de date, les paramètres peuvent passer de l’utilisateur à l’utilisateur. Si -1 est utilisé pour l’un ou l’autre paramètre de séparateur , les deux séparateurs sont définis par défaut sur Paramètres régionaux. Les valeurs des paramètres de séquence doivent être un nombre à trois chiffres qui contient exactement une occurrence de chacun des chiffres 1, 2 et 3. Les chiffres 1, 2 et 3 représentent respectivement jour, mois et année. Par exemple, 321 produit l’année de séquence, le mois et le jour. Ou la valeur peut être -1 pour utiliser les paramètres régionaux. Aucun type d’énumération ne doit être utilisé pour ce paramètre, car les nombres tels que 321 dépassent la plage de valeurs valides pour les valeurs d’énumération, comprises entre 0 et 250. La valeur par défaut du paramètre d’indicateurs est la valeur d’énumération DateFlags ::None , ce qui signifie qu’aucun traitement de séquence de gauche à droite ou de droite à gauche n’est effectué.

Example

L’exemple suivant affiche la date actuelle dans la séquence de l’année, du mois et du jour.

static void Job2(Args _args)
{
    date currentDate = today();
    str s;
    int iEnum;
    s = date2Str
    (currentDate, 
        321,
        DateDay::Digits2,
        DateSeparator::Hyphen, // separator1
        DateMonth::Digits2,
        DateSeparator::Hyphen, // separator2
        DateYear::Digits4
    );
    info("Today is:  " + s);
}
/** Example Infolog output
Message (12:36:21 pm)
Today is:  2009-01-13
**/

datetime2Str

Convertit une valeur utcdatetime en chaîne.

str datetime2Str(utcdatetime datetime [, int flags = DateFlags::None])

Paramètres

Valeur retournée

Chaîne qui représente la valeur utcdatetime spécifiée en tant que paramètre datetime .

Remarques

Entrée de date/heure Null

Si la valeur utcdatetime minimale est spécifiée pour le paramètre datetime , la fonction datetime2Str la traite comme une valeur d’entrée Null. Cela provoque le retour d’une chaîne vide par la fonction. La date-heure 1900-01-01T00:00:00 est retournée par la méthode DateTimeUtil ::minValue . Cette valeur minimale est traitée comme null.

Paramètres locaux de droite à gauche

Le comportement par défaut de cette fonction consiste à générer la chaîne dans la séquence de gauche à droite, où la partie année est la plus à gauche. Toutefois, la valeur du paramètre d’indicateur de la valeur d’énumération DateFlags ::FormatAll dirige la fonction pour générer la chaîne dans la séquence de droite à gauche si les paramètres locaux sont configurés pour la droite à gauche. Le format de la méthode toStr de la classe DateTimeUtil n’est pas affecté par les paramètres régionaux.

Example

static void jobTestDatetime2str( Args _args )
{
    utcdatetime utc2 = 1959-06-17T15:44:33;
    str s3;
    s3 = datetime2Str( utc2 );
    info( s3 );
}

enum2Str

Convertit le texte énuméré spécifié en représentation de caractères.

str enum2Str(enum enum)

Paramètres

Valeur retournée

Valeur de l’énumération sous forme de chaîne.

Example

L’exemple suivant retourne la chaîne « Non inclus ». Il s’agit de l’étiquette de la valeur IncludeNot du type d’énumération ListCode .

static void enum2StrExample(Args _arg)
{
    ListCode l;
    l =  ListCode::IncludeNot;
    print enum2Str(l);
}

guid2Str

Convertit l’objet GUID spécifié en chaîne équivalente.

str guid2String(guid _uuid)

Paramètres

Valeur retournée

Équivalent de chaîne de l’objet GUID spécifié.

Example

static void guid2StrExample()
{
    guid _guid;
    str stringGuid;
    _guid = Global::guidFromString("{12345678-1234-1234-1234-123456789abc}");
    print strfmt("GUID is %1", _guid);
    stringGuid = guid2str(_guid);
    info("String GUID is " + stringGuid);
}
/**** Output to Infolog
String GUID is {12345678-1234-1234-1234-123456789ABC}
****/

int2Str

Convertit un entier en chaîne équivalente.

str int2Str(int integer)

Paramètres

Valeur retournée

Représentation sous forme de chaîne de l’entier.

Example

static void int2StrExample(Args _arg)
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

int642Str

Convertit le paramètre entier spécifié en chaîne de texte équivalente.

str int642Str(int64 integer)

Paramètres

Valeur retournée

Chaîne de texte équivalente du paramètre entier .

Example

static void example()
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

num2Char

Convertit un entier en caractère ASCII correspondant.

str num2Char(int figure)

Paramètres

Valeur retournée

Caractère représenté par l’entier spécifié.

Example

static void num2CharExample(Args _arg)
{
    str s;
    s = num2Char(42);
    // Prints an asterisk * -the character represented by 42.
    print s;
}

num2Date

Récupère la date qui correspond au nombre spécifié de jours après le 1er janvier 1900.

date num2Date(int _days)

Paramètres

Valeur retournée

Date du nombre de jours spécifié par le paramètre _days après le 1er janvier 1900.

Remarques

num2Date(366); //Returns the date 01/01/1901 (1 January 1901).

num2Str

Convertit un nombre réel en chaîne.

str num2Str(real number, int character, int decimals, int separator1, int separator2)

Paramètres

Valeur retournée

Chaîne qui représente le nombre.

Remarques

Pour le paramètre décimal , la valeur maximale est 16. Si un nombre plus grand est utilisé, cette méthode obtient plutôt une valeur pour le paramètre décimal de l’ordinateur local. Dans les deux cas, l’arrondi se produit. Voici les valeurs d’énumération possibles pour le paramètre séparateur1 :

• 99 – Automatique (les paramètres de mise en forme de l’utilisateur déterminent quel séparateur décimal est utilisé), valeur d’énumération DecimalSeparator ::Auto
• 1 – Point (.), valeur d’énumération DecimalSeparator ::D ot
• 2 – Virgule (,), valeur d’énumération DecimalSeparator ::Comma

Voici les valeurs possibles pour le paramètre séparateur2 :

• 99 – Automatique (les paramètres de mise en forme de l’utilisateur déterminent quel séparateur de milliers est utilisé)
• 0 – Aucun (aucun séparateur de milliers), valeur d’énumération ThousandSeparator ::None
• 1 – Point (.), valeur d’énumération ThousandSeparator ::D ot
• 2 – Virgule (,), valeur d’énumération ThousandSeparator ::Comma
• 3 – Apostrophe ('), valeur d’énumération ThousandSeparator ::Apostrophe
• 4 – Espace ( ), valeur d’énumération ThousandSeparator ::Space

Example

Dans l’exemple de code suivant, le premier appel à la méthode num2str fournit 16 pour le paramètre décimal , et le deuxième appel fournit 17.

static void Job_Num2Str(Args _args)
{
    real realNum = 0.1294567890123456777; // 19 decimals places.
    info(Num2Str(realNum, 0, 16, DecimalSeparator::Dot, ThousandSeparator::Space)); // 16 decimal places
    info(Num2Str(realNum, 0, 17, DecimalSeparator::Dot, ThousandSeparator::Space)); // 17 decimal places
}

Output

Les messages se trouvent dans la sortie infolog suivante. Le premier nombre de la sortie contient 16 chiffres de décimales, tandis que le deuxième nombre ne contient que deux chiffres décimaux.

Message (10:18:12)
0.1294567890123457
0.13

str2Date

Convertit la chaîne spécifiée en valeur de date .

date str2Date(str _text, str _sequence)

Paramètres

Valeur retournée

Valeur de date .

Remarques

Utilisez les valeurs suivantes pour spécifier les positions du jour, du mois et de l’année dans le paramètre _sequence :

• Jour : 1
• Mois : 2
• Année : 3

Par exemple, si la séquence de la chaîne est mois, année, puis jour, le paramètre _sequence doit être 231. Une date 0 (zéro) est retournée si les paramètres d’entrée spécifient une date non valide. Les deux exemples suivants spécifient une date non valide.

str2Date("31/12/44", 123) // Year must be four digits to reach the minimum of January 1 1901.
str2Date("31/12/2044", 213) // 213 means the month occurs first in the string, but 31 cannot be a month.

Example

static void str2DateExample(Args _arg)
{
    date d;
    d = str2Date("22/11/2007", 123);
    print d;
}

str2Datetime

Génère une valeur utcdatetime à partir de la chaîne spécifiée d’informations de date et d’heure.

utcdatetime str2datetime( str text, int sequence )

Paramètres

Valeur retournée

Valeur utcdatetime qui représente la date et l’heure spécifiées.

Remarques

Les exigences de syntaxe pour la partie date du paramètre de texte sont flexibles. La variété de formats valides est la même que dans la fonction date2str . Chacun des appels suivants à str2datetime est valide et tous produisent la même sortie.

utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
utc3 = str2datetime( "Feb-1985-25 11:04:59 pm" ,231 );
utc3 = str2datetime( "2 25 1985 11:04:59 pm" ,123 );

Chaque composant de l’heure de date est représenté par un chiffre dans le paramètre de séquence :

• 1 – Jour
• 2 – Mois
• 3 – Année

Par exemple, année, mois, commande de jour est 321. Toutes les valeurs valides contiennent chacune de ces trois chiffres exactement une fois. Si la valeur du paramètre de séquence n’est pas valide, les paramètres régionaux sont utilisés pour interpréter le paramètre de texte d’entrée. Si les paramètres d’entrée décrivent une date et une heure non valides, une chaîne vide est retournée.

Example

static void JobTestStr2datetime( Args _args )
{
    utcdatetime utc3;
    str sTemp;
    utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
    sTemp = datetime2str( utc3 );
    print( "sTemp == " + sTemp );
}

str2Enum

Récupère l’élément d’énumération pour lequel la valeur de propriété Label localisée correspond à la chaîne d’entrée.

enum str2Enum(enum _type, str _text)

Paramètres

Valeur retournée

Élément de l’énumération cible, qui représente également un int.

Remarques

L’énumération de fonction associée retourne la valeur d’une propriété Label à partir d’un élément de l’énumération. La valeur retournée par la fonction enum2str peut être l’entrée du paramètre _type de la fonction str2enum . Une valeur appropriée pour le paramètre _text est enum2Str(BankAccountType ::SavingsAccount). Chaque élément d’une énumération a une propriété Name et une propriété Label . Dans une nouvelle installation, les valeurs Name sont presque toujours des mots anglais. Dans l’édition anglaise, la valeur de la propriété Label est presque toujours identique à la valeur Name . Toutefois, dans les éditions non anglaises, les valeurs d’étiquette sont localisées et ne correspondent donc pas aux valeurs Name .

Example

Pour éviter les incompatibilités de chaîne provoquées par la localisation vers d’autres langues parlées, nous vous recommandons d’utiliser la fonction enum2str pour générer l’entrée dans la fonction str2enum . L’exemple suivant montre la façon appropriée d’utiliser la fonction str2enum avec la fonction enum2str .

static void str2Enum_AcrossLangs(Args _arg)
{
    BankAccountType bat;
    str sEnumValueLabelLocalized;
    int nInt;
    // enum2str.
    sEnumValueLabelLocalized = enum2str(BankAccountType::SavingsAccount);
    info("Localized friendly string: "
        + sEnumValueLabelLocalized);
    // str2enum.
    bat = str2Enum(bat, sEnumValueLabelLocalized);
    nInt = bat;
    info("nInt = " + int2str(nInt));
    /********** Actual output:
    Message (04:32:12 pm)
    Localized friendly string: Savings account
    nInt = 1
    **********/
}

str2Guid

Convertit une chaîne en objet GUID.

Guid str2Guid(str text)

Paramètres

Valeur retournée

GUID représenté par la chaîne d’entrée.

Remarques

Par exemple, une valeur valide pour le paramètre guid est {12345678-1234-abCD-3456-123456789012}, avec ou sans accolades.

str2Int

Convertit une chaîne en entier équivalent.

int str2Int(str _text)

Paramètres

Valeur retournée

Entier équivalent de la chaîne spécifiée.

Example

static void str2IntExample(Args _arg)
{
    int i;
    i = str2Int("1234567890");
    print "i = " + int2Str(i);
}

str2Int64

Convertit une chaîne en valeur Int64 .

int str2Int64(str text)

Paramètres

Valeur retournée

Valeur Int64 de la chaîne spécifiée.

Example

static void str2Int64Example(Args _args)
{
    str myStr;
    str tooBig;
    Int64 myInt64;
    myStr = "1234567890";
    tooBig = int642str(int64Max()+1);
    myInt64 = str2Int64(mystr);
    print strfmt ("int64: %1",myInt64);
    myInt64 = str2Int64(tooBig);
    print strfmt ("Too big int64: %1",myInt64);
}

str2Num

Convertit une chaîne en nombre réel.

real str2Num(str _text)

Paramètres

Valeur retournée

Nombre réel si la chaîne spécifiée contient un nombre valide ; sinon, 0 (zéro).

Remarques

Les exemples suivants montrent comment cette fonction est utilisée.

str2Num("123.45") returns the value 123.45.
str2Num("a123") returns the value 0.0.
str2Num("123a") returns the value 123.00.

L’analyse se produit de gauche à droite et se termine lorsqu’un caractère ne peut pas être converti en partie d’un nombre réel.

Example

static void str2NumToReal(Args _arg)
{
    real r;
    str s;
    r = str2Num("3.15");
    s = strFmt("r = %1", r);
    info(s);
}
/*** Infolog output.
Message_@SYS14327 (02:36:12 pm)
r = 3.15
***/

static void str2NumExponentialSyntax(Args _args)
{
    Qty qty1, qty2, qty3;
    qty1 = str2num('1e-3'); // Bad syntax by the user.
    qty2 = str2num('1.e-3');
    qty3 = str2num('1.0e-3');
    info(strfmt('Result: %1; Expected: %2', num2str(qty1, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty2, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty3, 0,3,2,0), '0.001'));
}
/*** Infolog output. The first result differs from expectations.
Message_@SYS14327 (02:20:55 pm)
Result: 1,000; Expected: 0.001
Result: 0,001; Expected: 0.001
Result: 0,001; Expected: 0.001
***/

str2Time

Convertit une chaîne en valeur timeOfDay .

int str2Time(str _text)

Paramètres

Valeur retournée

Nombre de secondes entre minuit et le paramètre _text  ; sinon, -1.

Remarques

str2Time("05:01:37") //Returns the value 18097.
str2Time("7 o'clock") //Returns the value -1.

Example

static void str2TimeExample(Args _arg)
{
    int i;
    i = str2Time("11:30");
    print i;
}

time2Str

Convertit une valeur timeOfDay en chaîne qui inclut des heures, des minutes et des secondes.

str time2Str(int _time, int _separator, int _timeFormat)

Paramètres

Valeur retournée

Chaîne qui représente l’heure spécifiée.

Remarques

La valeur du paramètre _time est le nombre de secondes depuis minuit.

Example

static void TimeJob4(Args _args)
{
    timeOfDay theTime = timeNow();
    info( time2Str(theTime, TimeSeparator::Colon, TimeFormat::AMPM) );
}
/**
Message (04:33:56 pm)
04:33:56 pm
**/

uint2Str

Convertit un entier en chaîne. L’hypothèse est que l’entier n’est pas signé.

str uint2Str(int integer)

Paramètres

Valeur retournée

Chaîne équivalente à l’entier non signé spécifié.

Remarques

Utilisez cette fonction au lieu de la fonction int2str pour des entiers très volumineux, tels que des ID d’enregistrement.

info(int2str(3123456789)); //returns -1171510507 as a string.
info(uint2str(3123456789)); //returns 3123456789 as a string.