List.Select

Syntaxe

List.Select(list as list, selection as function) as list

À propos

Retourne les valeurs de la liste spécifiée qui correspondent à la condition de sélection.

• list: liste à examiner.
• selection: fonction qui détermine les valeurs à sélectionner.

Exemple 1

Recherchez les valeurs dans la liste {1, -3, 4, 9, -2} supérieures à 0.

Utilisation

List.Select({1, -3, 4, 9, -2}, each _ > 0)

Output

{1, 4, 9}

Exemple 2

Sélectionnez des dates dans la liste qui tombent le samedi ou le dimanche.

Utilisation

let
    dates = {
        #date(2025, 10, 20),  // Monday
        #date(2025, 10, 21),  // Tuesday
        #date(2025, 10, 25),  // Saturday
        #date(2025, 10, 26),  // Sunday
        #date(2025, 10, 27)   // Monday
    },
    weekendDates = List.Select(
        dates,
        each Date.DayOfWeek(_, Day.Monday) >= 5
    )
in
    weekendDates

Output

{
    #date(2025, 10, 25),
    #date(2025, 10, 26)
}

Exemple 3

Affichez une table des clients actifs avec des totaux d’achat de plus de 100 $.

Utilisation

let
    customers = {
        [Name = "Alice", Status = "Active", Purchases = 150],
        [Name = "Bob", Status = "Inactive", Purchases = 200],
        [Name = "Carol", Status = "Active", Purchases = 90],
        [Name = "Dave", Status = "Active", Purchases = 120]
    },
    highValueActiveCustomers = List.Select(
        customers,
        each [Status] = "Active" and [Purchases] > 100
    ),
    resultTable = Table.FromRecords(
        highValueActiveCustomers,
        type table [Name = text, Status = text, Purchases = number]
    )
in
    resultTable

Output

#table(type table[Name = text, Status = text, Purchases = number],
{
    {"Alice", "Active", 150},
    {"Dave", "Active", 120}
})