Partager via

TableDef.CreateField, méthode (DAO)

S’applique à : Access 2013 | Office 2013

Crée un objet Field (espaces de travail Microsoft Access uniquement).

Syntaxe

expression .CreateField(Name, Type, Size)

expression Variable représentant un objet TableDef.

Paramètres

Nom

Obligatoire/facultatif

Type de données

Description

Name

Facultatif

Variant

Chaîne qui identifie de manière unique le nouvel objet Field. Reportez-vous à la propriété Name pour plus d'informations sur les noms valides pour l'objet Field.

Type

Facultatif

Variant

Constante qui détermine le type de données du nouvel objet Field. Pour connaître les types de données valides, reportez-vous à la propriété Type.

Size

Facultatif

Variant

Nombre entier indiquant la taille maximale, en octets, d’un objet Field contenant du texte. Pour connaître les valeurs de taille valides, voir la propriété Size. Cet argument est ignoré pour les champs numériques et de longueur fixe.

Valeur renvoyée

Field

Remarques

Vous pouvez utiliser la méthode CreateField pour créer un champ, spécifier le nom, le type de données et la taille du champ. Si vous omettez une ou plusieurs des parties facultatives lorsque vous utilisez la méthode CreateField, vous pouvez utiliser une instruction d'affectation appropriée pour définir ou réinitialiser la propriété correspondante avant d'ajouter le nouvel objet à la collection. Une fois que vous avez ajouté le nouvel objet, vous pouvez modifier une partie de ses paramètres de propriété, mais pas tous. Pour plus d'informations, consultez les rubriques des différentes propriétés.

Les arguments Type et Size ne s’appliquent qu’aux objets Field dans un objet TableDef. Les arguments suivants sont ignorés quand un objet Field est associé un objet Index ou Relation.

Si l’argument Name renvoie à un objet qui est déjà membre de la collection, une erreur d’exécution se produit lorsque vous utilisez la méthode Append.

Pour supprimer un objet Field d'une collection Fields, utilisez la méthode Delete dans la collection. Vous ne pouvez pas supprimer un objet Field dans la collection Fields d'un objet TableDef une fois que vous avez créé un index qui renvoie à ce champ.

Lien fourni par la communauté UtterAccess. UtterAccess est le forum d’aide et wiki de Microsoft Access de référence.

Exemple

L'exemple suivant montre comment créer un champ calculé. La méthode CreateField crée un champ nommé FullName. La propriété Expression est ensuite définie sur l'expression qui calcule la valeur du champ.

Exemple de code fourni parMicrosoft Access 2010 Programmer’s Reference.

    Sub CreateCalculatedField()
        Dim dbs As DAO.Database
        Dim tdf As DAO.TableDef
        Dim fld As DAO.Field2
        
        ' get the database
        Set dbs = CurrentDb()
        
        ' create the table
        Set tdf = dbs.CreateTableDef("tblContactsCalcField")
        
        ' create the fields: first name, last name
        tdf.Fields.Append tdf.CreateField("FirstName", dbText, 20)
        tdf.Fields.Append tdf.CreateField("LastName", dbText, 20)
        
        ' create the calculated field: full name
        Set fld = tdf.CreateField("FullName", dbText, 50)
        fld.Expression = "[FirstName] & "" "" & [LastName]"
        tdf.Fields.Append fld
        
        ' append the table and cleanup
        dbs.TableDefs.Append tdf
        
    Cleanup:
        Set fld = Nothing
        Set tdf = Nothing
        Set dbs = Nothing
    End Sub
  • Last updated on