List.Accumulate

Syntaxe

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

À propos

Accumule une valeur récapitulative des éléments de la liste spécifiée à l’aide de l’accumulateur.

• list: liste à itérer.
• seed: valeur cumulée initiale.
• accumulator: fonction qui prend l’état actuel et l’élément actuel et retourne le nouvel état.

Exemple 1

Accumule la valeur récapitulative des éléments de la liste.

Utilisation

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Output

15

Exemple 2

Concaténer chaque mot de la liste avec un espace entre eux, mais n’incluez pas d’espace au début.

Utilisation

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Sortie"The quick brown fox jumps over the lazy dog."

Exemple 3

Créez une liste des heures d’achèvement du processus à partir d’une date de début et d’une liste des heures d’exécution du processus.

Utilisation

let
    #"Process Duration" = 
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) => 
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Output

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}