Recordset2.Restartable property (DAO)

S’applique à : Access 2013, Office 2013

Renvoie une valeur indiquant si un objet Recordset prend en charge la méthode Requery, laquelle réexécute la requête sur laquelle l'objet Recordset est basé.

Syntaxe

expression . Redémarrable

Expression Variable qui représente un objet Recordset2 .

Remarques

Les objets Recordset de type table renvoient toujours la valeur False.

Vérifiez la propriété Restartable avant d'utiliser la méthode Requery sur un objet Recordset. Si la propriété Restartable a la valeur False, appelez la méthode OpenRecordset sur l'objet QueryDef sous-jacent pour réexécuter la requête.

Exemple

Cet exemple illustre l'utilisation de la propriété Restartable avec différents objets Recordset.

    Sub RestartableX()
    
       Dim dbsNorthwind As Database
       Dim rstTemp As Recordset2
    
       Set dbsNorthwind = OpenDatabase("Northwind.mdb")
    
       With dbsNorthwind
          ' Open a table-type Recordset and print its 
          ' Restartable property.
          Set rstTemp = .OpenRecordset("Employees", dbOpenTable)
          Debug.Print _
             "Table-type recordset from Employees table"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          ' Open a Recordset from an SQL statement and print its 
          ' Restartable property.
          Set rstTemp = _
             .OpenRecordset("SELECT * FROM Employees")
          Debug.Print "Recordset based on SQL statement"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          ' Open a Recordset from a saved QueryDef object and 
          ' print its Restartable property.
          Set rstTemp = .OpenRecordset("Current Product List")
          Debug.Print _
             "Recordset based on permanent QueryDef (" & _
             rstTemp.Name & ")"
          Debug.Print "  Restartable = " & rstTemp.Restartable
          rstTemp.Close
    
          .Close
       End With
    
    End Sub