Tutoriel : joindre des données à partir de plusieurs tables

S’applique à : ✅Microsoft Fabric

La jonction de données à partir de plusieurs tables vous permet d’analyser les données entre les sources et de créer des relations entre des points de données. Dans le langage de requête Kusto (KQL), utilisez les opérateurs de jointure et de recherche pour combiner des données entre des tables.

Dans ce tutoriel, vous allez apprendre à :

Prérequis

Exécutez les requêtes dans un environnement de requête qui a accès aux exemples de données. Utilisez l’une des options suivantes :

Utiliser l’opérateur de jointure

La base de données Samples comporte deux tables d’événements de tempête associées : StormEvents et PopulationData. Dans cette section, vous les joignez pour analyser les données qui ne sont pas possibles avec une seule table.

Comprendre les données

Utilisez l’opérateur take pour voir quelles données chaque table contient.

StormEvents 
| take 5

Le tableau suivant affiche seulement six des 22 colonnes retournées.

PopulationData 
| take 5

Sortie

Les deux tables ont une State colonne. StormEvents a de nombreuses colonnes supplémentaires et PopulationData a une autre colonne avec la population de l’état.

Joindre les tables

Associe PopulationData avec StormEvents sur State pour calculer le total des dommages matériels par habitant par état.

StormEvents
| summarize PropertyDamage = sum(DamageProperty) by State
| join kind=innerunique PopulationData on State
| project State, PropertyDamagePerCapita = PropertyDamage / Population
| sort by PropertyDamagePerCapita

Ajoutez | render columnchart à la requête pour visualiser le résultat.

Si les colonnes ont des noms différents (par exemple, StormEvents a State et PopulationData a StateName), spécifiez la jointure comme suit :

StormEvents
| join kind=innerunique PopulationData on $left.State == $right.StateName  

$left fait référence à la table gauche (externe) dans la jointure : StormEvents. $right fait référence à la table droite (interne) : PopulationData.

Utiliser l’opérateur de recherche

L’opérateur de recherche optimise les requêtes qui enrichissent une table de faits avec des données d’une table de dimension. Il étend la table de faits avec des valeurs de la table de dimensions. Par défaut, le système part du principe que la table de gauche est la table de faits supérieure et que la table de droite est la table de dimensions plus petite. Cette valeur par défaut est l’inverse de l’hypothèse de l’opérateur join .

Le cluster d’aide inclut une base de données nommée ContosoSales avec des données de vente. La requête suivante utilise lookup pour fusionner les tables SalesFact et Products afin de retourner le total des ventes par catégorie de produit.

SalesFact
| lookup Products on ProductKey
| summarize TotalSales = count() by ProductCategoryName
| order by TotalSales desc

Sortie

Joindre des tables générées par une requête

Joindre les résultats de la même table.

Supposons que vous vouliez une liste d’états qui ont à la fois des éclairs et des événements d’avalanche. Utilisez l’opérateur de jointure pour fusionner des lignes de deux requêtes qui retournent des états distincts pour chaque type d’événement sur la State colonne.

StormEvents
| where EventType == "Lightning"
| distinct State
| join kind=inner (
    StormEvents 
    | where EventType == "Avalanche"
    | distinct State
    )
    on State
| project State

Sortie

Contenu connexe

• Découvrez différents types d’opérateur de jointure.
• Effectuez des requêtes inter-bases de données et inter-clusters.
• Suivez le didacticiel Créer des visualisations géospatiales .