Visualisations géospatiales

S’applique à : ✅Microsoft Fabric

Les données géospatiales peuvent être visualisées dans le cadre de votre requête à l’aide de l’opérateur de rendu en tant que points, secteurs ou bulles sur une carte.

Pour plus d’informations sur le clustering géospatial, consultez Clustering géospatial.

Exemples

L’exemple suivant recherche les événements storm et visualise 100 sur une carte.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

L’exemple suivant visualise plusieurs séries de points, où la paire [Longitude, Latitude] définit chaque point, et une troisième colonne définit la série. Dans cet exemple, la série est EventType.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

L’exemple suivant visualise une série de points sur une carte. Si vous avez plusieurs colonnes dans le résultat, vous devez spécifier les colonnes à utiliser pour xcolumn (Longitude), ycolumn (Latitude) et les séries.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

L’exemple suivant visualise les points sur la carte à l’aide de valeurs dynamiques GeoJSON pour définir les points.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

L’exemple suivant montre les événements storm agrégés par les cellules S2. Le graphique agrège les événements dans les bulles par emplacement dans une couleur.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

L’exemple suivant montre les événements storm agrégés par les cellules S2. Le graphique agrège les événements par type d’événement dans les graphiques en secteurs par emplacement.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Contenu connexe

• Clustering géospatial
• Opérateur de rendu
• Analyse des données pour les flottes de tests automobiles (cas d’usage de clustering géospatial )
• En savoir plus sur l’architecture Azure pour le traitement et l’analytique des données géospatiales