Limitation du nombre de lignes insérées via le mot clé TOP

Vous pouvez utiliser le mot clé TOP pour limiter le nombre de lignes à insérer.

L'exemple suivant crée la table NewEmployee et y insère les données d'adresse correspondant aux 10 premiers employés de la table Employee. L'instruction SELECT est ensuite exécutée pour vérifier le contenu de la table NewEmployee.

USE AdventureWorks;
GO
IF OBJECT_ID (N'HumanResources.NewEmployee', N'U') IS NOT NULL
    DROP TABLE HumanResources.NewEmployee;
GO
CREATE TABLE HumanResources.NewEmployee
(
    EmployeeID int NOT NULL,
    LastName nvarchar(50) NOT NULL,
    FirstName nvarchar(50) NOT NULL,
    Phone Phone NULL,
    AddressLine1 nvarchar(60) NOT NULL,
    City nvarchar(30) NOT NULL,
    State nchar(3) NOT NULL, 
    PostalCode nvarchar(15) NOT NULL,
    CurrentFlag Flag
);
GO
INSERT TOP (10) INTO HumanResources.NewEmployee 
    SELECT
       e.EmployeeID, c.LastName, c.FirstName, c.Phone,
       a.AddressLine1, a.City, sp.StateProvinceCode, 
       a.PostalCode, e.CurrentFlag
    FROM HumanResources.Employee e
        INNER JOIN HumanResources.EmployeeAddress AS ea
        ON e.EmployeeID = ea.EmployeeID
        INNER JOIN Person.Address AS a
        ON ea.AddressID = a.AddressID
        INNER JOIN Person.StateProvince AS sp
        ON a.StateProvinceID = sp.StateProvinceID
        INNER JOIN Person.Contact as c
        ON e.ContactID = c.ContactID;
GO
SELECT  EmployeeID, LastName, FirstName, Phone,
        AddressLine1, City, State, PostalCode, CurrentFlag
FROM HumanResources.NewEmployee;
GO

Voir aussi

Concepts

Limitation des jeux de résultats à l'aide de TOP et de PERCENT
Insertion d’une ligne à l'aide de l’instruction INSERT et VALUES
Insertion de lignes à l'aide des sous-requêtes INSERT et SELECT
Insertion de lignes au moyen de l'instruction SELECT INTO
Ajout de lignes à l'aide d'INSERT et SELECT

Autres ressources

INSERT (Transact-SQL)
TOP (Transact-SQL)
SELECT (Transact-SQL)

Aide et Informations

Assistance sur SQL Server 2005