Remarque
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de vous connecter ou de modifier des répertoires.
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de modifier des répertoires.
Renvoie un objet TextRange qui représente le texte trouvé ou le texte remplacé d’une opération de recherche. En lecture seule.
Syntaxe
expression. FoundTextRange
expression Variable qui représente un objet FindReplace .
Valeur renvoyée
TextRange
Remarques
L'objet TextRange réel renvoyé par la propriété FoundTextRange est déterminée par la valeur de la propriété ReplaceScope. Le tableau suivant répertorie les valeurs correspondantes de ces propriétés (voir également l’énumération PbReplaceScope ).
| When ReplaceScope = | FoundTextRange = |
|---|---|
| pbReplaceScopeAll | Empty |
| pbReplaceScopeNone | Rechercher une plage de texte |
| pbReplaceScopeOne | Remplacer une plage de texte |
Lorsque ReplaceScope a pour valeur pbReplaceScopeAll, la propriété FoundTextRange est vide. Toute tentative d’accès renvoie « Accès refusé ». La façon de manipuler la plage de texte du texte recherché consiste à définir la propriété ReplaceScope sur pbReplaceScopeNone ou pbReplaceScopeOne et à accéder à la plage de texte du texte recherché ou remplacé pour chaque occurrence trouvée.
Exemple
Lorsque ReplaceScope a pour valeur pbReplaceScopeNone, FoundTextRange renvoie la plage du texte recherché. L'exemple suivant illustre comment accéder aux attributs de police de la plage de texte de recherche lorsque ReplaceScope a pour valeur pbReplaceScopeNone.
With TextRange.Find
.Clear
.FindText = "important"
.ReplaceScope = pbReplaceScopeNone
Do While .Execute = True
'The FoundTextRange contains the word "important".
If .FoundTextRange.Font.Italic = msoFalse Then
.FoundTextRange.Font.Italic = msoTrue
End If
Loop
End With
Lorsque ReplaceScope a pour valeur pbReplaceScopeOne, la plage de texte du texte recherché est remplacée. Par conséquent, la propriété FoundTextRange renvoie la plage de texte du texte de remplacement. L'exemple suivant montre comment accéder aux attributs de police de la plage de texte remplacée lorsque ReplaceScope a pour valeur pbReplaceScopeOne.
With Document.Find
.Clear
.FindText = "important"
.ReplaceWithText = "urgent"
.ReplaceScope = pbReplaceScopeOne
Do While .Execute = True
'The FoundTextRange contains the word "urgent".
If .FoundTextRange.Font.Bold = msoFalse Then
.FoundTextRange.Font.Bold = msoTrue
End If
Loop
End With
Cet exemple remplace chaque occurrence du mot « bizarre » par le mot « strange » et met le texte remplacé en italique et en gras.
Dim objDocument As Document
Set objDocument = ActiveDocument
With objDocument.Find
.Clear
.FindText = "bizarre"
.ReplaceWithText = "strange"
.ReplaceScope = pbReplaceScopeOne
Do While .Execute = True
.FoundTextRange.Font.Italic = msoTrue
.FoundTextRange.Font.Bold = msoTrue
Loop
End With
Cet exemple recherche toutes les occurrences du mot « important » et les met en italique.
Dim objTextRange As TextRange
Set objTextRange = ActiveDocument.Pages(1).Shapes(1).TextFrame.TextRange
With objTextRange.Find
.Clear
.FindText = "important"
.ReplaceScope = pbReplaceScopeNone
Do While .Execute = True
.FoundTextRange.Font.Italic = msoTrue
Loop
End With
Assistance et commentaires
Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.