range operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Génère une table de valeurs à une seule colonne.

Syntax

range columnNamefromstarttostopstepstep

Learn more about syntax conventions.

Parameters

Returns

A table with a single column called columnName, whose values are start, start+step, ... up to and until stop.

Examples

L’exemple de cette section montre comment utiliser la syntaxe pour vous aider à commencer.

Plage au cours des sept derniers jours

L’exemple suivant crée une table avec des entrées pour l’horodatage actuel étendu au cours des sept derniers jours, une fois par jour.

range LastWeek from ago(7d) to now() step 1d

Output

Combiner des heures d’arrêt différentes

L’exemple suivant montre comment étendre les plages pour utiliser plusieurs arrêts à l’aide de l’opérateur union.

let Range1 = range Time from datetime(2024-01-01) to datetime(2024-01-05) step 1d;
let Range2 = range Time from datetime(2024-01-06) to datetime(2024-01-10) step 1d;
union Range1, Range2
| order by Time asc

Output

Plage à l’aide de paramètres

L’exemple suivant montre comment utiliser l’opérateur range avec des paramètres, qui sont ensuite étendus et consommés en tant que table.

let toUnixTime = (dt:datetime) 
{ 
    (dt - datetime(1970-01-01)) / 1s 
};
let MyMonthStart = startofmonth(now()); //Start of month
let StepBy = 4.534h; //Supported timespans
let nn = 64000; // Row Count parametrized
let MyTimeline = range MyMonthHour from MyMonthStart to now() step StepBy
| extend MyMonthHourinUnixTime = toUnixTime(MyMonthHour), DateOnly = bin(MyMonthHour,1d), TimeOnly = MyMonthHour - bin(MyMonthHour,1d)
; MyTimeline | order by MyMonthHour asc | take nn

Output

Incremented steps

L’exemple suivant crée une table avec une seule colonne appelée Steps dont le type est long et génère des valeurs comprises entre un et huit incrémentés par trois.

range Steps from 1 to 8 step 3

Output

Traces sur un intervalle de temps

L’exemple suivant montre comment l’opérateur range peut être utilisé pour créer une table de dimension utilisée pour introduire des zéros où les données sources n’ont aucune valeur. Il faut des horodatages des quatre dernières heures et compte les traces pour chaque intervalle d’une minute. Lorsqu’il n’y a aucune trace pour un intervalle spécifique, le nombre est égal à zéro.

range TIMESTAMP from ago(4h) to now() step 1m
| join kind=fullouter
  (Traces
      | where TIMESTAMP > ago(4h)
      | summarize Count=count() by bin(TIMESTAMP, 1m)
  ) on TIMESTAMP
| project Count=iff(isnull(Count), 0, Count), TIMESTAMP
| render timechart