ダッシュボード固有のビジュアル

レンダー演算子のコンテキストで作成されたすべての視覚化は、ダッシュボードの視覚化で使用できます。 ただし、次の視覚化は、レンダー 演算子ではなく、 Azure Data Explorer ダッシュボード、リアルタイム ダッシュボード、または Azure Data Explorer Web UI でのみ使用できます。

ダッシュボード ビジュアルのカスタマイズ方法については、「Azure Data Explorer ダッシュボード ビジュアルのカスタマイズ」を参照してください。

Azure Data Explorer のダッシュボードに関する一般的な情報については、「 Azure Data Explorer ダッシュボードを使用してデータを表示する」を参照してください。

じょうごグラフ

ファンネル チャートは、連続した接続ステージを持つ線形プロセスを視覚化します。 じょうごの各段階は、全体のうちの割合を表します。 そのため、ほとんどの場合、ファンネル チャートはファンネルのような形をしており、最初のステージが最も大きく、後続の各ステージは前のステージよりも小さくなります。

次の例では、サーバー要求の進行状況を視覚化し、セッションの合計数、要求、および完了状態を示します。 セッションから要求へのドロップオフと、完了した要求と不完全な要求の割合が強調表示されます。

クエリの例

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

ヒートマップ

ヒートマップは、2 つの軸変数にわたる主要な関心変数の値を、色付きの正方形のグリッドとして表示します。

ヒートマップをレンダリングするには、クエリで 3 つの列を持つテーブルを生成する必要があります。 値フィールドに使用されるデータは数値である必要があります。 x と y の値に使用される列には、次の規則が使用されます。

• 列 x の値が string 形式の場合、列 y の値も string 形式である必要があります。
• 列 x の値が datetime 形式の場合、列 y の値は数値である必要があります。

次の例は、さまざまなメトリックの種類にわたる 5 つの最も頻繁な SQL メトリックの分布を示しています。 各 SQL メトリックで最も一般的なメトリックの種類が強調表示されているため、上位メトリックのアクティビティ パターンを簡単に識別できます。

クエリの例

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count