bag_pack()

S’applique à : ✅Microsoft Fabric✅

Crée un objet de conteneur de propriétés dynamique à partir d’une liste de clés et de valeurs.

Alias déconseillés : pack(), pack_dictionary()

Syntaxe

bag_pack( key1 value1,,key2 value2,,... )

En savoir plus sur les conventions de syntaxe.

Paramètres

Retours

Retourne un dynamic objet de conteneur de propriétés à partir des entrées clé et valeur répertoriées.

Exemples

Exemple 1 :

L’exemple suivant crée et retourne un conteneur de propriétés à partir d’une liste alternée de clés et de valeurs.

print bag_pack("Level", "Information", "ProcessID", 1234, "Data", bag_pack("url", "www.bing.com"))

Résultats

Exemple 2

L’exemple suivant crée un conteneur de propriétés et extrait la valeur du conteneur de propriétés à l’aide de l’opérateur « . ».

datatable (
    Source: int,
    Destination: int,
    Message: string
) [
    1234, 100, "Hi", 
    4567, 200, "Hello",
    1212, 300, "Hey" 
]
| extend MyBag=bag_pack("Dest", Destination, "Text", Message)
| project-away Source, Destination, Message
| extend MyBag_Dest=MyBag.Dest, MyBag_Text=MyBag.Text

Résultats

Exemple 3

L’exemple suivant utilise deux tables, SmsMessages et MmsMessages, et retourne leurs colonnes communes et un conteneur de propriétés à partir des autres colonnes. Les tables sont créées ad hoc dans le cadre de la requête.

SmsMessages

MmsMessages

let SmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    CharsCount: string
) [
    "555-555-1234", "555-555-1212", "46", 
    "555-555-1234", "555-555-1213", "50",
    "555-555-1212", "555-555-1234", "32" 
];
let MmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    FileSize: string,
    FileName: string
) [
    "555-555-1212", "555-555-1213", "200", "Pic1",
    "555-555-1234", "555-555-1212", "250", "Pic2",
    "555-555-1234", "555-555-1213", "300", "Pic3"
];
SmsMessages 
| join kind=inner MmsMessages on SourceNumber
| extend Packed=bag_pack("CharsCount", CharsCount, "FileSize", FileSize, "FileName", FileName) 
| where SourceNumber == "555-555-1234"
| project SourceNumber, TargetNumber, Packed

Résultats

Contenu connexe

• pack-all, fonction
• plug-in bag-unpack