Table.RemoveMatchingRows

Syntaxe

Table.RemoveMatchingRows(
    table as table,
    rows as list,
    optional equationCriteria as any
) as table

À propos

Supprime toutes les occurrences des lignes spécifiées de la table.

• table: table à rechercher.
• rows: liste contenant des informations sur les lignes à supprimer.
• equationCriteria: (Facultatif) Spécifie la façon dont l’égalité est déterminée lors de la comparaison des valeurs. Ce paramètre peut être une fonction de sélecteur clé, une fonction comparateur ou une liste des colonnes de la table à utiliser lors de la comparaison de lignes.

Exemple 1

Supprimez toutes les lignes où [a = 1] de la table spécifiée.

Utilisation

Table.RemoveMatchingRows(
    Table.FromRecords({
        [a = 1, b = 2],
        [a = 3, b = 4],
        [a = 1, b = 6]
    }),
    {[a = 1]},
    "a"
)

Sortie

Table.FromRecords({[a = 3, b = 4]})

Exemple 2

Supprimez les commandes annulées, en ignorant la casse.

Utilisation

let
    CurrentOrders = #table(type table[OrderID = number, Product = text, Quantity = number],
    {
        {101, "Widget", 5},
        {102, "Gadget", 3},
        {103, "Widget", 5}
    }),
    CanceledOrders = {
        [OrderID = 103, Product = "widget", Quantity = 5]
    },
    FilteredOrders = Table.RemoveMatchingRows(CurrentOrders, CanceledOrders, Comparer.OrdinalIgnoreCase)
in
    FilteredOrders

Sortie

#table(type table[OrderID = number, Product = text, Quantity = number],
{
    {101, "Widget", 5},
    {102, "Gadget", 3}
})

Exemple 3

Supprimez toutes les tâches de maintenance qui tombent sur les jours fériés américains.

Utilisation

let
    MaintenanceSchedule = #table(type table [Task = text, Date = date],
    {
        {"HVAC Check", #date(2025, 7, 10)},             // Not a holiday
        {"Window Washing", #date(2025, 9, 1)},          // Labor Day
        {"Fire Drill", #date(2025, 9, 17)},             // Not a holiday
        {"Light Bulb Replacement", #date(2025, 11, 27)} // Thanksgiving
    }),

    USHolidays = {
        [Date = #date(2025, 1, 1)],   // New Year's Day
        [Date = #date(2025, 7, 4)],   // Independence Day
        [Date = #date(2025, 9, 1)],   // Labor Day
        [Date = #date(2025, 11, 27)], // Thanksgiving
        [Date = #date(2025, 12, 25)]  // Christmas
    },

    FilteredSchedule = Table.RemoveMatchingRows(
        MaintenanceSchedule,
        USHolidays,
        {"Date"}
    )
in
    FilteredSchedule

Sortie

#table(type table[Task = text, Date = date],
{
    {"HVAC Check", #date(2025, 7, 10)},
    {"Fire Drill", #date(2025, 9, 17)}
})

Contenu connexe

Critères d’équation