次の方法で共有

List.PositionOfAny

構文

List.PositionOfAny(
    list as list,
    values as list,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

バージョン情報

指定した値リストの項目がリストに表示されるオフセットを返します。 1 つも出現しない場合は -1 が返されます。

  • list: 検索するリスト。
  • values: 元のリストで検索する値の一覧。
  • occurrence: (省略可能) 報告する特定の出現箇所。 この値には、 Occurrence.First、 Occurrence.Last、または Occurrence.All を指定できます。 occurrenceが指定されていない場合は、Occurrence.Firstが使用されます。
  • equationCriteria: (省略可能) 値を比較するときに等値を決定する方法を指定します。 このパラメーターには、キー セレクター関数、比較子関数、またはキー セレクターと比較子の両方を含むリストを指定できます。

例 1

リスト {1, 2, 3} 内で値 2 または 3 が出現する最初の位置を求めます。

使用方法

List.PositionOfAny({1, 2, 3}, {2, 3})

出力

1

例 2

2022 年または 2023 年の日付のすべてのインスタンスの一覧で位置を検索します。

使用方法

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2025, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = {2022, 2023},
    FindPositions = List.PositionOfAny(YearList, TargetYear, Occurrence.All)
in
    FindPositions

出力

{1, 2, 4}

例 3

大文字と小文字を区別しない、犬または猫という単語の最後の出現箇所のリスト内の位置を検索します。

使用方法

let
    Source = List.PositionOfAny(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        {"dog", "cat"}, 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

出力

6

例 4

17 または 28 のいずれかの 2 つの単位内にあるリスト内の任意の位置を検索します。

使用方法

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOfAny(
        Source, 
        {17, 28},
        Occurrence.All, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

出力

{1, 4}

関連するコンテンツ

数式の条件

  • Last updated on